Support version constraints when finding CRoaring with CMake (#739)

* Add version generation and separate config and targets so that versions are supported

* Add comment

Author: vyasr

cmake/config.cmake.in

@@ -0,0 +1,28 @@
+# Licensed to the Apache Software Foundation (ASF) under one
+# or more contributor license agreements.  See the NOTICE file
+# distributed with this work for additional information
+# regarding copyright ownership.  The ASF licenses this file
+# to you under the Apache License, Version 2.0 (the
+# "License"); you may not use this file except in compliance
+# with the License.  You may obtain a copy of the License at
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing,
+# software distributed under the License is distributed on an
+# "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
+# KIND, either express or implied.  See the License for the
+# specific language governing permissions and limitations
+# under the License.
+
+
+@PACKAGE_INIT@
+
+cmake_minimum_required(VERSION @CMAKE_MINIMUM_REQUIRED_VERSION@)
+
+include("${CMAKE_CURRENT_LIST_DIR}/roaring-targets.cmake" REQUIRED)
+include("${CMAKE_CURRENT_LIST_DIR}/roaring-config-version.cmake" REQUIRED)
+
+set(${CMAKE_FIND_PACKAGE_NAME}_CONFIG "${CMAKE_CURRENT_LIST_FILE}")
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(${CMAKE_FIND_PACKAGE_NAME} CONFIG_MODE)

src/CMakeLists.txt

@@ -71,11 +71,42 @@ install(TARGETS roaring
    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
    INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
 )
-install(EXPORT roaring-config
-   FILE roaring-config.cmake
-   NAMESPACE roaring::
-   DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/roaring
- )
+
+include(CMakePackageConfigHelpers)
+
+# Set up both the build and install trees as suitable for find_package calls.
+# Configuring the build tree as well as the install tree makes it much easier
+# to test other libraries against custom builds of CRoaring by pointing
+# CMAKE_PREFIX_PATH or equivalent directly at the build directory of CRoaring.
+foreach(tree_type BUILD INSTALL)
+  if(tree_type STREQUAL "BUILD")
+    set(install_location ".")
+  else()
+    set(install_location "${CMAKE_INSTALL_LIBDIR}/cmake/roaring")
+  endif()
+
+  set(build_location "${PROJECT_BINARY_DIR}/${install_location}")
+  write_basic_package_version_file(
+    "${build_location}/roaring-config-version.cmake"
+    VERSION ${ROARING_LIB_VERSION}
+    COMPATIBILITY SameMajorVersion)
+  configure_package_config_file("${CMAKE_SOURCE_DIR}/cmake/config.cmake.in"
+                                "${build_location}/roaring-config.cmake"
+                                INSTALL_DESTINATION "${install_location}")
+
+  if(tree_type STREQUAL "BUILD")
+    export(EXPORT roaring-config
+           FILE "${build_location}/roaring-targets.cmake"
+           NAMESPACE roaring::)
+
+  else()
+    install(DIRECTORY "${build_location}/" DESTINATION "${install_location}")
+    install(EXPORT roaring-config
+            DESTINATION "${install_location}"
+            FILE "roaring-targets.cmake"
+            NAMESPACE roaring::)
+  endif()
+endforeach()
 
 if(NOT MSVC)
 ## We output the library at the root of the current directory where cmake is invoked
@@ -112,4 +143,4 @@ if(ROARING_SANITIZE_THREADS)
   message(STATUS "Enabling thread sanitizer")
   target_compile_options(roaring PUBLIC -fsanitize=thread -fno-sanitize-recover=all)
   target_link_libraries(roaring PUBLIC -fsanitize=thread -fno-sanitize-recover=all)
-endif()
+endif()