Add author disambiguation panel to wikiproject curation page

[Daniel-Mietchen]

What kind of panel would you like to add to which Scholia aspect?

On the curation page for the wikiproject aspect, I would like to add a panel that highlights author name strings relevant to the given WikiProject.

What kind of information should the panel provide, and which of the visualization options (e.g. table, bubble chart, map) should it use?

• Sample query (based on scholia/app/templates/topic-curation_missing-author-items.sparql):

PREFIX target: <http://www.wikidata.org/entity/Q56241615>

SELECT
  # Number of works with the author
  ?count

  # Author score - 3 points for authoring a work, 1 for being cited
  ?score

  # Author as a string
  ?author

  # Build URL to the Author disambiguator tool
  (CONCAT(
      'https://author-disambiguator.toolforge.org/names_oauth.php?doit=Look+for+author&name=',
      ENCODE_FOR_URI(?author)) AS ?resolver_url)
WITH {
  SELECT DISTINCT ?work WHERE {
    ?work wdt:P6104 target: .
  }
  LIMIT 100000
} AS %works
WITH {
  SELECT
    (COUNT(?work) AS ?count)
    ?author
  WHERE {
    INCLUDE %works
    ?work wdt:P2093 ?author .
  }
  GROUP BY ?author
} AS %result

# Generate a score for each author
WITH {
  SELECT (SUM(?score_) AS ?score) ?author
  WHERE {
    {
      # Assign them 3 points if they are an author of a work on the subject
      SELECT (3 AS ?score_) ?author ?work WHERE {
        ?work wdt:P2093 ?author .
        ?work wdt:P6104 target: .
      }
    }
    UNION
    {
      # Assign them 1 point if they are the author of a work that is cited by a work on the subject
      SELECT (1 AS ?score_) ?author ?work WHERE {
        ?work wdt:P2093 ?author .
        ?citing_work wdt:P2860 ?work .
        ?citing_work wdt:P6104 target: .
      }
    }
  }
  GROUP BY ?author
} AS %scores

WHERE {
  INCLUDE %result
  INCLUDE %scores

  # Label the result
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" . }
}
ORDER BY DESC(?count) DESC(?score)
LIMIT 200

Which Wikidata entries would be good candidates to explore such visualizations?

• WikiProject Invasion Biology (Q56241615) for maintained by WikiProject (P6104)
• NIOSH WikiCite project (Q104416361) for on focus list of Wikimedia project (P5008)

Anything else?

For now, we will probably have to cater to users of both P6104 and P5008.