build.gradle

plugins {
    id 'fabric-loom' version '1.15.+'
    id 'maven-publish'
    id 'com.matthewprenger.cursegradle' version '1.5.0'
    id "com.modrinth.minotaur" version "2.+"
    id "com.github.breadmoirai.github-release" version "2.5.2"
}

version = project.mod_version
group = project.maven_group

repositories {
    // Add repositories to retrieve artifacts from in here.
    // You should only use this when depending on other mods because
    // Loom adds the essential maven repositories to download Minecraft and libraries from automatically.
    // See https://docs.gradle.org/current/userguide/declaring_repositories.html
    // for more information about repositories.
    maven { url 'https://jitpack.io' }
    maven { url "https://maven.shedaniel.me/" }
    maven { url "https://maven.pitan76.net/" }
    maven { url "https://maven.architectury.dev/" }
}

dependencies {
    implementation "com.google.guava:guava:${project.guava_version}"
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

    modImplementation "net.pitan76:mcpitanlib-fabric${rootProject.mcpitanlib_version}"
    include "net.pitan76:mcpitanlib_checker-fabric:${rootProject.mcpitanlib_checker_version}"

    //modLocalRuntime "me.shedaniel:RoughlyEnoughItems-fabric:${rootProject.rei_version}"
}

processResources {
    inputs.property "version", project.version
    filteringCharset "UTF-8"

    filesMatching("fabric.mod.json") {
        expand "version": project.version
    }
}

def targetJavaVersion = 8
tasks.withType(JavaCompile).configureEach {
    // ensure that the encoding is set to UTF-8, no matter what the system default is
    // this fixes some edge cases with special characters not displaying correctly
    // see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
    // If Javadoc is generated, this must be specified in that task too.
    it.options.encoding = "UTF-8"
    it.options.release.set(targetJavaVersion)

    sourceCompatibility = JavaVersion.VERSION_1_8
    targetCompatibility = JavaVersion.VERSION_1_8
}

java {
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
    if (JavaVersion.current() < javaVersion) {
        toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
    }
    // Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
    // if it is present.
    // If you remove this line, sources will not be generated.
    withSourcesJar()
}

base {
    archivesName = project.archives_base_name
}

jar {
    from("LICENSE") {
        rename { "${it}_${base.archivesName.get()}" }
    }
}

// configure the maven publication
publishing {
    publications {
        create("mavenJava", MavenPublication) {
            artifactId = project.archives_base_name
            version = project.mod_version + "-SNAPSHOT"
            from components.java

            pom.withXml {
                def pomNode = asNode()
                pomNode.dependencies.'*'.findAll {
                    def groupId = it.groupId.text()
                    def artifactId = it.artifactId.text()

                    (groupId == 'net.pitan76' && artifactId.startsWith('mcpitanlib-')) ||
                            (groupId == 'net.fabricmc.fabric-api')
                }.each() {
                    it.parent().remove(it)
                    print("Removed dependency: ${it.groupId.text()}:${it.artifactId.text()}\n")
                }
            }
        }
    }

    // See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
    repositories {
        maven {
            name = "GitHubPackages"
            url = uri("https://maven.pkg.github.com/PTOM76/maven")
            credentials {
                username = project.findProperty("gpr.user") ?: System.getenv("GITHUB_ACTOR")
                password = project.findProperty("gpr.key") ?: System.getenv("GITHUB_TOKEN")
            }
        }
    }
}

curseforge {
    if (System.getenv("CURSEFORGE_TOKEN") != null) {
        apiKey = System.getenv("CURSEFORGE_TOKEN")
        project {
            id = '697926'
            changelog = rootProject.changelog + "\nMCPitanLib version: " + mcpitanlib_version.split(":")[1]
            releaseType = 'release'
            addGameVersion '1.18.1'
            addGameVersion '1.18.2'
            addGameVersion '1.19'
            addGameVersion '1.19.1'
            addGameVersion '1.19.2'
            addGameVersion '1.20'
            addGameVersion '1.20.1'
            addGameVersion '1.20.3'
            addGameVersion '1.20.4'
            addGameVersion '1.21'
            addGameVersion '1.21.1'
            addGameVersion '1.21.2'
            addGameVersion '1.21.3'
            addGameVersion '1.21.4'
            addGameVersion '1.21.5'
            addGameVersion '1.21.6'
            addGameVersion '1.21.7'
            addGameVersion '1.21.8'
            addGameVersion '1.21.9'
            addGameVersion '1.21.10'
            addGameVersion '1.21.11'
            addGameVersion '26.1'
            addGameVersion '26.1.1'
            addGameVersion '26.1.2'

            addGameVersion "Fabric"
            relations {
                requiredDependency 'fabric-api'
                requiredDependency 'mcpitanlibarch'
            }

            mainArtifact(remapJar)
        }
        options {
            forgeGradleIntegration = false
        }
    }
}

import com.modrinth.minotaur.dependencies.ModDependency

modrinth {
    if (System.getenv("MODRINTH_TOKEN") != null) {
        token = System.getenv("MODRINTH_TOKEN")
        projectId = 'cfQx2fbQ'
        versionNumber = project.mod_version
        uploadFile = remapJar
        gameVersions = ['1.18.1', '1.18.2', '1.19', '1.19.1', '1.19.2', '1.20', '1.20.1', '1.20.3', '1.20.4',
                        '1.21', '1.21.1', '1.21.2', '1.21.3', '1.21.4', '1.21.5', '1.21.6', '1.21.7', '1.21.8',
                        '1.21.9', '1.21.10', '1.21.11', '26.1', '26.1.1', '26.1.2']
        versionType = 'release'
        loaders = ['fabric']
        changelog = rootProject.changelog + "\nMCPitanLib version: " + mcpitanlib_version.split(":")[1]
        dependencies = [
                new ModDependency('P7dR8mSH', 'required'), // Fabric API
                new ModDependency('uNRoUnGT', 'required')  // MCPitanLibarch
        ]
    }
}

// === GitHub Releases publishing ===
// Requires environment variable GITHUB_TOKEN (or -PghToken=... project property) with repo:write scope.
githubRelease {
    delegate.token = System.getenv("GITHUB_TOKEN") ?: project.findProperty("ghToken") ?: ""
    delegate.owner = "Pitan76"
    delegate.repo = "item-alchemy"
    tagName = project.mod_version
    targetCommitish = System.getenv("GITHUB_SHA") ?: "main"
    releaseName = project.mod_version
    body = rootProject.changelog
    draft = false
    prerelease = false
    releaseAssets.from(remapJar.archiveFile, remapSourcesJar.archiveFile)
    overwrite = false
    allowUploadToExisting = false
}

tasks.named('githubRelease') {
    // Avoid failing the task when token is absent (e.g. local builds without CI secrets)
    onlyIf { System.getenv("GITHUB_TOKEN") != null || project.hasProperty("ghToken") }
}

tasks.register('publishToModSites') {
//    dependsOn modrinth
//    dependsOn curseforge
    dependsOn 'githubRelease'
}