python312Packages.atproto: init at 0.0.59 (#383978)

Author: Aleksanaa

pkgs/development/python-modules/atproto/default.nix

@@ -0,0 +1,107 @@
+{
+  lib,
+  fetchFromGitHub,
+  buildPythonPackage,
+  pythonOlder,
+  nix-update-script,
+
+  # build-system
+  poetry-core,
+  poetry-dynamic-versioning,
+
+  # dependencies
+  click,
+  cryptography,
+  dnspython,
+  httpx,
+  libipld,
+  pydantic,
+  typing-extensions,
+  websockets,
+
+  # nativeCheckInputs
+  pytestCheckHook,
+  pytest-asyncio,
+  coverage,
+}:
+
+buildPythonPackage rec {
+  pname = "atproto";
+  version = "0.0.59";
+  format = "pyproject";
+  disabled = pythonOlder "3.8";
+
+  # use GitHub, pypi does not include tests
+  src = fetchFromGitHub {
+    owner = "MarshalX";
+    repo = "atproto";
+    tag = "v${version}";
+    hash = "sha256-Q+ZJMbchz3u7kXAR9fJpzJd6Zdc44LkntPmEE7IeW6A=";
+  };
+
+  POETRY_DYNAMIC_VERSIONING_BYPASS = version;
+
+  build-system = [
+    poetry-core
+    poetry-dynamic-versioning
+  ];
+
+  dependencies = [
+    click
+    cryptography
+    dnspython
+    httpx
+    libipld
+    pydantic
+    typing-extensions
+    websockets
+  ];
+
+  pythonRelaxDeps = [
+    "websockets"
+  ];
+
+  nativeCheckInputs = [
+    pytestCheckHook
+    pytest-asyncio
+    coverage
+  ];
+
+  disabledTestPaths = [
+    # the required `_PATH_TO_LEXICONS` is outside the package tree
+    "tests/test_atproto_lexicon/test_lexicon_parser.py"
+    # touches network
+    "tests/test_atproto_identity/test_atproto_data.py"
+    "tests/test_atproto_identity/test_async_atproto_data.py"
+    "tests/test_atproto_identity/test_did_resolver.py"
+    "tests/test_atproto_identity/test_async_did_resolver.py"
+    "tests/test_atproto_identity/test_did_resolver_cache.py"
+    "tests/test_atproto_identity/test_async_did_resolver_cache.py"
+    "tests/test_atproto_identity/test_handle_resolver.py"
+    "tests/test_atproto_identity/test_async_handle_resolver.py"
+    "tests/test_atproto_server/auth/test_custom_feed_auth.py"
+  ];
+
+  pythonImportsCheck = [
+    "atproto"
+    "atproto_cli"
+    "atproto_client"
+    "atproto_codegen"
+    "atproto_core"
+    "atproto_crypto"
+    "atproto_firehose"
+    "atproto_identity"
+    "atproto_lexicon"
+    "atproto_server"
+  ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "AT Protocol (Bluesky) SDK for Python";
+    homepage = "https://github.com/MarshalX/atproto";
+    changelog = "https://github.com/MarshalX/atproto/blob/v${version}/CHANGES.md";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ vji ];
+  };
+}

pkgs/development/python-modules/libipld/default.nix

@@ -0,0 +1,68 @@
+{
+  lib,
+  fetchPypi,
+  buildPythonPackage,
+  pythonOlder,
+  rustPlatform,
+  nix-update-script,
+
+  # build-system
+  maturin,
+
+  # nativeCheckInputs
+  pytestCheckHook,
+  pytest-benchmark,
+  pytest-codspeed,
+  pytest-xdist,
+}:
+
+buildPythonPackage rec {
+  pname = "libipld";
+  version = "3.0.1";
+  format = "pyproject";
+  disabled = pythonOlder "3.8";
+
+  # use pypi, GitHub does not include Cargo.lock
+  src = fetchPypi {
+    inherit pname version;
+    hash = "sha256-KXB1LecOX9ysRkaQDN76oNygjbm11ZxAtUltmeO/+mQ=";
+  };
+
+  cargoDeps = rustPlatform.fetchCargoVendor {
+    inherit src;
+    hash = "sha256-V/UGTO+VEBtv5gwKR/fZmmhbeYILsIVc7Mq/Rl6E4Dw=";
+  };
+
+  build-system = [
+    maturin
+  ];
+
+  nativeBuildInputs = with rustPlatform; [
+    cargoSetupHook
+    maturinBuildHook
+  ];
+
+  nativeCheckInputs = [
+    pytestCheckHook
+    pytest-benchmark
+    pytest-codspeed
+    pytest-xdist
+  ];
+
+  disabledTests = [
+    # touches network
+    "test_decode_car"
+  ];
+
+  pythonImportsCheck = [ "libipld" ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Fast Python library to work with IPLD: DAG-CBOR, CID, CAR, multibase";
+    homepage = "https://github.com/MarshalX/python-libipld";
+    changelog = "https://github.com/MarshalX/python-libipld/blob/v${version}/CHANGES.md";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ vji ];
+  };
+}

pkgs/top-level/python-packages.nix

@@ -998,6 +998,8 @@ self: super: with self; {
 
   atomman = callPackage ../development/python-modules/atomman { };
 
+  atproto = callPackage ../development/python-modules/atproto { };
+
   atpublic = callPackage ../development/python-modules/atpublic { };
 
   atsim-potentials = callPackage ../development/python-modules/atsim-potentials { };
@@ -7407,6 +7409,8 @@ self: super: with self; {
     inherit python;
   })).python;
 
+  libipld = callPackage ../development/python-modules/libipld { };
+
   libkeepass = callPackage ../development/python-modules/libkeepass { };
 
   libknot = callPackage ../development/python-modules/libknot { };