In publisher aspect, add panel for most recent publications

[Daniel-Mietchen]

e.g. last 500 or so, as we do per topic.

[fnielsen]

# Recently published works from a specific publisher
SELECT DISTINCT ?date ?work ?workLabel WHERE {
  ?work wdt:P1433* / wdt:P123 wd:Q2188 .
  ?work wdt:P577 ?datetime . 
  BIND(xsd:date(?datetime) AS ?date)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,da,es,fr,jp,nl,no,ru,sv,zh". }
}
ORDER BY DESC(?date)
LIMIT 500

[Daniel-Mietchen]

Looks good in principle, but times out for Elsevier, even for a limit of 10. Maybe we need a subquery with a limit here.

[fnielsen]

This also times out:

# Recently published works from a specific publisher
SELECT DISTINCT ?date ?work ?workLabel 
WITH {
  SELECT ?datetime ?work WHERE {
    ?work wdt:P1433* / wdt:P123 wd:Q746413 .
    ?work wdt:P577 ?datetime . 
  }
  ORDER BY DESC(?datetime)
  LIMIT 500 
} AS %results
WHERE {
  INCLUDE %results
  BIND(xsd:date(?datetime) AS ?date)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,da,es,fr,jp,nl,no,ru,sv,zh". }
}
ORDER BY DESC(?date)

[fnielsen]

This works (but with on journal articles):

# Recently published works from a specific publisher
SELECT DISTINCT ?date ?work ?workLabel 
WITH {
  SELECT ?datetime ?work WHERE {
    ?work wdt:P123 wd:Q746413 .
    ?work wdt:P577 ?datetime . 
  }
  ORDER BY DESC(?datetime)
  LIMIT 500 
} AS %results
WHERE {
  INCLUDE %results
  BIND(xsd:date(?datetime) AS ?date)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,da,es,fr,jp,nl,no,ru,sv,zh". }
}
ORDER BY DESC(?date)

[fnielsen]

This neither works

# Recently published works from a specific publisher
SELECT DISTINCT ?date ?work ?workLabel 
WITH {
  SELECT ?datetime ?work WHERE {
    ?work wdt:P1433 / wdt:P123 wd:Q746413 .
    ?work wdt:P577 ?datetime . 
    BIND(str(year(?datetime)) AS ?year)
    FILTER (?year = "2018")
  }
  ORDER BY DESC(?datetime)
  LIMIT 500 
} AS %results
WHERE {
  INCLUDE %results
  BIND(xsd:date(?datetime) AS ?year)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,da,es,fr,jp,nl,no,ru,sv,zh". }
}
ORDER BY DESC(?date)

It seems to be difficult to sort on such large number of items.

[fnielsen]

This is quick:

# Recently published works from a specific publisher
SELECT DISTINCT ?date ?work ?workLabel 
WITH {
  SELECT ?datetime ?work WHERE {
    ?work wdt:P1433 / wdt:P123 wd:Q746413 .
    ?work wdt:P577 ?datetime . 
  }
  LIMIT 500 
} AS %results
WHERE {
  INCLUDE %results
  BIND(xsd:date(?datetime) AS ?date)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,da,es,fr,jp,nl,no,ru,sv,zh". }
}
ORDER BY DESC(?date)

and too dirty.