[Guide] How to fix a mismatch between the proc macro version used by your Rust toolchain and the one used by NVF's rust analyzer

[KrappRamiro]

Hi! If your rust-analyzer shows the error

Failed to run proc-macro server from path /home/YOUR_USERNAME_HERE/.rustup/toolchains/stable-x86_64-unknown-linux-gnu/libexec/rust-analyzer-proc-macro-srv, error: Custom { kind: Other, error: "The version of the proc-macro server (6) in your Rust toolchain is newer than the version supported by your rust-analyzer (5).\n This will prevent proc-macro expansion from working. Please consider updating your rust-analyzer to ensure compatibility with your current toolchain." } rust-analyzer (macro-error)

That means there's a mismatch between the proc-macro version used by your Rust toolchain and the one used by NVF’s rust-analyzer.

To fix that, all you have to do is define lsp.package like this:

    programs.nvf.settings.vim = {
      languages = {
        rust = {
          enable = true;
          crates.enable = true;
          lsp.enable = true;
          # This fixes the issue:
          # "The version of the proc-macro server in your Rust toolchain is newer than the version supported by your rust-analyzer"
          lsp.package = ["rustup" "run" "stable" "rust-analyzer"];
        };
      };
    };

[KrappRamiro]

mark as autosolved, this is a guide

[NotAShelf]

You probably don't want to use rustup for this. This is neither pure nor reproducible; you might even get different versions on the same installation, and this'll try to reinstall the component each time you launch Neovim. The correct approach in the same spirit as this guide is either:

1. Pinning the Rust toolchain in your configuration, and pass it to the language module. You can use something like rust-overlay for this
2. Setting the package to ["rust-analyzer"] and adding the correct rust-analyzer version to your dev shell.

With the above methods you can override the version of RA NVF pulls, but also make it explicit what exactly you are pulling.

[KrappRamiro]

oops, i did not know! Im gonna try that and update this

[KrappRamiro]

@NotAShelf Would this be alright?

If it is, i will update my post in order to:

1. Teach people how to do it correcly
2. Make sure everyone (who reads this) avoids doing it wrong (like i did)

This is my config:

flake.nix

{
  description = "A simple NixOS flake";
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.05";
    hyprland.url = "github:hyprwm/Hyprland";

    home-manager = {
      url = "github:nix-community/home-manager/release-25.05";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    # --- NEOVIM WITH NVF
    # Required, nvf works best and only directly supports flakes
    nvf = {
      url = "github:NotAShelf/nvf";
      # You can override the input nixpkgs to follow your system's
      # instance of nixpkgs. This is safe to do as nvf does not depend
      # on a binary cache.
      inputs.nixpkgs.follows = "nixpkgs";
    };

    # See https://github.com/NotAShelf/nvf/discussions/1250
    rust-overlay.url = "github:oxalica/rust-overlay";
  };

  outputs = {
    self,
    nixpkgs,
    home-manager,
    nvf,
    ...
  } @ inputs: let
    system = "x86_64-linux";
    pkgs = nixpkgs.legacyPackages.${system};
  in {
    nixosConfigurations = {
      desktop = nixpkgs.lib.nixosSystem {
        specialArgs = {inherit inputs;};
        modules = [
          inputs.home-manager.nixosModules.default
          nvf.nixosModules.default
          ./hosts/desktop/configuration.nix

          # This applies the overlay to the system instance of pkgs
          ({pkgs, ...}: {
            nixpkgs.overlays = [inputs.rust-overlay.overlays.default];
          })
        ];
      };
    };
  };
}

nvf-config.nix

{
  lib,
  config,
  pkgs,
  ...
}: {

    programs.nvf.settings.vim = {
      languages = {
        rust = {
          enable = true;
          crates.enable = true;
          lsp.enable = true;
          # This fixes the issue:
          # "The version of the proc-macro server in your Rust toolchain is newer than the version supported by your rust-analyzer"
          lsp.package = pkgs.rust-bin.stable.latest.rust-analyzer;
        };
      };
    };
}