.dotfiles/justfile at main · SymphonySimper/.dotfiles · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
set quiet := true

hostname := `hostname`

[group('build')]
[linux]
build-system HOST=hostname:
    sudo nixos-rebuild switch --flake .#{{ HOST }}

[group('build')]
[unix]
build-home HOST=hostname:
    home-manager build switch --flake .#{{ HOST }}

[group('clean')]
[linux]
clean-system:
    sudo nix-collect-garbage -d

[group('clean')]
[unix]
clean-home:
    nix-collect-garbage -d

[group('clean')]
[linux]
clean: clean-system clean-home

[unix]
last-week-commits:
    ./scripts/flake-last-week-commits.sh

[unix]
news-home HOST=hostname:
    home-manager news --flake .#{{ HOST }}

[unix]
update-flake:
    nix flake update --commit-lock-file

[linux]
gnome-nested-shell:
    SHELL_DEBUG=all dbus-run-session gnome-shell --devkit --wayland

[group('scripts')]
[windows]
update-config:
    nu ./scripts/windows/update-config.nu