SmartPianoEngine/CMakeLists.txt at main · ProjetISIE/SmartPianoEngine · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
cmake_minimum_required(VERSION 3.20)
project(
  engine # Smart Piano Engine
  VERSION 3.0.0 # Smart learning
  LANGUAGES CXX)

set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
set(CMAKE_CXX_STANDARD 23)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)

find_package(Threads REQUIRED)
find_package(PkgConfig REQUIRED)
pkg_check_modules(RTMIDI REQUIRED rtmidi)
# pkg_check_modules(ALSA REQUIRED alsa)

add_compile_options(
  -Wall -Wextra -Wpedantic -Wshadow
  # -Wconversion -Werror
)

option(COVERAGE "Mesure couverture de code" ON)
if(COVERAGE)
  add_compile_options(-fprofile-instr-generate -fcoverage-mapping)
  add_link_options(-fprofile-instr-generate)
endif()

add_subdirectory(src)

if(BUILD_TESTING)
  enable_testing()
  add_subdirectory(test)

  set(PROFRAW_MAIN "main.profraw")
  set(PROFRAW_TESTS "tests-%m.profraw")
  set(PROFDATA_FILE "coverage.profdata")

  # Exécute les exécutables pour générer données de profilage (main.profraw…)
  add_custom_target(
    run
    COMMAND LLVM_PROFILE_FILE=${CMAKE_BINARY_DIR}/${PROFRAW_MAIN} ./src/main
            --timeout 1000 # S’arrêter tout seul après 1s
    COMMENT "Exécution du main pour générer ${PROFRAW_MAIN}")
  add_custom_target(
    tests
    COMMAND rm -f ${CMAKE_BINARY_DIR}/tests-*.profraw
    COMMAND LLVM_PROFILE_FILE=${CMAKE_BINARY_DIR}/${PROFRAW_TESTS} ctest
    COMMENT "Exécution des tests pour générer ${PROFRAW_TESTS}")
  # Fusionne les données de profilage dans coverage.profdata
  add_custom_target(
    merge_coverage_data
    COMMAND
      bash -c
      "llvm-profdata merge -sparse -output=${CMAKE_BINARY_DIR}/${PROFDATA_FILE} ${CMAKE_BINARY_DIR}/${PROFRAW_MAIN} ${CMAKE_BINARY_DIR}/tests-*.profraw"
    DEPENDS tests run
    COMMENT "Fusion données couverture: ${PROFDATA_FILE}")
  # Génération du rapport de couverture de code HTML
  add_custom_target(
    coverage
    COMMAND
      llvm-cov show ./src/main
      -instr-profile=${CMAKE_BINARY_DIR}/${PROFDATA_FILE} -format=html
      -output-dir=${CMAKE_BINARY_DIR}/coverage
    DEPENDS merge_coverage_data
    COMMENT "Rapport de couverture HTML généré: ${CMAKE_BINARY_DIR}/coverage")

  add_dependencies(run main)
  add_dependencies(tests ChordRepositoryTest)
  add_dependencies(tests ChordGameTest)
  add_dependencies(tests GameEngineTest)
  add_dependencies(tests ChallengeFactoryTest)
  add_dependencies(tests LoggerTest)
  add_dependencies(tests MessageTest)
  add_dependencies(tests NoteTest)
  add_dependencies(tests NoteGameTest)
  add_dependencies(tests RtMidiInputTest)
  add_dependencies(tests UdsTransportTest)
  add_dependencies(tests AnswerValidatorTest)
  add_dependencies(tests integrationTest)
  add_dependencies(coverage merge_coverage_data)
endif()