nixosConfigurations: add ci-vm

Add a VM for using `act` to test GitHub workflows.
https://github.com/nektos/act

Author: djacu

.gitignore

@@ -3,6 +3,9 @@ result/
 .pre-commit-config.yaml
 *.otf
 
+# VM
+nixos.qcow2
+
 # Python
 __pycache__
 

flake.nix

@@ -25,6 +25,7 @@
     hydraJobs = import ./hydra-jobs inputs;
     legacyPackages = import ./legacy-packages inputs;
     library = import ./library inputs;
+    nixosConfigurations = import ./nixos-configurations inputs;
     overlays = import ./overlays inputs;
     packages = import ./packages inputs;
   };

nixos-configurations/ci-vm/configuration.nix

@@ -0,0 +1,68 @@
+{
+  lib,
+  modulesPath,
+  pkgs,
+  ...
+}:
+
+let
+
+  inherit (lib.modules)
+    mkMerge
+    ;
+
+in
+
+{
+  imports = [
+    (modulesPath + "/profiles/qemu-guest.nix")
+    (modulesPath + "/profiles/minimal.nix")
+  ];
+
+  config = mkMerge [
+
+    {
+
+      # Needed to make nix flake check happy
+      system.stateVersion = "25.05";
+      nixpkgs.hostPlatform = "x86_64-linux";
+      fileSystems = {
+        "/".device = "/dev/hda1";
+      };
+
+      boot.loader.systemd-boot.enable = true;
+      boot.loader.efi.canTouchEfiVariables = true;
+
+      # Configure networking
+      networking.useDHCP = true;
+
+      # Create user "test"
+      users.users.test.isNormalUser = true;
+      users.users.test.initialPassword = "test";
+      users.users.test.extraGroups = [ "wheel" ];
+
+      # Enable passwordless ‘sudo’ for the "test" user
+      services.getty.autologinUser = "test";
+      security.sudo.wheelNeedsPassword = false;
+
+      # Make VM output to the terminal instead of a separate window
+      virtualisation.vmVariant.virtualisation.graphics = false;
+
+    }
+
+    {
+      # Setup environment for act
+      environment.systemPackages = with pkgs; [
+        act
+        git
+        vim
+      ];
+      virtualisation.docker.enable = true;
+      virtualisation.vmVariant.virtualisation.diskSize = 8192;
+      virtualisation.vmVariant.virtualisation.memorySize = 2048;
+      virtualisation.vmVariant.virtualisation.cores = 4;
+      users.users.test.extraGroups = [ "docker" ];
+    }
+
+  ];
+}

nixos-configurations/default.nix

@@ -0,0 +1,27 @@
+inputs:
+
+let
+
+  inherit (inputs.nixpkgs)
+    lib
+    ;
+
+  inherit (lib)
+    nixosSystem
+    ;
+
+  inherit (lib.attrsets)
+    filterAttrs
+    mapAttrs
+    ;
+
+in
+
+mapAttrs (
+  configurationDir: _:
+  nixosSystem {
+    modules = [
+      ./${configurationDir}/configuration.nix
+    ];
+  }
+) (filterAttrs (_: fileType: fileType == "directory") (builtins.readDir ./.))