TerminalMC/start_game.bat at main · PiBOH-MC/TerminalMC · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
@echo off
setlocal EnableExtensions
cd /d "%~dp0"
if not exist log mkdir log
if not exist docs mkdir docs
if exist README.md if not exist docs\README.en.md copy /Y README.md docs\README.en.md >nul
if exist README.it.md if not exist docs\README.it.md copy /Y README.it.md docs\README.it.md >nul
if not defined TERMINALMC_LOG_STAMP for /f %%I in ('powershell -NoProfile -Command "Get-Date -Format yyyyMMdd_HHmmss"') do set "TERMINALMC_LOG_STAMP=%%I"
set "STAMP=%TERMINALMC_LOG_STAMP%"
set "TERMINALMC_LOG_DIR=%CD%\log"
set "TERMINALMC_ACTION_LOG=%CD%\log\actions_%STAMP%.log"
set "LAUNCHER_LANG=en"
set "TM_VERSION=0.0.0-UNKNOWN"
if exist scripts\version (
    for /f "usebackq delims=" %%V in ("scripts\version") do (
        if not "%%V"=="" set "TM_VERSION=%%V"
        goto VERSION_DONE
    )
)
:VERSION_DONE

echo [%DATE% %TIME%] [pre-menu-bat] start_game opened version=%TM_VERSION% > "%TERMINALMC_ACTION_LOG%"

:MENU
cls
if /I "%LAUNCHER_LANG%"=="it" goto MENU_IT

echo ============================================
echo       TerminalMC Launcher - v%TM_VERSION%
echo ============================================
echo.
echo Language: English
echo.
echo 1. Start in Alacritty ^(recommended^)
echo 2. Start in current console
echo 3. Install/Update dependencies
echo 4. Uninstall dependencies
echo 5. Open documentation menu
echo 6. Mouse test
echo 7. View logs
echo 8. Pre-menu mouse mode ^(experimental^)
echo 9. Cambia lingua in italiano
echo 10. Exit
echo.
set /p CHOICE="Choose [1-10]: "
goto HANDLE_CHOICE

:MENU_IT
echo ============================================
echo       TerminalMC Launcher - v%TM_VERSION%
echo ============================================
echo.
echo Lingua: Italiano
echo.
echo 1. Avvia in Alacritty ^(consigliato^)
echo 2. Avvia nella console corrente
echo 3. Installa/Aggiorna dipendenze
echo 4. Disinstalla dipendenze
echo 5. Apri menu documentazione
echo 6. Test mouse
echo 7. Vedi log
echo 8. Pre-menu mouse mode ^(sperimentale^)
echo 9. Switch language to English
echo 10. Esci
echo.
set /p CHOICE="Scegli [1-10]: "
goto HANDLE_CHOICE

:HANDLE_CHOICE
echo [%DATE% %TIME%] [pre-menu-bat] lang=%LAUNCHER_LANG% choice=%CHOICE% >> "%TERMINALMC_ACTION_LOG%"
set "TERMINALMC_LANG=%LAUNCHER_LANG%"

if "%CHOICE%"=="1" call scripts\run_alacritty.bat & goto MENU
if "%CHOICE%"=="2" call scripts\run_console.bat & goto MENU
if "%CHOICE%"=="3" call scripts\install_deps.bat & goto MENU
if "%CHOICE%"=="4" call scripts\uninstall_deps.bat & goto MENU
if "%CHOICE%"=="5" set "TERMINALMC_DOC_LANG=%LAUNCHER_LANG%" & call scripts\open_docs.bat & goto MENU
if "%CHOICE%"=="6" call scripts\run_mouse_test.bat & goto MENU
if "%CHOICE%"=="7" call scripts\open_logs.bat & goto MENU
if "%CHOICE%"=="8" python scripts\pre_menu.py & goto MENU
if "%CHOICE%"=="9" call :TOGGLE_LANG & goto MENU
if "%CHOICE%"=="10" exit /b 0

echo.
if /I "%LAUNCHER_LANG%"=="it" (
    echo Scelta non valida.
) else (
    echo Invalid choice.
)
timeout /t 1 >nul
goto MENU

:TOGGLE_LANG
if /I "%LAUNCHER_LANG%"=="it" (
    set "LAUNCHER_LANG=en"
) else (
    set "LAUNCHER_LANG=it"
)
echo [%DATE% %TIME%] [pre-menu-bat] language changed to %LAUNCHER_LANG% >> "%TERMINALMC_ACTION_LOG%"
exit /b 0