NorthstarDiscordRPC/flake.nix at main · R2Northstar/NorthstarDiscordRPC · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };
  outputs =
    {
      self,
      nixpkgs,
      rust-overlay,
    }:
    let
      systems = [
        "x86_64-linux"
        "aarch64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];
      eachSystem = nixpkgs.lib.genAttrs systems;

      perSystem = eachSystem (system: rec {
        pkgs = import nixpkgs {
          inherit system;
          overlays = [ (import rust-overlay) ];
        };
        pkgs-cross = pkgs.pkgsCross.mingwW64;
        toolchain = pkgs.pkgsBuildHost.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml;
      });
    in
    {
      formatter = eachSystem (system: perSystem.${system}.pkgs.nixfmt-tree);

      packages = eachSystem (
        system: with perSystem.${system}; {
          discordrpc =
            pkgs-cross.callPackage
              (
                {
                  lib,
                  makeRustPlatform,
                  toolchain,
                }:
                (makeRustPlatform {
                  cargo = toolchain;
                  rustc = toolchain;
                }).buildRustPackage
                  (finalAttrs: {
                    name = "DiscordRPC";
                    version = "14.0.0";

                    src = ./.;

                    meta = {
                      description = "discord rpc impl for northstar";
                      homepage = "https://github.com/R2Northstar/NorthstarDiscordRPC";
                      license = lib.licenses.unlicense;
                      maintainers = [ "cat_or_not" ];
                    };

                    cargoLock = {
                      lockFile = ./Cargo.lock;
                    };
                  })
              )
              {
                toolchain = pkgs-cross.rust-bin.stable."1.97.1".default; # the build can't link to any pre built stuff that gets bundled with the one from rust-toolchain.toml
              };

          default = self.packages.${system}.discordrpc;
        }
      );

      devShells = eachSystem (
        system: with perSystem.${system}; {
          default = pkgs.mkShell {
            buildInputs = with pkgs-cross; [
              windows.mingw_w64_headers
              windows.mcfgthreads
              windows.pthreads
            ];

            nativeBuildInputs = [
              toolchain
            ];
          };
        }
      );
    };
}