SpartanEngine/generate_project_files.bat at master · PanosK92/SpartanEngine · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
@echo off
setlocal enableextensions
pushd "%~dp0"

set "premake=build_scripts\premake5.exe"
set "lua=build_scripts/premake.lua"
set "interactive=1"

if not "%~1"=="" (
    set "interactive=0"
    call :run_choice %~1
    goto :end
)

:menu
cls
echo =============================================
echo          spartan engine project generator
echo =============================================
echo.
echo   [1] visual studio 2026 - vulkan
echo   [2] visual studio 2026 - d3d12 (wip)
echo   [3] gmake2 - vulkan (linux)
echo   [0] exit
echo.
set /p choice="enter your choice: "
call :run_choice %choice%

:end
if "%interactive%"=="1" (
    echo.
    pause
)
popd
endlocal
exit /b %errorlevel%

:run_choice
if "%~1"=="1" (
    "%premake%" --file=%lua% vs2026 vulkan
    goto :eof
)
if "%~1"=="2" (
    "%premake%" --file=%lua% vs2026 d3d12
    goto :eof
)
if "%~1"=="3" (
    "%premake%" --file=%lua% gmake2 vulkan
    goto :eof
)
if "%~1"=="0" goto :eof
echo invalid choice: %~1
exit /b 1