SmartPianoEngine/flake.nix at main · ProjetISIE/SmartPianoEngine · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
{
  description = "Nix flake C++23 development environment";
  nixConfig = {
    extra-substituters = [ "https://cache.garnix.io" ];
    extra-trusted-public-keys = [ "cache.garnix.io:CTFPyKSLcx5RMJKfLo5EEPUObbA78b0YQ2DTCJXqr9g=" ];
  };
  inputs.nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
  outputs =
    { self, nixpkgs }:
    let
      systems = [
        "x86_64-linux" # "aarch64-linux"
        "aarch64-darwin"
      ];
      forSystems = nixpkgs.lib.genAttrs systems;
    in
    {
      packages = forSystems (
        system:
        let
          pkgs = import nixpkgs { inherit system; };
          makeEngine =
            p:
            p.callPackage ./engine.nix {
              stdenv = p.clangStdenv;
            };
        in
        {
          default = makeEngine pkgs;
          smart-piano-engine = makeEngine pkgs;
        }
        // nixpkgs.lib.optionalAttrs (system == "x86_64-linux") {
          aarch64-linux-default = makeEngine pkgs.pkgsCross.aarch64-multiplatform;
          aarch64-linux-smart-piano-engine = makeEngine pkgs.pkgsCross.aarch64-multiplatform;
        }
      );
      checks = forSystems (
        system:
        let
          pkgs = import nixpkgs { inherit system; };
          defaultPkg = self.packages.${system}.default;
        in
        {
          coverage = pkgs.clangStdenv.mkDerivation {
            name = "coverage-check";
            src = pkgs.lib.cleanSource ./.;
            doCheck = true;
            nativeBuildInputs = defaultPkg.nativeBuildInputs ++ [
              pkgs.lcov
              pkgs.jq
            ];
            buildInputs = defaultPkg.buildInputs;
            configurePhase = ''
              cmake -DCMAKE_BUILD_TYPE=Debug -DBUILD_TESTING=ON \
                -DCOVERAGE=ON -GNinja -B build -S .
            '';
            buildPhase = ''
              cmake --build build -j16
            '';
            checkPhase = ''
              cmake --build build --target coverage -j1 # Multithread breaks tests
              # Text report for the CI comment
              llvm-cov report build/src/main -instr-profile=build/coverage.profdata -ignore-filename-regex='test/.*' > build/coverage.txt
              cat build/coverage.txt
              # JSON export for threshold verification
              llvm-cov export build/src/main -instr-profile=build/coverage.profdata -ignore-filename-regex='test/.*' --summary-only > build/coverage.json
            '';
            installPhase = ''
              mkdir -p $out
              if [ -f "build/coverage.txt" ]; then cp build/coverage.txt $out/; fi
              if [ -f "build/coverage.json" ]; then cp build/coverage.json $out/; fi
              if [ -d "build/coverage" ]; then cp -R build/coverage $out/html; fi
            '';
          };
        }
      );
      devShells = forSystems (
        system:
        let
          pkgs = import nixpkgs { inherit system; };
          defaultPkg = self.packages.${system}.default;
        in
        {
          default =
            pkgs.mkShell.override
              {
                stdenv = pkgs.clangStdenv; # Clang instead of GCC
              }
              {
                packages =
                  with pkgs;
                  [
                    bashInteractive
                    clang-tools # Clang CLIs, including LSP
                    cmake-format # CMake formatter
                    cmake-language-server # Cmake LSP
                    doxygen # Documentation generator
                    lldb # Clang debug adapter
                  ]
                  ++ lib.optionals stdenv.isLinux [
                    alsa-utils # aconnect…
                    clang-uml # UML diagram generator
                    cppcheck # C++ Static analysis
                    fluidsynth # JACK Synthesizer
                    qsynth # FluidSynth GUI
                    socat # Serial terminal for manual testing
                    valgrind # Debugging and profiling
                  ];
                inputsFrom = [ defaultPkg ];
                # Export compile commands JSON for LSP and other tools
                shellHook = ''
                  export LD_LIBRARY_PATH="${pkgs.lib.makeLibraryPath defaultPkg.buildInputs}:$LD_LIBRARY_PATH"
                  cmake -GNinja -DCMAKE_EXPORT_COMPILE_COMMANDS=ON \
                    -DCMAKE_BUILD_TYPE=Debug -DBUILD_TESTING=ON -DCOVERAGE=ON \
                    -B build # -S .
                '';
              };
        }
      );
    };
}