WildfireFemaleGenderMod/build.gradle at cc1ba47ab7096d0cd765ad94f8ea34490876fe21 · WildfireRomeo/WildfireFemaleGenderMod · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
plugins {
	id "net.fabricmc.fabric-loom" version "${loom_version}"
}

version = "fabric-${project.mod_version}+${project.minecraft_version}"
group = project.maven_group

base {
	archivesName = project.archives_base_name
}

repositories {
	maven { url = "https://pkgs.dev.azure.com/djtheredstoner/DevAuth/_packaging/public/maven/v1" }
	maven { url = "https://maven.terraformersmc.com/" }
	maven { url = "https://maven.parchmentmc.org/" }
}

dependencies {
	// To change the versions see the gradle.properties file
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	implementation "net.fabricmc:fabric-loader:${project.loader_version}"

	implementation fabricApi.module("fabric-networking-api-v1", project.fabric_version)
	implementation fabricApi.module("fabric-key-mapping-api-v1", project.fabric_version)
	implementation fabricApi.module("fabric-lifecycle-events-v1", project.fabric_version)
	implementation fabricApi.module("fabric-command-api-v2", project.fabric_version)
	implementation fabricApi.module("fabric-rendering-v1", project.fabric_version)
	implementation fabricApi.module("fabric-resource-loader-v1", project.fabric_version)
	runtimeOnly fabricApi.module("fabric-registry-sync-v0", project.fabric_version)

	// Allow logging into an actual Minecraft account in a dev env
	// See https://github.com/DJtheRedstoner/DevAuth
	localRuntime "me.djtheredstoner:DevAuth-fabric:1.2.2"

	// If you want to load Mod Menu in a development environment, change this to implementation
	// and uncomment the associated Fabric API module.
	compileOnly("com.terraformersmc:modmenu:${project.modmenu_version}")
	//runtimeOnly(fabricApi.module("fabric-screen-api-v1", project.fabric_version))
}

processResources {
	inputs.property "version", project.mod_version
	inputs.property "minecraft_version", project.minecraft_version
	inputs.property "minecraft_dependency", project.minecraft_dependency

	filesMatching("fabric.mod.json") {
		expand "version": project.mod_version,
				"minecraft_version": project.minecraft_version,
				"minecraft_dependency": project.minecraft_dependency
	}
}

tasks.withType(JavaCompile).configureEach {
	it.options.release = 25
}

java {
	sourceCompatibility = JavaVersion.VERSION_25
	targetCompatibility = JavaVersion.VERSION_25
}

loom {
	decompilers {
		named("vineflower") {
			options.put("mark-corresponding-synthetics", "1")
		}
	}

	accessWidenerPath = file("src/main/resources/wildfire_gender.accesswidener")
}

jar {
	from("LICENSE") {
		rename { "${it}_${project.property("archives_base_name")}" }
	}
}