exe_installer_setup.iss

; Script generated by the Inno Setup Script Wizard.
; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!

#define MyAppName "PyFlat Youtube Downloader"
#define MyAppPublisher "PyFlat Studios"
#define MyAppExeName "main.exe"
#define MyAppIconFile "appdata/images/app-icon.ico"
#define BaseBuildDir "C:\Users\Johannes\Documents\GitHub\YT-Downloader\build\exe.win-amd64-"
#define BuildDir BaseBuildDir + AppPythonVersion


[Setup]
; NOTE: The value of AppId uniquely identifies this application. Do not use the same AppId value in installers for other applications.
; (To generate a new GUID, click Tools | Generate GUID inside the IDE.)
SignTool=signtool
AppId={{C07689AF-CD91-4D65-BF7E-33F6F1D6F556}
AppName={#MyAppName}
AppVersion={#MyAppVersion}
;AppVerName={#MyAppName} {#MyAppVersion}
AppPublisher={#MyAppPublisher}
DefaultDirName={autopf}\{#MyAppName}
DefaultGroupName={#MyAppName}
LicenseFile=C:\Users\Johannes\Documents\GitHub\YT-Downloader\LICENSE
AllowNoIcons=no
; Remove the following line to run in administrative install mode (install for all users.)
PrivilegesRequired=lowest
OutputDir=C:\Users\Johannes\Documents\GitHub\YT-Downloader\build
OutputBaseFilename=pyflat_yt_dl_win_installer_{#MyAppVersion}
Compression=lzma
SolidCompression=yes
WizardStyle=modern

[Languages]
Name: "english"; MessagesFile: "compiler:Default.isl"
Name: "german"; MessagesFile: "compiler:Languages\German.isl"

[Tasks]
Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: unchecked

[Files]
Source: "{#BuildDir}\{#MyAppExeName}"; DestDir: "{app}"; Flags: ignoreversion
Source: "{#BuildDir}\frozen_application_license.txt"; DestDir: "{app}"; Flags: ignoreversion
Source: "{#BuildDir}\python3.dll"; DestDir: "{app}"; Flags: ignoreversion
Source: "{#BuildDir}\python{#StringChange(AppPythonVersion, '.', '')}.dll"; DestDir: "{app}"; Flags: ignoreversion
Source: "{#BuildDir}\appdata\*"; DestDir: "{app}\appdata"; Flags: ignoreversion recursesubdirs createallsubdirs
Source: "{#BuildDir}\languages\*"; DestDir: "{app}\languages"; Flags: ignoreversion recursesubdirs createallsubdirs
Source: "{#BuildDir}\lib\*"; DestDir: "{app}\lib"; Flags: ignoreversion recursesubdirs createallsubdirs
; NOTE: Don't use "Flags: ignoreversion" on any shared system files

[Icons]
Name: "{group}\{#MyAppName}"; Filename: "{app}\{#MyAppExeName}"; IconFilename: "{app}\{#MyAppIconFile}"
Name: "{group}\{cm:UninstallProgram,{#MyAppName}}"; Filename: "{uninstallexe}"; IconFilename: "{app}\{#MyAppIconFile}"
Name: "{autodesktop}\{#MyAppName}"; Filename: "{app}\{#MyAppExeName}"; Tasks: desktopicon; IconFilename: "{app}\{#MyAppIconFile}"

[Run]
Filename: "{cmd}"; Parameters: "/C del /S /Q ""{app}\lib\appdata\__init__.pyc"""; Flags: runhidden
Filename: "{cmd}"; Parameters: "/C del /S /Q ""{app}\lib\src\__init__.pyc"""; Flags: runhidden
Filename: "{cmd}"; Parameters: "/C for /R ""{app}\lib\appdata"" %F in (__init__.pyc) do del ""%F"""; Flags: runhidden
Filename: "{cmd}"; Parameters: "/C for /R ""{app}\lib\src"" %F in (__init__.pyc) do del ""%F"""; Flags: runhidden
Filename: "{app}\{#MyAppExeName}"; Description: "{cm:LaunchProgram,{#StringChange(MyAppName, '&', '&&')}}"; Flags: nowait postinstall skipifsilent

[Code]
procedure EditIniFileIfNeeded;
var
  IniFilePath: string;
begin
  IniFilePath := ExpandConstant('{app}\appdata\config.ini');
  if FileExists(IniFilePath) then
  begin
    SetIniString('DEFAULT', 'first-use-since-update', 'True', IniFilePath);
  end;
end;
procedure CurStepChanged(CurStep: TSetupStep);
begin
  if CurStep = ssPostInstall then
    EditIniFileIfNeeded;
end;