Move the linker script detection code out into its own CMake module

Author: NWilson

CMakeLists.txt

@@ -114,12 +114,13 @@
 #          -- ./CMakeLists.txt ./cmake/*.cmake ./cmake/*.cmake.in
 ################################################################################
 
+message(STATUS "Using CMake version ${CMAKE_VERSION} (${CMAKE_COMMAND})")
+
 # Increased minimum to 3.15 to allow use of string(REPEAT).
 cmake_minimum_required(VERSION 3.15 FATAL_ERROR)
 project(PCRE2 C)
 set(CMAKE_C_STANDARD 99)
 set(CMAKE_C_STANDARD_REQUIRED TRUE)
-
 set(CMAKE_C_VISIBILITY_PRESET hidden)
 
 # Solaris-specific fix for "CMAKE_C_VISIBILITY_PRESET": this feature was only
@@ -141,12 +142,10 @@ endif()
 # cmake_policy(SET CMP0026 OLD)
 # cmake_policy(SET CMP0074 NEW)
 
-# For FindReadline.cmake. This uses list(APPEND) rather than set() to allow
+# For our modules in cmake/. This uses list(APPEND) rather than set() to allow
 # setting CMAKE_MODULE_PATH on the command line.
 list(APPEND CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
 
-include_directories(${PROJECT_BINARY_DIR}/interface ${PROJECT_BINARY_DIR}/src ${PROJECT_SOURCE_DIR}/src)
-
 # external packages
 find_package(BZip2)
 find_package(ZLIB)
@@ -163,7 +162,7 @@ include(CheckTypeSize)
 include(CMakePackageConfigHelpers)
 include(CMakePushCheckState)
 include(GNUInstallDirs) # for CMAKE_INSTALL_LIBDIR
-include(PCRE2CheckLinkerFlag)
+include(PCRE2CheckVscript)
 include(PCRE2UseSystemExtensions)
 include(PCRE2WarningAsError)
 
@@ -270,29 +269,7 @@ check_c_source_compiles(
 
 # Detect support for linker scripts.
 
-file(WRITE ${PROJECT_BINARY_DIR}/test-map-file.sym "PCRE2_10.00 { global: main; };")
-file(WRITE ${PROJECT_BINARY_DIR}/test-map-file-broken.sym "PCRE2_10.00 { global: main; };  {")
-if(NOT MSVC)
-  pcre2_check_linker_flag(C -Wl,--version-script,${PROJECT_BINARY_DIR}/test-map-file.sym HAVE_VSCRIPT_GNU)
-  pcre2_check_linker_flag(C -Wl,-M,${PROJECT_BINARY_DIR}/test-map-file.sym HAVE_VSCRIPT_SUN)
-endif()
-if(HAVE_VSCRIPT_GNU)
-  set(VSCRIPT_FLAG --version-script)
-  set(HAVE_VSCRIPT TRUE)
-elseif(HAVE_VSCRIPT_SUN)
-  set(VSCRIPT_FLAG -M)
-  set(HAVE_VSCRIPT TRUE)
-endif()
-if(HAVE_VSCRIPT)
-  # Perform the same logic as ax_check_vscript.m4, to test whether the linker
-  # silently ignores (and overwrites) linker scripts it doesn't understand.
-  pcre2_check_linker_flag(C -Wl,${VSCRIPT_FLAG},${PROJECT_BINARY_DIR}/test-map-file-broken.sym HAVE_VSCRIPT_BROKEN)
-  if(HAVE_VSCRIPT_BROKEN)
-    set(HAVE_VSCRIPT FALSE)
-  endif()
-endif()
-file(REMOVE ${PROJECT_BINARY_DIR}/test-map-file.sym)
-file(REMOVE ${PROJECT_BINARY_DIR}/test-map-file-broken.sym)
+pcre2_check_vscript(HAVE_VSCRIPT VSCRIPT_FLAG)
 
 # Check whether Intel CET is enabled, and if so, adjust compiler flags. This
 # code was written by PH, trying to imitate the logic from the autotools
@@ -472,6 +449,54 @@ endif()
 if(BZIP2_FOUND)
   option(PCRE2_SUPPORT_LIBBZ2 "Enable support for linking pcre2grep with libbz2." ON)
 endif()
+
+# zlib
+if(ZLIB_FOUND)
+  option(PCRE2_SUPPORT_LIBZ "Enable support for linking pcre2grep with libz." ON)
+endif()
+
+# editline lib
+if(EDITLINE_FOUND)
+  option(PCRE2_SUPPORT_LIBEDIT "Enable support for linking pcre2test with libedit." OFF)
+endif()
+
+# readline lib
+if(READLINE_FOUND)
+  option(PCRE2_SUPPORT_LIBREADLINE "Enable support for linking pcre2test with libreadline." ON)
+endif()
+
+# Prepare build configuration
+
+include_directories(${PROJECT_BINARY_DIR}/interface ${PROJECT_BINARY_DIR}/src ${PROJECT_SOURCE_DIR}/src)
+
+if(NOT BUILD_SHARED_LIBS AND NOT BUILD_STATIC_LIBS)
+  message(FATAL_ERROR "At least one of BUILD_SHARED_LIBS or BUILD_STATIC_LIBS must be enabled.")
+endif()
+
+if(NOT PCRE2_BUILD_PCRE2_8 AND NOT PCRE2_BUILD_PCRE2_16 AND NOT PCRE2_BUILD_PCRE2_32)
+  message(
+    FATAL_ERROR
+    "At least one of PCRE2_BUILD_PCRE2_8, PCRE2_BUILD_PCRE2_16 or PCRE2_BUILD_PCRE2_32 must be enabled"
+  )
+endif()
+
+if(PCRE2_BUILD_PCRE2_8)
+  set(SUPPORT_PCRE2_8 1)
+endif()
+
+if(PCRE2_BUILD_PCRE2_16)
+  set(SUPPORT_PCRE2_16 1)
+endif()
+
+if(PCRE2_BUILD_PCRE2_32)
+  set(SUPPORT_PCRE2_32 1)
+endif()
+
+if(PCRE2_BUILD_PCRE2GREP AND NOT PCRE2_BUILD_PCRE2_8)
+  message(STATUS "** PCRE2_BUILD_PCRE2_8 must be enabled for the pcre2grep program")
+  set(PCRE2_BUILD_PCRE2GREP OFF)
+endif()
+
 if(PCRE2_SUPPORT_LIBBZ2)
   if(BZIP2_FOUND)
     include_directories(${BZIP2_INCLUDE_DIR})
@@ -484,10 +509,6 @@ if(PCRE2_SUPPORT_LIBBZ2)
   endif()
 endif()
 
-# zlib
-if(ZLIB_FOUND)
-  option(PCRE2_SUPPORT_LIBZ "Enable support for linking pcre2grep with libz." ON)
-endif()
 if(PCRE2_SUPPORT_LIBZ)
   if(ZLIB_FOUND)
     include_directories(${ZLIB_INCLUDE_DIR})
@@ -500,10 +521,6 @@ if(PCRE2_SUPPORT_LIBZ)
   endif()
 endif()
 
-# editline lib
-if(EDITLINE_FOUND)
-  option(PCRE2_SUPPORT_LIBEDIT "Enable support for linking pcre2test with libedit." OFF)
-endif()
 if(PCRE2_SUPPORT_LIBEDIT)
   if(EDITLINE_FOUND)
     include_directories(${EDITLINE_INCLUDE_DIR})
@@ -516,10 +533,6 @@ if(PCRE2_SUPPORT_LIBEDIT)
   endif()
 endif()
 
-# readline lib
-if(READLINE_FOUND)
-  option(PCRE2_SUPPORT_LIBREADLINE "Enable support for linking pcre2test with libreadline." ON)
-endif()
 if(PCRE2_SUPPORT_LIBREADLINE)
   if(READLINE_FOUND)
     include_directories(${READLINE_INCLUDE_DIR})
@@ -532,36 +545,6 @@ if(PCRE2_SUPPORT_LIBREADLINE)
   endif()
 endif()
 
-# Prepare build configuration
-
-if(NOT BUILD_SHARED_LIBS AND NOT BUILD_STATIC_LIBS)
-  message(FATAL_ERROR "At least one of BUILD_SHARED_LIBS or BUILD_STATIC_LIBS must be enabled.")
-endif()
-
-if(NOT PCRE2_BUILD_PCRE2_8 AND NOT PCRE2_BUILD_PCRE2_16 AND NOT PCRE2_BUILD_PCRE2_32)
-  message(
-    FATAL_ERROR
-    "At least one of PCRE2_BUILD_PCRE2_8, PCRE2_BUILD_PCRE2_16 or PCRE2_BUILD_PCRE2_32 must be enabled"
-  )
-endif()
-
-if(PCRE2_BUILD_PCRE2_8)
-  set(SUPPORT_PCRE2_8 1)
-endif()
-
-if(PCRE2_BUILD_PCRE2_16)
-  set(SUPPORT_PCRE2_16 1)
-endif()
-
-if(PCRE2_BUILD_PCRE2_32)
-  set(SUPPORT_PCRE2_32 1)
-endif()
-
-if(PCRE2_BUILD_PCRE2GREP AND NOT PCRE2_BUILD_PCRE2_8)
-  message(STATUS "** PCRE2_BUILD_PCRE2_8 must be enabled for the pcre2grep program")
-  set(PCRE2_BUILD_PCRE2GREP OFF)
-endif()
-
 if(PCRE2_SUPPORT_LIBREADLINE AND PCRE2_SUPPORT_LIBEDIT)
   if(READLINE_FOUND)
     message(

Makefile.am

@@ -1014,7 +1014,7 @@ EXTRA_DIST += \
   cmake/FindEditline.cmake \
   cmake/FindReadline.cmake \
   cmake/pcre2-config.cmake.in \
-  cmake/PCRE2CheckLinkerFlag.cmake \
+  cmake/PCRE2CheckVscript.cmake \
   cmake/PCRE2UseSystemExtensions.cmake \
   cmake/PCRE2WarningAsError.cmake \
   src/config-cmake.h.in \

NON-AUTOTOOLS-BUILD

@@ -429,8 +429,14 @@ applications can be supported through UNIX System Services.
 The PCRE2 codebase compiles and runs with native EBCDIC support on modern z/OS
 systems, using the pre-installed tools (/bin/sh, ./configure, and the XLC or
 IBM-Clang compilers). PCRE2 supports z/OS using both Autoconf (./configure) and
-CMake (which IBM distributes via "zopen install cmake"). Any EBCDIC codepage
-should work (PCRE2 does not assume or require IBM-1047).
+CMake (which IBM distributes via "zopen install cmake").
+
+Note that as of the time of writing, IBM's port of CMake to z/OS has only
+partial support for EBCDIC. It is recommended to build PCRE2 using the
+./configure script, if you require an EBCDIC build.
+
+Any EBCDIC codepage should work (PCRE2 does not assume or require IBM-1047), or
+PCRE2 can compiled for ASCII/Latin-1/Unicode.
 
 After unpacking the PCRE2 tarball, you must subsequently tag the files as ASCII
 in order for the z/OS shell and compiler to interpret them correctly:

README

@@ -974,7 +974,7 @@ The distribution should contain the files listed below.
   cmake/FindEditline.cmake
   cmake/FindReadline.cmake
   cmake/pcre2-config.cmake.in
-  cmake/PCRE2CheckLinkerFlag.cmake
+  cmake/PCRE2CheckVscript.cmake
   cmake/PCRE2UseSystemExtensions.cmake
   cmake/PCRE2WarningAsError.cmake
   src/config-cmake.h.in

cmake/PCRE2CheckLinkerFlag.cmake

@@ -0,0 +1,112 @@
+# Similarly to Autoconf's ax_check_vscript.m4, check whether the linker supports
+# version scripts (GNU ld) or map files (Sun linker).
+# Sets the "have_var" to TRUE or FALSE depending on the detected support; and if
+# support is detected then sets "flag_var" to the appropriate flag to pass to
+# the linker (namely, --version-script or -M).
+
+function(pcre2_check_vscript have_var flag_var)
+  set(${have_var} FALSE PARENT_SCOPE)
+  set(${flag_var} "" PARENT_SCOPE)
+
+  if(MSVC)
+    return()
+  endif()
+
+  set(first_run FALSE)
+  if(NOT DEFINED HAVE_VSCRIPT_GNU)
+    set(first_run TRUE)
+    message(STATUS "Detecting linker version script support")
+  endif()
+
+  include(CheckCSourceCompiles)
+  include(CMakePushCheckState)
+
+  # The BSD file here is a workaround for the fact that check_c_source_compiles
+  # very unfortunately only supports linking executables
+  # with an entrypoint (or a static library), and yet the symbol visibility
+  # requirements for executables are understandably different on some platforms
+  # as compared to linking a shared library. On FreeBSD, linking fails if you
+  # use the linker script to hide various global symbols from /usr/lib/crt1.o.
+  #   https://bugs.freebsd.org/bugzilla/show_bug.cgi?id=269370
+  # Basically, everyone using --version-script is actually going to be creating
+  # a shared library. It's a frustrating mismatch.
+  file(WRITE ${PROJECT_BINARY_DIR}/test-map-file.sym "PCRE2_10.00 { global: exposethis; local: *; };")
+  file(WRITE ${PROJECT_BINARY_DIR}/test-map-file-bsd.sym "PCRE2_10.00 { global: exposethis; environ; __progname; local: *; };")
+  file(WRITE ${PROJECT_BINARY_DIR}/test-map-file-broken.sym "PCRE2_10.00 { global: exposethis; local: *; };  {")
+
+  set(HAVE_VSCRIPT FALSE)
+
+  # Using an executable to check for version-script support is rather delicate,
+  # because linking in an entrypoint (main) adds extra symbols into the mix.
+  # If CMake ever added a SHARED_LIBRARY option to check_c_source_compiles, we'd
+  # use it here.
+  set(
+    test_source
+    [=[
+    int exposethis = 0, hidethis = 0;
+    int main(void) {
+      return exposethis + hidethis;
+    }
+    ]=]
+  )
+
+  cmake_push_check_state(RESET)
+  set(CMAKE_REQUIRED_QUIET TRUE)
+
+  set(CMAKE_REQUIRED_LINK_OPTIONS "-Wl,--version-script,${PROJECT_BINARY_DIR}/test-map-file.sym")
+  check_c_source_compiles("${test_source}" HAVE_VSCRIPT_GNU)
+
+  if(HAVE_VSCRIPT_GNU)
+    set(VSCRIPT_FLAG --version-script)
+    set(HAVE_VSCRIPT TRUE)
+  else()
+    set(CMAKE_REQUIRED_LINK_OPTIONS "-Wl,--version-script,${PROJECT_BINARY_DIR}/test-map-file-bsd.sym")
+    check_c_source_compiles("${test_source}" HAVE_VSCRIPT_BSD)
+
+    if(HAVE_VSCRIPT_BSD)
+      set(VSCRIPT_FLAG --version-script)
+      set(HAVE_VSCRIPT TRUE)
+    else()
+      set(CMAKE_REQUIRED_LINK_OPTIONS "-Wl,-M,${PROJECT_BINARY_DIR}/test-map-file.sym")
+      check_c_source_compiles("${test_source}" HAVE_VSCRIPT_SUN)
+
+      if(HAVE_VSCRIPT_SUN)
+        set(VSCRIPT_FLAG -M)
+        set(HAVE_VSCRIPT TRUE)
+      endif()
+    endif()
+  endif()
+
+  if(HAVE_VSCRIPT)
+    # Perform the same logic as ax_check_vscript.m4, to test whether the linker
+    # silently ignores (and overwrites) linker scripts it doesn't understand.
+    set(CMAKE_REQUIRED_LINK_OPTIONS "-Wl,${VSCRIPT_FLAG},${PROJECT_BINARY_DIR}/test-map-file-broken.sym")
+    check_c_source_compiles("${test_source}" HAVE_VSCRIPT_BROKEN)
+
+    if(HAVE_VSCRIPT_BROKEN)
+      set(HAVE_VSCRIPT FALSE)
+      if(first_run)
+        message(STATUS "Detecting linker version script support - no (linker overwrites unknown scripts)")
+      endif()
+    else()
+      if(first_run)
+        message(STATUS "Detecting linker version script support - yes (${VSCRIPT_FLAG})")
+      endif()
+    endif()
+  else()
+    if(first_run)
+      message(STATUS "Detecting linker version script support - none detected")
+    endif()
+  endif()
+
+  cmake_pop_check_state()
+
+  file(REMOVE ${PROJECT_BINARY_DIR}/test-map-file.sym)
+  file(REMOVE ${PROJECT_BINARY_DIR}/test-map-file-bsd.sym)
+  file(REMOVE ${PROJECT_BINARY_DIR}/test-map-file-broken.sym)
+
+  if(HAVE_VSCRIPT)
+    set(${have_var} TRUE PARENT_SCOPE)
+    set(${flag_var} "${VSCRIPT_FLAG}" PARENT_SCOPE)
+  endif()
+endfunction()