sonar-ruby/settings.gradle at master · SonarSource/sonar-ruby · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
pluginManagement {
    repositories {
        mavenCentral()
        gradlePluginPortal()
    }
}

plugins {
    id 'com.gradle.develocity' version '3.18.2'
}

develocity {
    server = 'https://develocity-public.sonar.build'
}

def isCI = System.getenv('CI') != null

buildCache {
    local {
        enabled = !isCI
    }
    remote(develocity.buildCache) {
        enabled = true
        push = isCI
    }
}

dependencyResolutionManagement {
    def slangDependenciesVersion = '1.20.0.7866'
    def analyzerCommonsVersion = '2.20.0.4607'
    def pluginApiVersion = '12.0.0.2960'
    def sonarqubeVersion = '10.0.0.68432'
    def orchestratorVersion = '6.0.1.3892'
    def sonarlintVersion = '9.8.0.76914'
    // slf4j is provided by SQ, SC or SL, should be aligned with sonar-plugin-api
    def slf4jApiVersion = '1.7.30'

    versionCatalogs {
        libs {
            library("sonar-plugin-api", "org.sonarsource.api.plugin", "sonar-plugin-api").version(pluginApiVersion)
            library("sonar-xml-parsing", "org.sonarsource.analyzer-commons", "sonar-xml-parsing").version(analyzerCommonsVersion)
            library("sonar-analyzer-commons", "org.sonarsource.analyzer-commons", "sonar-analyzer-commons").version(analyzerCommonsVersion)
            library("slang-api", "org.sonarsource.slang", "slang-api").version(slangDependenciesVersion)
            library("slang-checks", "org.sonarsource.slang", "slang-checks").version(slangDependenciesVersion)
            library("slang-plugin", "org.sonarsource.slang", "slang-plugin").version(slangDependenciesVersion)
            library("slf4j-api", "org.slf4j", "slf4j-api").version(slf4jApiVersion)
        }

        testLibs {
            library("sonar-plugin-api-test-fixtures", "org.sonarsource.api.plugin", "sonar-plugin-api-test-fixtures").version(pluginApiVersion)
            library("sonar-plugin-api-impl", "org.sonarsource.sonarqube", "sonar-plugin-api-impl").version(sonarqubeVersion)
            library("sonar-orchestrator", "org.sonarsource.orchestrator", "sonar-orchestrator-junit4").version(orchestratorVersion)
            library("sonarlint-core", "org.sonarsource.sonarlint.core", "sonarlint-core").version(sonarlintVersion)
            library("sonar-ws", "org.sonarsource.sonarqube", "sonar-ws").version(sonarqubeVersion)
            library("slang-antlr", "org.sonarsource.slang", "slang-antlr").version(slangDependenciesVersion)
            library("slang-testing", "org.sonarsource.slang", "slang-testing").version(slangDependenciesVersion)
            library("mockito-core", "org.mockito", "mockito-core").version("5.13.0")
            library("assertj-core", "org.assertj", "assertj-core").version("3.26.3")
            library("junit-jupiter-api", "org.junit.jupiter", "junit-jupiter-api").version("5.11.0")
            library("junit-jupiter-engine", "org.junit.jupiter", "junit-jupiter-engine").version("5.11.0")
            library("junit-platform-launcher", "org.junit.platform", "junit-platform-launcher").version("1.11.0")
        }
    }
}

rootProject.name = 'sonar-ruby'

include 'sonar-ruby-plugin'
include 'its:plugin'
include 'its:ruling'
include 'its:test-plugin'
include 'jruby-repackaged'