OVERPASS api working

[pandabear-de]

I have tried to get the following query running. I always get

Could not identify format for service response: serviceURI=http://wikiba.se/ontology#tabular, contentType=application/rdf+xml : response=

my query

PREFIX hint: <http://www.bigdata.com/queryHints#>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX tabular: <http://wikiba.se/ontology-tabular#>
PREFIX osmm: <https://sophox.org/ontology#>
PREFIX osmt: <https://sophox.org/ontology/tags/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT * WHERE {
  hint:Query hint:optimizer "None" .

  SERVICE wikibase:tabular {
    bd:serviceParam wikibase:otQuery '''
      [out:csv(::id,::type,name)][timeout:25];
      (
        node["place"="village"]["wikidata"!~".*"](50,8.4045882700567,50.518665868545,9.3054671763067);
      );
      out;
    ''' .
    ?type tabular:%40type 'string' .
    ?id tabular:%40id 'string' . 
    ?name tabular:name 'string' .
  }

  BIND(URI(CONCAT("https://www.openstreetmap.org/", ?type, "/", ?id)) AS ?osmId)

  ?osmId osmm:loc ?loc .

  OPTIONAL {
    ?osmId osmt:wikidata ?wikidata .
    ?wikidata wdt:P31 ?instanceOf .
    SERVICE wikibase:label {
      bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de" .
      ?instanceOf rdfs:label ?instanceOfLabel .
    }
  }
}

[1ec5]

The Overpass turbo integration relies on the wikibase:tabular service, which was disabled several years ago: #15.

[1ec5]

That said, the query you’re attempting doesn’t require Overpass at all. It appears to be searching for place=village nodes near Hesse that lack wikidata=* tags. You can do this directly in SPARQL:

SELECT * WHERE {
  ?osm osmt:place "village";
       osmt:name ?name;
       osmm:type "n";
       osmm:loc ?coord.
  FILTER NOT EXISTS {
    ?osm osmt:wikidata [].
  }
  SERVICE wikibase:box {
    ?osm osmm:loc ?coord.
    bd:serviceParam wikibase:cornerSouthWest 'Point(8.4045882700567 50)'^^geo:wktLiteral.
    bd:serviceParam wikibase:cornerNorthEast 'Point(9.3054671763067 50.518665868545)'^^geo:wktLiteral.
  }
}

If you’re also trying to determine which Wikidata items correspond to these untagged nodes, you can also perform a federated query:

SELECT * WHERE {
  ?osm osmt:place "village";
       osmt:name ?name;
       osmm:type "n";
       osmm:loc ?coord.
  FILTER NOT EXISTS {
    ?osm osmt:wikidata [].
  }
  SERVICE wikibase:box {
    ?osm osmm:loc ?coord.
    bd:serviceParam wikibase:cornerSouthWest 'Point(8.4045882700567 50)'^^geo:wktLiteral.
    bd:serviceParam wikibase:cornerNorthEast 'Point(9.3054671763067 50.518665868545)'^^geo:wktLiteral.
  }
  
  OPTIONAL {
    SERVICE <https://query.wikidata.org/sparql> {
      ?wd wdt:P11693 ?osm.
    }
  }
}

That said, this kind of query runs very slowly on Sophox. QLever can return a result much more quickly based on its cached copy of Wikidata:

PREFIX ogc: <http://www.opengis.net/rdf#>
PREFIX osmrel: <https://www.openstreetmap.org/relation/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX osmkey: <https://www.openstreetmap.org/wiki/Key:>
PREFIX osm: <https://www.openstreetmap.org/>
PREFIX osm2rdfkey: <https://osm2rdf.cs.uni-freiburg.de/rdf/key#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
SELECT * WHERE {
  # Hesse boundary relation
  osmrel:62650 ogc:sfIntersects ?osm .
  ?osm osmkey:place "village" .
  ?osm rdf:type osm:node .
  FILTER NOT EXISTS {
	?osm osmkey:wikidata [].
  }
  BIND(STRAFTER(STR(?osm), "/node/") AS ?osm_id)
  OPTIONAL {
	SERVICE <https://qlever.cs.uni-freiburg.de/api/wikidata> {
	  ?wd wdt:P11693 ?osm_id .
	}
  }
}

However, you won’t get any Wikidata items in this case, because apparently none of the items about these villages has a OpenStreetMap node ID (P11693) statement on it.