PlazmaBukkit/build.gradle.kts at ver/1.21.8 · PlazmaMC/PlazmaBukkit · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
import org.gradle.api.tasks.testing.logging.TestExceptionFormat
import org.gradle.api.tasks.testing.logging.TestLogEvent

plugins {
    java
    id("io.papermc.paperweight.patcher") version "2.0.0-beta.19"
}

val paperMavenPublicUrl = "https://repo.papermc.io/repository/maven-public/"

val brandName: String by project
val providerRepo: String by project

paperweight {
    upstreams.register("purpur") {
        repo = github("PurpurMC", "Purpur")
        ref = providers.gradleProperty("purpurCommit")

        patchFile {
            path = "purpur-server/build.gradle.kts"
            outputFile = file("${brandName.lowercase()}-server/build.gradle.kts")
            patchFile = file("${brandName.lowercase()}-server/build.gradle.kts.patch")
        }
        patchFile {
            path = "purpur-api/build.gradle.kts"
            outputFile = file("${brandName.lowercase()}-api/build.gradle.kts")
            patchFile = file("${brandName.lowercase()}-api/build.gradle.kts.patch")
        }
        patchRepo("paperApi") {
            upstreamPath = "paper-api"
            patchesDir = file("${brandName.lowercase()}-api/paper-patches")
            outputDir = file("paper-api")
        }
        patchDir("purpurApi") {
            upstreamPath = "purpur-api"
            excludes = listOf("build.gradle.kts", "build.gradle.kts.patch", "paper-patches")
            patchesDir = file("${brandName.lowercase()}-api/purpur-patches")
            outputDir = file("purpur-api")
        }
    }
}

val mavenUsername: String? by project
val mavenPassword: String? by project

subprojects {
    apply(plugin = "java-library")
    apply(plugin = "maven-publish")

    extensions.configure<JavaPluginExtension> {
        toolchain {
            languageVersion = JavaLanguageVersion.of(21)
        }
    }

    repositories {
        mavenCentral()
        maven(paperMavenPublicUrl)
    }

    tasks.withType<AbstractArchiveTask>().configureEach {
        isPreserveFileTimestamps = false
        isReproducibleFileOrder = true
    }
    tasks.withType<JavaCompile> {
        options.encoding = Charsets.UTF_8.name()
        options.release = 21
        options.isFork = true
        options.compilerArgs.addAll(listOf("-Xlint:-deprecation", "-Xlint:-removal"))
        options.forkOptions.memoryMaximumSize = "4g"
    }
    tasks.withType<Javadoc> {
        options.encoding = Charsets.UTF_8.name()
    }
    tasks.withType<ProcessResources> {
        filteringCharset = Charsets.UTF_8.name()
    }
    tasks.withType<Test> {
        testLogging {
            showStackTraces = true
            exceptionFormat = TestExceptionFormat.FULL
            events(TestLogEvent.STANDARD_OUT)
        }
    }

    extensions.configure<PublishingExtension> {
        repositories {
            maven("https://maven.pkg.github.com/$providerRepo") {
                name = "github"
                credentials {
                    username = mavenUsername ?: System.getenv("GRADLE_PROPERTY_MAVEN_USERNAME")
                            ?: System.getenv("MAVEN_USERNAME")
                    password = mavenPassword ?: System.getenv("GRADLE_PROPERTY_MAVEN_PASSWORD")
                            ?: System.getenv("MAVEN_PASSWORD")
                }
            }
            maven("https://repo.codemc.io/repository/plazmamc/") {
                name = "codemc"
                credentials {
                    username = mavenUsername ?: System.getenv("GRADLE_PROPERTY_MAVEN_USERNAME")
                            ?: System.getenv("MAVEN_USERNAME")
                    password = mavenPassword ?: System.getenv("GRADLE_PROPERTY_MAVEN_PASSWORD")
                            ?: System.getenv("MAVEN_PASSWORD")
                }
            }
        }
    }
}

tasks.register("printMinecraftVersion") {
    doLast {
        println(providers.gradleProperty("mcVersion").get().trim())
    }
}

tasks.register("printPlazmaVersion") {
    doLast {
        println(project.version)
    }
}