umbriel/flake.nix at main · Yocraft-2000/umbriel · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
{
  description = "Umbriel, a Wayland compositor built on wlroots and SceneFX.";

  inputs = {
    self.submodules = true;
    nixpkgs.url = "https://channels.nixos.org/nixos-unstable/nixexprs.tar.xz";
    xdg-desktop-portal-umbriel = {
      url = "github:noctalia-dev/xdg-desktop-portal-umbriel";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      xdg-desktop-portal-umbriel,
      ...
    }:
    let
      systems = [
        "x86_64-linux"
        "aarch64-linux"
      ];

      forEachSystem =
        perSystem: nixpkgs.lib.genAttrs systems (system: perSystem nixpkgs.legacyPackages.${system});

      withDefaultPackage =
        module:
        { pkgs, lib, ... }:
        {
          imports = [ module ];
          programs.umbriel.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.default;
        };
    in
    {
      overlays.default = final: _: {
        umbriel = final.callPackage ./nix/package.nix { };
      };

      packages = forEachSystem (pkgs: {
        default = pkgs.callPackage ./nix/package.nix { };
      });

      devShells = forEachSystem (pkgs: {
        default = pkgs.callPackage ./nix/devshell.nix {
          umbriel = self.packages.${pkgs.stdenv.hostPlatform.system}.default;
        };
      });

      homeModules.default = withDefaultPackage ./nix/home-module.nix;
      hjemModules.default = withDefaultPackage ./nix/hjem-module.nix;
      nixosModules.default = withDefaultPackage (
        import ./nix/nixos-module.nix { inherit xdg-desktop-portal-umbriel; }
      );
    };
}