refactor action buttons (ParadiseSS13#29416)

* refactor action buttons

* fix cult spell charge overlay

* lewc review

* update for a/mhelp buttons and xenobio organs

* update for minebot

* properly create button each time

* directly add/remove unavail overlay for reasons

* lewc review

Author: warriorstar-orion

code/__DEFINES/action_defines.dm

@@ -4,3 +4,12 @@
 #define UPDATE_BUTTON_BACKGROUND (1<<2)
 #define UPDATE_BUTTON_OVERLAY (1<<3)
 #define UPDATE_BUTTON_STATUS (1<<4)
+
+// Defines for formatting cooldown actions for the stat panel.
+/// The stat panel the action is displayed in.
+#define PANEL_DISPLAY_PANEL "panel"
+/// The status shown in the stat panel.
+/// Can be stuff like "ready", "on cooldown", "active", "charges", "charge cost", etc.
+#define PANEL_DISPLAY_STATUS "status"
+/// The name shown in the stat panel.
+#define PANEL_DISPLAY_NAME "name"

code/__DEFINES/dcs/datum_signals.dm

@@ -85,7 +85,8 @@
 #define COMSIG_ACTION_REMOVED "action_removed"
 /// From /datum/action/Remove(): (datum/action)
 #define COMSIG_MOB_REMOVED_ACTION "mob_action_removed"
-
+/// From /datum/action/apply_button_overlay()
+#define COMSIG_ACTION_OVERLAY_APPLY "action_overlay_applied"
 
 // /datum/objective
 

code/_onclick/hud/action_button.dm

@@ -10,6 +10,13 @@
 	/// The HUD this action button belongs to
 	var/datum/hud/our_hud
 
+	/// The overlay we have overtop our button
+	var/mutable_appearance/button_overlay
+	/// The icon state of our active overlay, used to prevent re-applying identical overlays
+	var/active_overlay_icon_state
+	/// The icon state of our active underlay, used to prevent re-applying identical underlays
+	var/active_underlay_icon_state
+
 	/// Where we are currently placed on the hud. SCRN_OBJ_DEFAULT asks the linked action what it thinks
 	var/location = SCRN_OBJ_DEFAULT
 	/// A unique bitflag, combined with the name of our linked action this lets us persistently remember any user changes to our position
@@ -212,10 +219,9 @@
 	closeToolTip(usr)
 	return ..()
 
-/mob/proc/update_action_buttons_icon(status_only = FALSE)
-	for(var/X in actions)
-		var/datum/action/A = X
-		A.UpdateButtons(status_only)
+/mob/proc/update_action_buttons_icon(update_flags = ALL, force = FALSE)
+	for(var/datum/action/current_action as anything in actions)
+		current_action.build_all_button_icons(update_flags, force)
 
 //This is the proc used to update all the action buttons.
 /mob/proc/update_action_buttons(reload_screen)
@@ -227,7 +233,7 @@
 
 	for(var/datum/action/action as anything in actions)
 		var/atom/movable/screen/movable/action_button/button = action.viewers[hud_used]
-		action.UpdateButtons()
+		action.build_all_button_icons()
 		if(reload_screen)
 			client.screen += button
 			client.update_active_keybindings()

code/datums/actions/action.dm

@@ -3,14 +3,22 @@
 	var/desc = null
 	var/obj/target = null
 	var/check_flags = 0
-	/// Icon that our button screen object overlay and background
-	var/button_overlay_icon = 'icons/mob/actions/actions.dmi'
-	/// Icon state of screen object overlay
-	var/button_overlay_icon_state = ACTION_BUTTON_DEFAULT_OVERLAY
-	/// Icon that our button screen object background will have
-	var/button_background_icon = 'icons/mob/actions/actions.dmi'
+
+	/// This is the icon state state for the BACKGROUND underlay icon of the button
+	/// (If set to ACTION_BUTTON_DEFAULT_BACKGROUND, uses the hud's default background)
+	var/background_icon = 'icons/mob/actions/actions.dmi'
 	/// Icon state of screen object background
-	var/button_background_icon_state = ACTION_BUTTON_DEFAULT_BACKGROUND
+	var/background_icon_state = ACTION_BUTTON_DEFAULT_BACKGROUND
+
+	/// This is the file for the icon that appears on the button
+	var/button_icon = 'icons/mob/actions/actions.dmi'
+	/// This is the icon state for the icon that appears on the button
+	var/button_icon_state = ACTION_BUTTON_DEFAULT_OVERLAY
+
+	/// This is the file for any FOREGROUND overlay icons on the button (such as borders)
+	var/overlay_icon = 'icons/mob/actions/actions.dmi'
+	/// This is the icon state for any FOREGROUND overlay icons on the button (such as borders)
+	var/overlay_icon_state
 	var/buttontooltipstyle = ""
 	var/transparent_when_unavailable = TRUE
 	var/mob/owner
@@ -20,10 +28,21 @@
 	var/list/viewers = list()
 	/// Whether or not this will be shown to observers
 	var/show_to_observers = TRUE
+	/// Toggles whether this action is usable or not
+	var/action_disabled = FALSE
+	/// The appearance used as an overlay for when the action is unavailable
+	var/mutable_appearance/unavailable_effect
 
+/datum/action/New(target)
+	link_to(target)
 
-/datum/action/New(Target)
-	target = Target
+/// Links the passed target to our action, registering any relevant signals
+/datum/action/proc/link_to(target_)
+	target = target_
+	RegisterSignal(target, COMSIG_PARENT_QDELETING, PROC_REF(clear_ref), override = TRUE)
+
+	if(isatom(target))
+		RegisterSignal(target, COMSIG_ATOM_UPDATED_ICON, PROC_REF(on_target_icon_update))
 
 /datum/action/proc/should_draw_cooldown()
 	return !IsAvailable()
@@ -79,10 +98,10 @@
 		UnregisterSignal(owner, COMSIG_PARENT_QDELETING)
 		owner = null
 
-/datum/action/proc/UpdateButtons(status_only, force)
-	for(var/datum/hud/hud in viewers)
-		var/atom/movable/screen/movable/button = viewers[hud]
-		UpdateButton(button, status_only, force)
+/// Builds / updates all buttons we have shared or given out
+/datum/action/proc/build_all_button_icons(update_flags = ALL, force)
+	for(var/datum/hud/hud as anything in viewers)
+		build_button_icon(viewers[hud], update_flags, force)
 
 /datum/action/proc/Trigger(left_click = TRUE)
 	if(!IsAvailable())
@@ -123,31 +142,60 @@
 			return FALSE
 	return TRUE
 
-/datum/action/proc/UpdateButton(atom/movable/screen/movable/action_button/button, status_only = FALSE, force = FALSE)
+/**
+ * Builds the icon of the button.
+ *
+ * Concept:
+ * - Underlay (Background icon)
+ * - Icon (button icon)
+ * - Maptext
+ * - Overlay (Background border)
+ *
+ * button - which button we are modifying the icon of
+ * force - whether we're forcing a full update
+ */
+/datum/action/proc/build_button_icon(atom/movable/screen/movable/action_button/button, update_flags = ALL, force = FALSE)
 	if(!button)
 		return
-	if(!status_only)
-		button.name = name
-		if(desc)
-			button.desc = "[desc] [initial(button.desc)]"
-		if(owner?.hud_used && button_background_icon_state == ACTION_BUTTON_DEFAULT_BACKGROUND)
-			var/list/settings = owner.hud_used.get_action_buttons_icons()
-			if(button.icon != settings["bg_icon"])
-				button.icon = settings["bg_icon"]
-			if(button.icon_state != settings["bg_state"])
-				button.icon_state = settings["bg_state"]
-		else
-			if(button.icon != button_background_icon)
-				button.icon = button_background_icon
-			if(button.icon_state != button_background_icon_state)
-				button.icon_state = button_background_icon_state
 
+	if(update_flags & UPDATE_BUTTON_NAME)
+		update_button_name(button, force)
+
+	if(update_flags & UPDATE_BUTTON_BACKGROUND)
+		apply_button_background(button, force)
+
+	if(update_flags & UPDATE_BUTTON_ICON)
+		apply_button_icon(button, force)
+
+	if(update_flags & UPDATE_BUTTON_OVERLAY)
 		apply_button_overlay(button, force)
 
+	if(update_flags & UPDATE_BUTTON_STATUS)
+		update_button_status(button, force)
+
+/**
+ * Updates the name and description of the button to match our action name and discription.
+ *
+ * button - what button are we editing?
+ * force - whether an update is forced regardless of existing status
+ */
+/datum/action/proc/update_button_name(atom/movable/screen/movable/action_button/button, force = FALSE)
+	button.name = name
+	if(desc)
+		button.desc = desc
+
+/**
+ * Any other miscellaneous "status" updates within the action button is handled here,
+ * such as redding out when unavailable or modifying maptext.
+ *
+ * button - what button are we editing?
+ * force - whether an update is forced regardless of existing status
+ */
+/datum/action/proc/update_button_status(atom/movable/screen/movable/action_button/button, force = FALSE)
+	button.overlays -= unavailable_effect
+	button.maptext = ""
 	if(should_draw_cooldown())
 		apply_unavailable_effect(button)
-	else
-		return TRUE
 
 //Give our action button to the player
 /datum/action/proc/GiveAction(mob/viewer)
@@ -164,7 +212,7 @@
 		return
 
 
-	var/atom/movable/screen/movable/action_button/button = CreateButton()
+	var/atom/movable/screen/movable/action_button/button = create_button()
 	SetId(button, viewer)
 
 	button.our_hud = our_hud
@@ -186,18 +234,18 @@
 		qdel(button)
 
 
-/datum/action/proc/CreateButton()
+/datum/action/proc/create_button()
 	var/atom/movable/screen/movable/action_button/button = new()
 	button.linked_action = src
-	button.name = name
+	build_button_icon(button, ALL, force = TRUE)
+	// TODO: Pull all of this into the build button structure somehow later
 	button.actiontooltipstyle = buttontooltipstyle
 	var/list/our_description = list()
 	our_description += desc
 	our_description += button.desc
 	button.desc = our_description.Join(" ")
 	return button
 
-
 /datum/action/proc/SetId(atom/movable/screen/movable/action_button/our_button, mob/owner)
 	//button id generation
 	var/bitfield = 0
@@ -215,20 +263,97 @@
 			our_button.id = bitflag
 			return
 
-/datum/action/proc/apply_unavailable_effect(atom/movable/screen/movable/action_button/B)
-	var/image/img = image('icons/mob/screen_white.dmi', icon_state = "template")
-	img.alpha = 200
-	img.appearance_flags = RESET_COLOR | RESET_ALPHA
-	img.color = "#000000"
-	img.plane = FLOAT_PLANE + 1
-	B.add_overlay(img)
-
-
-/datum/action/proc/apply_button_overlay(atom/movable/screen/movable/action_button/current_button)
-	current_button.cut_overlays()
-	if(button_overlay_icon && button_overlay_icon_state)
-		var/image/img = image(button_overlay_icon, current_button, button_overlay_icon_state)
-		img.appearance_flags = RESET_COLOR | RESET_ALPHA
-		img.pixel_x = 0
-		img.pixel_y = 0
-		current_button.add_overlay(img)
+/datum/action/proc/apply_unavailable_effect(atom/movable/screen/movable/action_button/button)
+	if(isnull(unavailable_effect))
+		unavailable_effect = mutable_appearance('icons/mob/screen_white.dmi', icon_state = "template")
+		unavailable_effect.alpha = 200
+		unavailable_effect.appearance_flags = RESET_COLOR | RESET_ALPHA
+		unavailable_effect.color = "#000000"
+		unavailable_effect.plane = FLOAT_PLANE + 1
+	button.overlays |= unavailable_effect
+
+/**
+ * Applies any overlays to our button
+ *
+ * button - what button are we editing?
+ * force - whether an update is forced regardless of existing status
+ */
+/datum/action/proc/apply_button_overlay(atom/movable/screen/movable/action_button/button, force = FALSE)
+	SEND_SIGNAL(src, COMSIG_ACTION_OVERLAY_APPLY, button, force)
+
+	if(!overlay_icon || !overlay_icon_state || (button.active_overlay_icon_state == overlay_icon_state && !force))
+		return
+
+	button.cut_overlay(button.button_overlay)
+	button.button_overlay = mutable_appearance(icon = overlay_icon, icon_state = overlay_icon_state, appearance_flags = (RESET_COLOR|RESET_ALPHA))
+	button.add_overlay(button.button_overlay)
+	button.active_overlay_icon_state = overlay_icon_state
+
+/// Checks if our action is actively selected. Used for selecting icons primarily.
+/datum/action/proc/is_action_active(atom/movable/screen/movable/action_button/button)
+	return FALSE
+
+/**
+ * Creates the background underlay for the button
+ *
+ * button - what button are we editing?
+ * force - whether an update is forced regardless of existing status
+ */
+/datum/action/proc/apply_button_background(atom/movable/screen/movable/action_button/button, force = FALSE)
+	if(!background_icon || !background_icon_state || (button.active_underlay_icon_state == background_icon_state && !force))
+		return
+
+	// What icons we use for our background
+	var/list/icon_settings = list(
+		// The icon file
+		"bg_icon" = background_icon,
+		// The icon state, if is_action_active() returns FALSE
+		"bg_state" = background_icon_state,
+		// The icon state, if is_action_active() returns TRUE
+		"bg_state_active" = background_icon_state,
+	)
+
+	// If background_icon_state is ACTION_BUTTON_DEFAULT_BACKGROUND instead use our hud's action button scheme
+	if(background_icon_state == ACTION_BUTTON_DEFAULT_BACKGROUND && owner?.hud_used)
+		icon_settings = owner.hud_used.get_action_buttons_icons()
+
+	// Determine which icon to use
+	var/used_icon_key = is_action_active(button) ? "bg_state_active" : "bg_state"
+
+	// Make the underlay
+	button.underlays.Cut()
+	var/image/underlay = image(icon = icon_settings["bg_icon"], icon_state = icon_settings[used_icon_key])
+	button.underlays += underlay
+	button.active_underlay_icon_state = icon_settings[used_icon_key]
+
+/**
+ * Applies our button icon and icon state to the button
+ *
+ * button - what button are we editing?
+ * force - whether an update is forced regardless of existing status
+ */
+/datum/action/proc/apply_button_icon(atom/movable/screen/movable/action_button/button, force = FALSE)
+	if(!button_icon || !button_icon_state || (button.icon_state == button_icon_state && !force))
+		return
+
+	button.icon = button_icon
+	button.icon_state = button_icon_state
+
+/// Updates our buttons if our target's icon was updated
+/datum/action/proc/on_target_icon_update(datum/source, updates, updated)
+	SIGNAL_HANDLER // COMSIG_ATOM_UPDATED_ICON
+
+	var/update_flag = NONE
+	var/forced = FALSE
+	if(updates & UPDATE_ICON_STATE)
+		update_flag |= UPDATE_BUTTON_ICON
+		forced = TRUE
+	if(updates & UPDATE_OVERLAYS)
+		update_flag |= UPDATE_BUTTON_OVERLAY
+		forced = TRUE
+	if(updates & (UPDATE_NAME|UPDATE_DESC))
+		update_flag |= UPDATE_BUTTON_NAME
+	// Status is not relevant, and background is not relevant. Neither will change
+
+	// Force the update if an icon state or overlay change was done
+	build_all_button_icons(update_flag, forced)