build.gradle

plugins {
    id 'java'
    id 'org.springframework.boot' version '3.4.1'
    id 'io.spring.dependency-management' version '1.1.6'
    id 'jacoco' // Jacoco
    id 'com.google.cloud.tools.jib' version '3.4.0' // Jib
}

group = 'org.sopt'
version = '1.0-SNAPSHOT'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(17)
    }
}

repositories {
    mavenCentral()
}

ext {
    springAiVersion = '1.1.2'
}

dependencyManagement {
    imports {
        mavenBom "org.springframework.ai:spring-ai-bom:${springAiVersion}"
    }
}

dependencies {
    // WEB
    implementation 'org.springframework.boot:spring-boot-starter-web'

    // JPA
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'

    // mysql (DB 선택)
    runtimeOnly 'com.mysql:mysql-connector-j'

    // H2 (테스트용)
    testRuntimeOnly 'com.h2database:h2'

    // postgresql (DB 선택)
    runtimeOnly 'org.postgresql:postgresql:42.7.3'

    // Validation
    implementation 'org.springframework.boot:spring-boot-starter-validation'

    // Lombok
    compileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.projectlombok:lombok'

    // QueryDSL
    implementation "com.querydsl:querydsl-jpa:5.0.0:jakarta"
    annotationProcessor "com.querydsl:querydsl-apt:5.0.0:jakarta"
    annotationProcessor "jakarta.annotation:jakarta.annotation-api"
    annotationProcessor "jakarta.persistence:jakarta.persistence-api"

    // Swagger
    implementation 'org.springdoc:springdoc-openapi-starter-webmvc-ui:2.7.0'

    // actuator
    implementation 'org.springframework.boot:spring-boot-starter-actuator'

    // JWT
    implementation 'io.jsonwebtoken:jjwt-api:0.11.5'
    runtimeOnly 'io.jsonwebtoken:jjwt-impl:0.11.5'
    runtimeOnly 'io.jsonwebtoken:jjwt-jackson:0.11.5'

    implementation 'com.fasterxml.jackson.core:jackson-databind'

    // Spring Security
    implementation 'org.springframework.boot:spring-boot-starter-security'

    // Redis
    implementation 'org.springframework.boot:spring-boot-starter-data-redis'

    // monitoring
    implementation 'io.micrometer:micrometer-registry-prometheus'

    // S3
    implementation platform("software.amazon.awssdk:bom:2.31.68")
    implementation "software.amazon.awssdk:s3"

    // Spring ai
    implementation 'org.springframework.ai:spring-ai-starter-model-google-genai'
    implementation 'org.springframework.ai:spring-ai-starter-model-google-genai-embedding'

    // chat memory - jdbc
    implementation 'org.springframework.ai:spring-ai-starter-model-chat-memory-repository-jdbc'

    // pgvector
    implementation 'org.springframework.ai:spring-ai-starter-vector-store-pgvector'

    // Hibernate
    implementation "org.hibernate.orm:hibernate-vector:6.4.4.Final"

    // TikaDocumentReader
    implementation 'org.springframework.ai:spring-ai-tika-document-reader'

    // Test
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testImplementation 'org.springframework.security:spring-security-test'

    // test ai
    testImplementation 'org.springframework.ai:spring-ai-test'
    testImplementation 'org.springframework.ai:spring-ai-spring-boot-testcontainers'

    // test h2
    testImplementation 'com.h2database:h2'

    // retry
    implementation 'org.springframework.retry:spring-retry'
    implementation 'org.springframework:spring-aspects'
}

def querydslDir = "src/main/generated/querydsl"

sourceSets {
    main {
        java {
            srcDirs += querydslDir
        }
    }
}

tasks.withType(JavaCompile) {
    options.getGeneratedSourceOutputDirectory().set(file(querydslDir))
}

clean {
    delete file(querydslDir)
}

test {
    useJUnitPlatform()
    finalizedBy jacocoTestReport
}

// == Jacoco 설정 == //
jacoco {
    toolVersion = "0.8.11"
}

jacocoTestReport{
    dependsOn test

    reports{
        xml.required = true
        html.required = true
        csv.required = true
    }

    // 커버리지 계산에서 제외할 클래스 지정(논의 필요)
    afterEvaluate {
        classDirectories.setFrom(files(classDirectories.files.collect {
            fileTree(dir: it, exclude: [
                    '**/config/**',
                    '**/dto/**',
                    '**/entity/**',
                    '**/exception/**',
                    '**/Q*.class',
                    '**/global/response/**'
            ])
        }))
    }
}

// == Jib 설정 == //
jib{
    // 베이스 이미지
    from{
     image = 'eclipse-temurin:17-jre'

        platforms {
            platform {
                architecture = 'amd64'
                os = 'linux'
            }
        }

    }

    to{
        image = project.findProperty('jibToImage') ?: 'clustar'
        tags = [project.findProperty('jibTag') ?: 'latest']
    }

    container{
        jvmFlags = [
                '-Xms512m',
                '-Xmx1024m',
                '-Duser.timezone=Asia/Seoul'
        ]

        ports = ['8080']

        creationTime = 'USE_CURRENT_TIMESTAMP'
    }
}