build.gradle

def localProperties = new Properties()
def localPropertiesFile = rootProject.file('local.properties')
if (localPropertiesFile.exists()) {
    localPropertiesFile.withReader('UTF-8') { reader ->
        localProperties.load(reader)
    }
}

def flutterRoot = localProperties.getProperty('flutter.sdk')
if (flutterRoot == null) {
    throw new GradleException("Flutter SDK not found. Define location with flutter.sdk in the local.properties file.")
}

def flutterVersionCode = localProperties.getProperty('flutter.versionCode')
if (flutterVersionCode == null) {
    flutterVersionCode = '3'
}

def flutterVersionName = localProperties.getProperty('flutter.versionName')
if (flutterVersionName == null) {
    flutterVersionName = '1.0'
}

apply plugin: 'com.android.application'
apply plugin: 'kotlin-android'
apply from: "$flutterRoot/packages/flutter_tools/gradle/flutter.gradle"

def keystoreProperties = new Properties()
def keystorePropertiesFile = rootProject.file('privkey.properties')
if (keystorePropertiesFile.exists()) {
    keystoreProperties.load(new FileInputStream(keystorePropertiesFile))
}

android {
    compileSdkVersion 31
    ndkVersion "22.1.7171670"

    sourceSets {
        main.java.srcDirs += 'src/main/kotlin'
    }

    lintOptions {
        disable 'InvalidPackage'
    }

    defaultConfig {
        applicationId "com.potatoproject.notes"
        minSdkVersion 23
        targetSdkVersion 30
        versionCode flutterVersionCode.toInteger()
        versionName flutterVersionName
        testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
    }

    signingConfigs {
        release {
            keyAlias keystoreProperties['keyAlias']
            keyPassword keystoreProperties['keyPassword']
            storeFile file(keystoreProperties['storeFile'])
            storePassword keystoreProperties['storePassword']
        }
    }

    flavorDimensions "app"
    productFlavors {
        def debugSigning = signingConfigs.debug
        def releaseSigning = signingConfigs.release

        dev {
            signingConfig debugSigning
            applicationId = "com.potatoproject.notes.dev"
            dimension "app"
            manifestPlaceholders = [
                label: "Leaflet Dev",
            ]
        }

        ci {
            signingConfig debugSigning
            applicationId = "com.potatoproject.notes.ci"
            dimension "app"
            manifestPlaceholders = [
                label: "Leaflet CI",
            ]
        }

        production {
            signingConfig releaseSigning
            applicationId = "com.potatoproject.notes"
            dimension "app"
            manifestPlaceholders = [
                label: "Leaflet",
            ]
        }
    }
}

flutter {
    source '../..'
}

dependencies {
    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk7:$kotlin_version"
    implementation 'androidx.core:core-ktx:1.6.0-alpha02'
    implementation 'androidx.annotation:annotation:1.2.0'
}

[
    new Tuple2('Debug', 'debug'),
    new Tuple2('Profile', 'release'),
    new Tuple2('Release', 'release')
].each {
    def taskPostfix = it.first
    def profileMode = it.second

    tasks.whenTaskAdded { task ->
        if (task.name == "javaPreCompileDev$taskPostfix"
            || task.name == "javaPreCompileCi$taskPostfix"
            || task.name == "javaPreCompileProduction$taskPostfix") {
            task.dependsOn "cargoBuild$taskPostfix"
        }
    }

    tasks.register("cargoBuild$taskPostfix", Exec) {
        // Until https://github.com/bbqsrc/cargo-ndk/pull/13 is merged,
        // this workaround is necessary.
        commandLine 'just', '-d', '../..', '--justfile', '../../justfile', "android-native-$profileMode"
    }
}