graphdb-benchmarks/src/main/assembly/resources/sparql/270_lngSmf.sparql at master · Rothamsted/graphdb-benchmarks · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
# [paths] Long and Complex Semantic Motif
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX bk: <http://knetminer.org/data/rdf/terms/biokno/>
PREFIX bkr: <http://knetminer.org/data/rdf/resources/>
PREFIX bka: <http://knetminer.org/data/rdf/terms/biokno/attributes/>
PREFIX bkg: <http://knetminer.org/data/rdf/resources/graphs/>

SELECT *
# FROM bkg:poaceae
{
  ?gene a bk:Gene.
  ?gene bk:enc ?prot.

  ?prot a bk:Protein.
  ?prot (bk:h_s_s|bk:ortho|bk:xref|^bk:h_s_s|^bk:ortho|^bk:xref){0,3} ?prot1.

  ?prot1 a bk:Protein.
  ?prot1 bk:is_a|^bk:ac_by ?enz.

  ?enz a bk:Enzyme.
  ?enz bk:ac_by|bk:in_by ?cmp.

  ?cmp a bk:Comp.
  ?cmp bk:cs_by|bk:pd_by ?trn.

  ?trn a bk:Transport.
  ?trn bk:part_of{0,3} ?pwy.

  ?pwy a bk:Path.

  ?pwy (^bk:part_of){0,3} ?react.
  ?react a bk:Reaction.

  OPTIONAL {
    ?react ^(bk:cs_by|bk:pd_by){0,3} ?rprot.
    ?rprot a bk:Protein.

    ?rprot (bk:h_s_s|bk:ortho|bk:xref|^bk:h_s_s|^bk:ortho|^bk:xref){0,2} ?rprot1.
    ?rprot1 a bk:Protein.

    OPTIONAL {
      # Don't know why sometimes (^bk:enc)? doesn't work
      ?rprot1 ^bk:enc ?rgene.

      # We don't do this for sake of consistency with the Cypher counterpart which
      # doesn't do it either to keep things a bit simpler.
      # ?rgene a bk:Gene.
    }
  }
}
# ORDER BY RAND()
LIMIT 100