build.gradle

plugins {
    id 'eclipse'
    id 'idea'
    id 'java-library'
    id 'maven-publish'
    id "me.shedaniel.unified-publishing" version "0.1.+"
    id 'net.minecraftforge.gradle' version '[6.0.16,6.2)'
    id 'org.parchmentmc.librarian.forgegradle' version '1.+'
    id 'org.spongepowered.mixin' version '0.7.+'
}

version = mc_version + "-" + mod_version + "-" + mod_version_tag
group = mod_group_id

base {
    archivesName = mod_name
}

java.toolchain.languageVersion = JavaLanguageVersion.of(17)
println "Java: ${System.getProperty 'java.version'}, JVM: ${System.getProperty 'java.vm.version'} (${System.getProperty 'java.vendor'}), Arch: ${System.getProperty 'os.arch'}"


minecraft {
    //mappings channel: 'official', version: mc_version
    mappings channel: mapping_channel, version: mapping_version

    accessTransformer = file('src/main/resources/META-INF/accesstransformer.cfg')
    copyIdeResources = true

    runs {
        configureEach {
            workingDirectory project.file('run')
            property 'forge.logging.markers', 'REGISTRIES'
            property 'forge.logging.console.level', 'debug'
            args "-mixin.config=${mod_id}.mixins.json"
            mods {
                "${mod_id}" {
                    source sourceSets.main
                }
            }
        }
        client {
            if (project.hasProperty('mc_uuid')) {
                args '--uuid', project.getProperty('mc_uuid')
            }
            if (project.hasProperty('mc_username')) {
                args '--username', project.getProperty('mc_username')
            }
            if (project.hasProperty('mc_accessToken')) {
                args '--accessToken', project.getProperty('mc_accessToken')
            }
            property 'forge.enabledGameTestNamespaces', mod_id
        }

        server {
            property 'forge.enabledGameTestNamespaces', mod_id
        }

        data {
            workingDirectory project.file('run-data')
            args '--mod', mod_id, '--all', '--output', file('src/generated/resources/'), '--existing', file('src/main/resources/')
        }
    }

}

sourceSets.main.resources { srcDir 'src/generated/resources' }

mixin {
    add sourceSets.main, "${mod_id}.refmap.json"
    config "${mod_id}.mixins.json"
    debug.verbose = true
    debug.export = true
}

repositories {
    mavenCentral()
    mavenLocal()
    maven { url = "https://maven.covers1624.net/" }
    maven { url = 'https://maven.blamejared.com' }
    maven { url = 'https://maven.theillusivec4.top/' }
    maven { url = 'https://maven.melanx.de/' }
    maven { url = "https://maven.architectury.dev" }
    maven { url = "https://maven.saps.dev/minecraft" }
    maven { url = 'https://www.jitpack.io' }
    maven { url = "https://maven.terraformersmc.com/" }
    maven {
        name = 'Twilight Forest'
        url = 'https://modmaven.dev/'
    }
    maven {
        url = "https://maven.latvian.dev/releases"
        content {
            includeGroup "dev.latvian.mods"
            includeGroup "dev.latvian.apps"
        }
    }
    maven {
        url "https://www.cursemaven.com"
        content {
            includeGroup "curse.maven"
        }
    }
}

dependencies {
    minecraft "net.minecraftforge:forge:${mc_version}-${forge_version}"
    annotationProcessor "org.spongepowered:mixin:${mixin_version}:processor"

    implementation fg.deobf("curse.maven:jade-324717:${jade_id}")

    compileOnly fg.deobf("top.theillusivec4.curios:curios-forge:${curios_version}:api")
    runtimeOnly fg.deobf("top.theillusivec4.curios:curios-forge:${curios_version}")


    compileOnly ("org.projectlombok:lombok:$lombok_version")
    annotationProcessor ("org.projectlombok:lombok:$lombok_version")

    // compile against the JEI API but do not include it at runtime
    compileOnly fg.deobf("mezz.jei:jei-${mc_version}-common-api:${jei_version}")
    compileOnly fg.deobf("mezz.jei:jei-${mc_version}-forge:${jei_version}")

    // REI
    compileOnly fg.deobf("me.shedaniel:RoughlyEnoughItems-api-forge:${project.rei_version}")
    compileOnly fg.deobf("me.shedaniel:RoughlyEnoughItems-forge:${project.rei_version}")

    // EMI
    compileOnly fg.deobf("dev.emi:emi-forge:${emi_version}")

    if (project.recipe_viewer == 'jei')
        runtimeOnly fg.deobf("mezz.jei:jei-${mc_version}-forge:${jei_version}")
    else if (project.recipe_viewer == 'rei')
        runtimeOnly fg.deobf("me.shedaniel:RoughlyEnoughItems-forge:${project.rei_version}")
    else if (project.recipe_viewer == 'emi')
        runtimeOnly fg.deobf("dev.emi:emi-forge:${project.emi_version}")
    else
        println("unknown recipe viewer: $recipe_viewer")
}

tasks.named('processResources', ProcessResources).configure {
    var replaceProperties = [
            minecraft_version: mc_version, mc_range: mc_range,
            forge_version    : "${mc_version}-${forge_version}", forge_version_range: forge_version_range,
            loader_range     : loader_version_range,
            mod_id           : mod_id, mod_name: mod_name, mod_license: mod_license, mod_version: mod_version,
            issue_tracker    : issue_tracker,
            mod_authors      : mod_authors, mod_description: mod_description
    ]

    inputs.properties replaceProperties

    filesMatching(['META-INF/mods.toml', 'pack.mcmeta']) {
        expand replaceProperties + [project: project]
    }
}


tasks.named('jar', Jar).configure {
    manifest {
        attributes([
                'Specification-Title'     : mod_id,
                'Specification-Vendor'    : mod_authors,
                'Specification-Version'   : '1', // We are version 1 of ourselves
                'Implementation-Title'    : project.name,
                'Implementation-Version'  : project.jar.archiveVersion,
                'Implementation-Vendor'   : mod_authors,
                'Implementation-Timestamp': new Date().format("yyyy-MM-dd'T'HH:mm:ssZ")
        ])
    }

    finalizedBy 'reobfJar'
}

publishing {
    publications {
        register('mavenJava', MavenPublication) {
            artifact jar
        }
    }
    repositories {
        if (System.getenv('MAVEN_USERNAME') != null && System.getenv('MAVEN_PASSWORD') != null) {
            maven {
                name 'S3'
                url = 'https://maven.nova-committee.cn/s3'

                credentials {
                    username System.getenv('MAVEN_USERNAME')
                    password System.getenv('MAVEN_PASSWORD')
                }
            }
        }
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8' // Use the UTF-8 charset for Java compilation
    options.compilerArgs.add("-Xlint:-removal")
}