plugins/git: init octo-nvim

Author: Soliprem

docs/manual/release-notes/rl-26.12.md

@@ -101,6 +101,7 @@
   - `typst-preview.nvim`: lazy-load.
   - `vim-illuminate`: lazy-load.
   - `which-key.nvim`: lazy-load.
+- `plugins/git/octo-nvim`: init.
 
 [gmvar](https://github.com/gmvar):
 

modules/plugins/git/default.nix

@@ -8,6 +8,7 @@ in {
     ./git-conflict
     ./gitlinker-nvim
     ./neogit
+    ./octo-nvim
   ];
 
   options.vim.git = {
@@ -21,6 +22,7 @@ in {
       * vim-fugitive
       * git-conflict
       * gitlinker-nvim
+      * octo-nvim
     '';
   };
 }

modules/plugins/git/octo-nvim/config.nix

@@ -0,0 +1,44 @@
+{
+  options,
+  config,
+  lib,
+  ...
+}: let
+  inherit (lib.modules) mkIf mkDefault;
+  inherit (lib.nvim.binds) pushDownDefault mkKeymap;
+
+  cfg = config.vim.git.octo-nvim;
+
+  keys = cfg.mappings;
+  inherit (options.vim.git.octo-nvim) mappings;
+in {
+  config = mkIf cfg.enable {
+    vim = {
+      startPlugins = ["plenary-nvim"];
+      visuals.nvim-web-devicons.enable = mkDefault true;
+
+      lazy.plugins.octo-nvim = {
+        package = "octo-nvim";
+        setupModule = "octo";
+        inherit (cfg) setupOpts;
+
+        cmd = ["Octo"];
+
+        keys = [
+          (mkKeymap "n" keys.issueList ":Octo issue list<cr>" {desc = mappings.issueList.description;})
+          (mkKeymap "n" keys.prList ":Octo pr list<cr>" {desc = mappings.prList.description;})
+          (mkKeymap "n" keys.discussionList ":Octo discussion list<cr>" {desc = mappings.discussionList.description;})
+          (mkKeymap "n" keys.notificationList ":Octo notification list<cr>" {desc = mappings.notificationList.description;})
+          (mkKeymap "n" keys.search ''function() require("octo.utils").create_base_search_command { include_current_repo = true } end '' {
+            desc = mappings.search.description;
+            lua = true;
+          })
+        ];
+      };
+
+      binds.whichKey.register = pushDownDefault {
+        "<leader>o" = "+Octo";
+      };
+    };
+  };
+}

modules/plugins/git/octo-nvim/default.nix

@@ -0,0 +1,6 @@
+{
+  imports = [
+    ./config.nix
+    ./octo-nvim.nix
+  ];
+}

modules/plugins/git/octo-nvim/octo-nvim.nix

@@ -0,0 +1,39 @@
+{
+  config,
+  lib,
+  ...
+}: let
+  inherit (lib.options) mkEnableOption mkOption;
+  inherit (lib.types) enum;
+  inherit (lib.nvim.types) mkPluginSetupOption;
+  inherit (config.vim.lib) mkMappingOption;
+
+  selectedPicker =
+    if
+      config.vim.utility.snacks-nvim.enable
+      && (config.vim.utility.snacks-nvim.setupOpts.picker.enabled or false)
+    then "snacks"
+    else if config.vim.telescope.enable
+    then "telescope"
+    else if config.vim.fzf-lua.enable
+    then "fzf-lua"
+    else "default";
+in {
+  options.vim.git.octo-nvim = {
+    enable = mkEnableOption "Edit and review GitHub issues, pull requests, and discussions from the comfort of your favorite editor. [octo-nvim]";
+    setupOpts = mkPluginSetupOption "octo-nvim" {
+      picker = mkOption {
+        type = enum ["telescope" "fzf-lua" "snacks" "default"];
+        default = selectedPicker;
+        description = "Picker backend used by octo.nvim";
+      };
+    };
+    mappings = {
+      issueList = mkMappingOption "List GitHub Issues" "<leader>oi";
+      prList = mkMappingOption "List GitHub Pull Requests" "<leader>op";
+      discussionList = mkMappingOption "List GitHub Discussions" "<leader>od";
+      notificationList = mkMappingOption "List GitHub Notifications" "<leader>ol";
+      search = mkMappingOption "Search GitHub" "<leader>os";
+    };
+  };
+}

npins/sources.json

@@ -2321,6 +2321,19 @@
       "hash": "sha256-9Su5t8cJAHlXV+EE4GLa1+BhezfHZIZgl2P6kBrkX8E=",
       "frozen": true
     },
+    "octo-nvim": {
+      "type": "Git",
+      "repository": {
+        "type": "GitHub",
+        "owner": "pwntester",
+        "repo": "octo.nvim"
+      },
+      "branch": "master",
+      "submodules": false,
+      "revision": "205f024d3ea4a3d81aac751b6bf8e2d01e0c204f",
+      "url": "https://github.com/pwntester/octo.nvim/archive/205f024d3ea4a3d81aac751b6bf8e2d01e0c204f.tar.gz",
+      "hash": "sha256-p5s9JhujDEZezYYsNygi9ejI4qlxluRO3jYWFdJkSrw="
+    },
     "oil-git-status.nvim": {
       "type": "Git",
       "repository": {