BU-Server/build.gradle at develop · TEAM-CONCRETE/BU-Server · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
plugins {
	id 'java'
	id 'org.springframework.boot' version '3.5.7'
	id 'io.spring.dependency-management' version '1.1.7'
}

group = 'com.concrete'
version = '0.0.1-SNAPSHOT'
description = 'Backend service for Build-Up platform'

java {
	toolchain {
		languageVersion = JavaLanguageVersion.of(21)
	}
}

configurations {
	compileOnly {
		extendsFrom annotationProcessor
	}
}

repositories {
	mavenCentral()
}

dependencies {
	// Spring Boot Starters
	implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
	implementation 'org.springframework.boot:spring-boot-starter-security'
	implementation 'org.springframework.boot:spring-boot-starter-web'
	implementation 'org.springframework.boot:spring-boot-starter-validation'
	implementation 'org.springframework.boot:spring-boot-starter-actuator'
	implementation 'org.springframework.boot:spring-boot-starter-webflux' // FastAPI 연동용 WebClient
	implementation 'org.springframework.boot:spring-boot-starter-thymeleaf' // PDF 템플릿 렌더링용
	implementation 'org.springframework.retry:spring-retry' // Face API 재시도 로직용
	implementation 'org.springframework:spring-aspects' // AOP for @Retryable

	// Swagger/OpenAPI (Spring Boot 3 호환)
	implementation 'org.springdoc:springdoc-openapi-starter-webmvc-ui:2.8.0'

	// JWT (Spring Boot 3 호환)
	implementation 'io.jsonwebtoken:jjwt-api:0.12.6'
	runtimeOnly 'io.jsonwebtoken:jjwt-impl:0.12.6'
	runtimeOnly 'io.jsonwebtoken:jjwt-jackson:0.12.6'

	// AWS S3 (Spring Boot 3 호환)
	implementation 'io.awspring.cloud:spring-cloud-aws-starter-s3:3.2.1'

	// PDF Generation
	implementation 'com.github.librepdf:openpdf:1.3.30' // PDF 생성 및 조작용
	implementation 'org.xhtmlrenderer:flying-saucer-pdf-openpdf:9.1.22' // HTML to PDF 변환용

	// Database Migration (Flyway)
	implementation 'org.flywaydb:flyway-core'
	implementation 'org.flywaydb:flyway-mysql'

	// Development Tools
	developmentOnly 'org.springframework.boot:spring-boot-devtools'

	// Lombok
	compileOnly 'org.projectlombok:lombok'
	annotationProcessor 'org.projectlombok:lombok'

	// QueryDSL (Spring Boot 3 호환)
	implementation 'com.querydsl:querydsl-jpa:5.0.0:jakarta'
	annotationProcessor 'com.querydsl:querydsl-apt:5.0.0:jakarta'
	annotationProcessor 'jakarta.annotation:jakarta.annotation-api'
	annotationProcessor 'jakarta.persistence:jakarta.persistence-api'

	// Database Driver
	runtimeOnly 'com.mysql:mysql-connector-j'
	testRuntimeOnly 'com.h2database:h2' // 테스트용 H2 Database

	// Test Dependencies
	testImplementation 'org.springframework.boot:spring-boot-starter-test'
	testImplementation 'org.springframework.security:spring-security-test'
	testImplementation 'com.squareup.okhttp3:mockwebserver:4.12.0' // Face API Mock 테스트용
	testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
}

tasks.named('test') {
	useJUnitPlatform()

	// .env 파일에서 환경변수 로드
	def envFile = file('.env')
	if (envFile.exists()) {
		envFile.readLines().each { line ->
			// 빈 줄이나 주석으로 시작하는 줄 건너뛰기
			if (line.trim().isEmpty() || line.trim().startsWith('#')) {
				return
			}

			// 인라인 주석 제거 (# 이후 제거)
			def cleanLine = line.contains('#') ? line.substring(0, line.indexOf('#')) : line

			// = 가 포함된 줄만 처리
			if (cleanLine.contains('=')) {
				def parts = cleanLine.split('=', 2)
				if (parts.length == 2) {
					def key = parts[0].trim()
					def value = parts[1].trim()
					environment key, value
				}
			}
		}
	}
}

// QueryDSL 설정
def generated = 'src/main/generated'

// querydsl QClass 파일 생성 위치 지정
tasks.withType(JavaCompile).configureEach {
	options.getGeneratedSourceOutputDirectory().set(file(generated))
}

// java source set에 querydsl QClass 위치 추가
sourceSets {
	main.java.srcDirs += [generated]
}

// gradle clean 시 QClass 디렉토리 삭제
clean {
	delete file(generated)
}