Clody_Android/app/build.gradle.kts at 4e97a135e32be81e2a075776b66f742d303ad0a5 · Team-Clody/Clody_Android · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
import java.util.Properties

val properties = Properties().apply {
    load(project.rootProject.file("local.properties").inputStream())
}

plugins {
    alias(libs.plugins.android.application)
    alias(libs.plugins.kotlin.android)
    alias(libs.plugins.kotlin.compose)
    alias(libs.plugins.ksp)
    alias(libs.plugins.hilt)
    alias(libs.plugins.ktlint)
    alias(libs.plugins.kotlin.serialization)
    alias(libs.plugins.google.services)
    alias(libs.plugins.firebase.crashlytics.plugin)
    alias(libs.plugins.firebase.app.distribution)
}

android {
    namespace = "com.sopt.clody"
    compileSdk = 35

    defaultConfig {
        applicationId = "com.sopt.clody"
        minSdk = 28
        targetSdk = 35
        versionCode = 25
        versionName = "1.1.1"
        val kakaoApiKey: String = properties.getProperty("kakao.api.key")
        val amplitudeApiKey: String = properties.getProperty("amplitude.api.key")
        val googleAdmobAppId: String = properties.getProperty("GOOGLE_ADMOB_APP_ID", "")
        val googleAdmobUnitId: String = properties.getProperty("GOOGLE_ADMOB_UNIT_ID", "")
        buildConfigField("String", "GOOGLE_ADMOB_APP_ID", "\"$googleAdmobAppId\"")
        buildConfigField("String", "GOOGLE_ADMOB_UNIT_ID", "\"$googleAdmobUnitId\"")
        buildConfigField("String", "KAKAO_API_KEY", "\"$kakaoApiKey\"")
        buildConfigField("String", "AMPLITUDE_API_KEY", "\"$amplitudeApiKey\"")
        manifestPlaceholders["kakaoRedirectUri"] = "kakao$kakaoApiKey"
        manifestPlaceholders["GOOGLE_ADMOB_APP_ID"] = googleAdmobAppId
        testInstrumentationRunner = "androidx.test.runner.AndroidJUnitRunner"
    }

    signingConfigs {
        create("release") {
            storeFile = file(properties.getProperty("storeFile") ?: "")
            storePassword = properties.getProperty("storePassword") ?: ""
            keyAlias = properties.getProperty("keyAlias") ?: ""
            keyPassword = properties.getProperty("keyPassword") ?: ""
        }
    }

    buildTypes {
        debug {
            isMinifyEnabled = false
            buildConfigField("String", "CLODY_BASE_URL", properties["clody.base.url"].toString())
        }

        release {
            isMinifyEnabled = false
            isShrinkResources = false
            buildConfigField("String", "CLODY_BASE_URL", properties["clody.base.url"].toString())
            proguardFiles(
                getDefaultProguardFile("proguard-android-optimize.txt"),
                "proguard-rules.pro",
            )
            signingConfig = signingConfigs.getByName("release")
        }
    }
    compileOptions {
        sourceCompatibility = JavaVersion.VERSION_11
        targetCompatibility = JavaVersion.VERSION_11
    }
    kotlinOptions {
        jvmTarget = "11"
    }
    buildFeatures {
        buildConfig = true
        compose = true
    }
}

dependencies {
    // Test
    testImplementation(libs.junit)
    androidTestImplementation(platform(libs.compose.bom))
    androidTestImplementation(libs.bundles.test)

    // Debug
    debugImplementation(libs.bundles.debug)

    // Androidx
    implementation(libs.bundles.androidx)
    implementation(platform(libs.compose.bom))

    // Coroutine
    implementation(libs.bundles.coroutines)

    // DI
    implementation(libs.bundles.hilt)
    ksp(libs.hilt.compiler)

    // Third-Party
    implementation(platform(libs.okhttp.bom))
    implementation(libs.bundles.okhttp)
    implementation(libs.bundles.retrofit)
    implementation(libs.kotlinx.serialization.json)

    // FireBase
    implementation(platform(libs.firebase.bom))
    implementation(libs.bundles.firebase)
    implementation(libs.firebase.config.ktx)

    // Amplitude
    implementation(libs.amplitude)

    // Google Admob
    implementation(libs.admob)

    // UI Enhance
    implementation(libs.accompanist.systemuicontroller)
    implementation(libs.accompanist.insets)

    // Mavericks
    implementation(libs.bundles.mavericks)

    // Play Store
    implementation(libs.bundles.plays)

    // ETC
    implementation(libs.timber)
    implementation(libs.lottie.compose)
    implementation(libs.coil)
    implementation(libs.kakao.user)
    implementation(libs.kotlinx.datetime)
}