feat: add dedicated eMode creation to config engine

sakulstra · brotherlymite · kyzia551 · web-flow · commit 19a153133390 · 2025-05-27T09:58:35.000+02:00
eMode creation &amp; eMode updates sharing the same code has been problematic in the past due to concurrent proposals.
The addition of dedicated eMode creation should prevent issues with collisions.

---------

Co-authored-by: Harsh Pandey &lt;harshsatishpandey@gmail.com&gt;
Co-authored-by: Andrey &lt;kyzia.ru@gmail.com&gt;
diff --git a/src/contracts/extensions/v3-config-engine/AaveV3ConfigEngine.sol b/src/contracts/extensions/v3-config-engine/AaveV3ConfigEngine.sol
@@ -175,6 +175,17 @@ contract AaveV3ConfigEngine is IAaveV3ConfigEngine {
     );
   }
 
+  /// @inheritdoc IAaveV3ConfigEngine
+  function createEModeCategories(EModeCategoryCreation[] calldata creations) external {
+    EMODE_ENGINE.functionDelegateCall(
+      abi.encodeWithSelector(
+        EModeEngine.executeEModeCategoriesCreate.selector,
+        _getEngineConstants(),
+        creations
+      )
+    );
+  }
+
   /// @inheritdoc IAaveV3ConfigEngine
   function updateEModeCategories(EModeCategoryUpdate[] calldata updates) external {
     EMODE_ENGINE.functionDelegateCall(
diff --git a/src/contracts/extensions/v3-config-engine/AaveV3Payload.sol b/src/contracts/extensions/v3-config-engine/AaveV3Payload.sol
@@ -42,6 +42,7 @@ abstract contract AaveV3Payload {
   function execute() external {
     _preExecute();
 
+    IEngine.EModeCategoryCreation[] memory newEmodes = eModeCategoryCreations();
     IEngine.EModeCategoryUpdate[] memory eModeCategories = eModeCategoriesUpdates();
     IEngine.Listing[] memory listings = newListings();
     IEngine.ListingWithCustomImpl[] memory listingsCustom = newListingsCustom();
@@ -52,6 +53,12 @@ abstract contract AaveV3Payload {
     IEngine.AssetEModeUpdate[] memory assetsEModes = assetsEModeUpdates();
     IEngine.CapsUpdate[] memory caps = capsUpdates();
 
+    if (newEmodes.length != 0) {
+      address(CONFIG_ENGINE).functionDelegateCall(
+        abi.encodeWithSelector(CONFIG_ENGINE.createEModeCategories.selector, newEmodes)
+      );
+    }
+
     if (eModeCategories.length != 0) {
       address(CONFIG_ENGINE).functionDelegateCall(
         abi.encodeWithSelector(CONFIG_ENGINE.updateEModeCategories.selector, eModeCategories)
@@ -143,6 +150,14 @@ abstract contract AaveV3Payload {
   /// @dev to be defined in the child with a list of priceFeeds to update
   function priceFeedsUpdates() public view virtual returns (IEngine.PriceFeedUpdate[] memory) {}
 
+  /// @dev to be defined in the child with a list of eMode categories to create
+  function eModeCategoryCreations()
+    public
+    view
+    virtual
+    returns (IEngine.EModeCategoryCreation[] memory)
+  {}
+
   /// @dev to be defined in the child with a list of eMode categories to update
   function eModeCategoriesUpdates()
     public
diff --git a/src/contracts/extensions/v3-config-engine/IAaveV3ConfigEngine.sol b/src/contracts/extensions/v3-config-engine/IAaveV3ConfigEngine.sol
@@ -219,6 +219,26 @@ interface IAaveV3ConfigEngine {
     string label;
   }
 
+  /**
+   * @dev Example (mock):
+   * EModeCategoryUpdate({
+   *   ltv: 60_00,
+   *   liqThreshold: 70_00,
+   *   liqBonus: 3_00,
+   *   label: 'WETH USDC',
+   *   borrowables:[USDC],
+   *   collaterals:[ETH]
+   * })
+   */
+  struct EModeCategoryCreation {
+    uint256 ltv;
+    uint256 liqThreshold;
+    uint256 liqBonus;
+    string label;
+    address[] borrowables;
+    address[] collaterals;
+  }
+
   /**
    * @dev Example (mock):
    * RateStrategyUpdate({
@@ -295,6 +315,13 @@ interface IAaveV3ConfigEngine {
    */
   function updateBorrowSide(BorrowUpdate[] memory updates) external;
 
+  /**
+   * @notice Performs creation of new e-mode categories, in the Aave pool configured in this engine instance
+   * @param creations `EModeCategoryCreation[]` list of declarative creations containing the new parameters
+   *   More information on the documentation of the struct.
+   */
+  function createEModeCategories(EModeCategoryCreation[] memory creations) external;
+
   /**
    * @notice Performs an update of the e-mode categories, in the Aave pool configured in this engine instance
    * @param updates `EModeCategoryUpdate[]` list of declarative updates containing the new parameters
diff --git a/src/contracts/extensions/v3-config-engine/libraries/EModeEngine.sol b/src/contracts/extensions/v3-config-engine/libraries/EModeEngine.sol
@@ -11,13 +11,52 @@ library EModeEngine {
   using PercentageMath for uint256;
   using SafeCast for uint256;
 
+  error NoAvailableEmodeCategory();
+
   function executeAssetsEModeUpdate(
     IEngine.EngineConstants calldata engineConstants,
     IEngine.AssetEModeUpdate[] memory updates
   ) external {
     require(updates.length != 0, 'AT_LEAST_ONE_UPDATE_REQUIRED');
 
-    _configAssetsEMode(engineConstants.poolConfigurator, updates);
+    _configAssetsEMode(engineConstants.poolConfigurator, engineConstants.pool, updates);
+  }
+
+  function executeEModeCategoriesCreate(
+    IEngine.EngineConstants calldata engineConstants,
+    IEngine.EModeCategoryCreation[] memory creations
+  ) external {
+    for (uint256 i; i < creations.length; i++) {
+      require(
+        keccak256(abi.encode(creations[i].label)) !=
+          keccak256(abi.encode(EngineFlags.KEEP_CURRENT_STRING)),
+        'INVALID_LABEL'
+      );
+      uint8 categoryId = _findFirstUnusedEmodeCategory(engineConstants.pool);
+      engineConstants.poolConfigurator.setEModeCategory(
+        categoryId,
+        creations[i].ltv.toUint16(),
+        creations[i].liqThreshold.toUint16(),
+        // For reference, this is to simplify the interaction with the Aave protocol,
+        // as there the definition is as e.g. 105% (5% bonus for liquidators)
+        (100_00 + creations[i].liqBonus).toUint16(),
+        creations[i].label
+      );
+      for (uint256 j; j < creations[i].collaterals.length; j++) {
+        engineConstants.poolConfigurator.setAssetCollateralInEMode(
+          creations[i].collaterals[j],
+          categoryId,
+          true
+        );
+      }
+      for (uint256 k; k < creations[i].borrowables.length; k++) {
+        engineConstants.poolConfigurator.setAssetBorrowableInEMode(
+          creations[i].borrowables[k],
+          categoryId,
+          true
+        );
+      }
+    }
   }
 
   function executeEModeCategoriesUpdate(
@@ -31,9 +70,14 @@ library EModeEngine {
 
   function _configAssetsEMode(
     IPoolConfigurator poolConfigurator,
+    IPool pool,
     IEngine.AssetEModeUpdate[] memory updates
   ) internal {
     for (uint256 i = 0; i < updates.length; i++) {
+      DataTypes.CollateralConfig memory cfg = pool.getEModeCategoryCollateralConfig(
+        updates[i].eModeCategory
+      );
+      require(cfg.liquidationThreshold != 0, 'INVALID_UPDATE');
       if (updates[i].collateral != EngineFlags.KEEP_CURRENT) {
         poolConfigurator.setAssetCollateralInEMode(
           updates[i].asset,
@@ -69,11 +113,13 @@ library EModeEngine {
         keccak256(abi.encode(updates[i].label)) !=
         keccak256(abi.encode(EngineFlags.KEEP_CURRENT_STRING));
 
-      if (notAllKeepCurrent && atLeastOneKeepCurrent) {
-        DataTypes.CollateralConfig memory cfg = pool.getEModeCategoryCollateralConfig(
-          updates[i].eModeCategory
-        );
+      DataTypes.CollateralConfig memory cfg = pool.getEModeCategoryCollateralConfig(
+        updates[i].eModeCategory
+      );
+      // should only be able to update existing eModes, not create new ones
+      require(cfg.liquidationThreshold != 0, 'INVALID_UPDATE');
 
+      if (notAllKeepCurrent && atLeastOneKeepCurrent) {
         if (updates[i].ltv == EngineFlags.KEEP_CURRENT) {
           updates[i].ltv = cfg.ltv;
         }
@@ -114,4 +160,15 @@ library EModeEngine {
       }
     }
   }
+
+  /**
+   * @dev eModes must have a non-zero lt so we select the first that has a zero lt.
+   */
+  function _findFirstUnusedEmodeCategory(IPool pool) private view returns (uint8) {
+    // eMode id 0 is skipped intentially as it is the reserved default
+    for (uint8 i = 1; i < 256; i++) {
+      if (pool.getEModeCategoryCollateralConfig(i).liquidationThreshold == 0) return i;
+    }
+    revert NoAvailableEmodeCategory();
+  }
 }
diff --git a/tests/extensions/v3-config-engine/AaveV3ConfigEngineTest.t.sol b/tests/extensions/v3-config-engine/AaveV3ConfigEngineTest.t.sol
@@ -17,6 +17,7 @@ import {AaveV3MockPriceFeedUpdate} from './mocks/AaveV3MockPriceFeedUpdate.sol';
 import {AaveV3MockEModeCategoryUpdate, AaveV3MockEModeCategoryUpdateEdgeBonus} from './mocks/AaveV3MockEModeCategoryUpdate.sol';
 import {AaveV3MockEModeCategoryUpdateNoChange} from './mocks/AaveV3MockEModeCategoryUpdateNoChange.sol';
 import {AaveV3MockAssetEModeUpdate} from './mocks/AaveV3MockAssetEModeUpdate.sol';
+import {AaveV3MockEModeCategoryCreation} from './mocks/AaveV3MockEModeCategoryCreation.sol';
 
 import {ATokenInstance} from '../../../src/contracts/instances/ATokenInstance.sol';
 import {EModeConfiguration} from '../../../src/contracts/protocol/libraries/configuration/EModeConfiguration.sol';
@@ -507,14 +508,59 @@ contract AaveV3ConfigEngineTest is TestnetProcedures, ProtocolV3TestBase {
     );
   }
 
+  function testEModeCategoryCreation() public {
+    AaveV3MockEModeCategoryCreation payload = new AaveV3MockEModeCategoryCreation(
+      tokenList.weth,
+      tokenList.usdx,
+      tokenList.wbtc,
+      tokenList.weth,
+      configEngine
+    );
+
+    vm.prank(roleList.marketOwner);
+    contracts.aclManager.addPoolAdmin(address(payload));
+
+    payload.execute();
+
+    DataTypes.EModeCategory memory prevEmodeCategoryData;
+    prevEmodeCategoryData.ltv = 50_00;
+    prevEmodeCategoryData.liquidationThreshold = 60_00;
+    prevEmodeCategoryData.liquidationBonus = 101_00; // 100_00 + 1_00
+    prevEmodeCategoryData.label = 'No assets';
+
+    uint256 bitmap = contracts.poolProxy.getEModeCategoryBorrowableBitmap(1);
+    assertEq(bitmap, 0);
+    bitmap = contracts.poolProxy.getEModeCategoryCollateralBitmap(1);
+    assertEq(bitmap, 0);
+    _validateEmodeCategory(
+      IPoolAddressesProvider(address(contracts.poolAddressesProvider)),
+      1,
+      prevEmodeCategoryData
+    );
+
+    prevEmodeCategoryData.ltv = 97_40;
+    prevEmodeCategoryData.liquidationThreshold = 97_60;
+    prevEmodeCategoryData.liquidationBonus = 101_50; // 100_00 + 1_50
+    prevEmodeCategoryData.label = 'Test';
+    prevEmodeCategoryData.collateralBitmap = 10; // 1010
+    prevEmodeCategoryData.borrowableBitmap = 12; // 1100
+    _validateEmodeCategory(
+      IPoolAddressesProvider(address(contracts.poolAddressesProvider)),
+      2,
+      prevEmodeCategoryData
+    );
+  }
+
   function testEModeCategoryUpdates() public {
+    EModeCategoryInput memory ct = _genCategoryOne();
+    vm.prank(poolAdmin);
+    contracts.poolConfiguratorProxy.setEModeCategory(ct.id, ct.ltv, ct.lt, ct.lb, ct.label);
+
     AaveV3MockEModeCategoryUpdate payload = new AaveV3MockEModeCategoryUpdate(configEngine);
 
     vm.prank(roleList.marketOwner);
     contracts.aclManager.addPoolAdmin(address(payload));
 
-    contracts.poolProxy.getEModeCategoryData(1);
-
     createConfigurationSnapshot(
       'preTestEngineEModeCategoryUpdate',
       IPool(address(contracts.poolProxy))
@@ -543,6 +589,10 @@ contract AaveV3ConfigEngineTest is TestnetProcedures, ProtocolV3TestBase {
   }
 
   function testEModeCategoryUpdatesWrongBonus() public {
+    EModeCategoryInput memory ct = _genCategoryOne();
+    vm.prank(poolAdmin);
+    contracts.poolConfiguratorProxy.setEModeCategory(ct.id, ct.ltv, ct.lt, ct.lb, ct.label);
+
     AaveV3MockEModeCategoryUpdateEdgeBonus payload = new AaveV3MockEModeCategoryUpdateEdgeBonus(
       configEngine
     );
@@ -556,6 +606,10 @@ contract AaveV3ConfigEngineTest is TestnetProcedures, ProtocolV3TestBase {
 
   // TODO manage this after testFail* deprecation.
   function testEModeCategoryUpdatesNoChangeShouldNotEmit() public {
+    EModeCategoryInput memory ct = _genCategoryOne();
+    vm.prank(poolAdmin);
+    contracts.poolConfiguratorProxy.setEModeCategory(ct.id, ct.ltv, ct.lt, ct.lb, ct.label);
+
     AaveV3MockEModeCategoryUpdateNoChange payload = new AaveV3MockEModeCategoryUpdateNoChange(
       configEngine
     );
@@ -571,6 +625,9 @@ contract AaveV3ConfigEngineTest is TestnetProcedures, ProtocolV3TestBase {
 
   // Same as testEModeCategoryUpdatesNoChangeShouldNotEmit, but this time should work, as we are not expecting any event emitted
   function testEModeCategoryUpdatesNoChange() public {
+    EModeCategoryInput memory ct = _genCategoryOne();
+    vm.prank(poolAdmin);
+    contracts.poolConfiguratorProxy.setEModeCategory(ct.id, ct.ltv, ct.lt, ct.lb, ct.label);
     AaveV3MockEModeCategoryUpdateNoChange payload = new AaveV3MockEModeCategoryUpdateNoChange(
       configEngine
     );
@@ -610,12 +667,12 @@ contract AaveV3ConfigEngineTest is TestnetProcedures, ProtocolV3TestBase {
   }
 
   function testAssetEModeUpdates() public {
+    vm.prank(poolAdmin);
+    contracts.poolConfiguratorProxy.setEModeCategory(1, 97_40, 97_60, 101_50, 'ETH Correlated');
+
     address asset = tokenList.usdx;
     address asset2 = tokenList.wbtc;
 
-    AaveV3MockEModeCategoryUpdate payloadToAddEMode = new AaveV3MockEModeCategoryUpdate(
-      configEngine
-    );
     AaveV3MockAssetEModeUpdate payload = new AaveV3MockAssetEModeUpdate(
       asset,
       asset2,
@@ -624,11 +681,8 @@ contract AaveV3ConfigEngineTest is TestnetProcedures, ProtocolV3TestBase {
 
     vm.startPrank(roleList.marketOwner);
     contracts.aclManager.addPoolAdmin(address(payload));
-    contracts.aclManager.addPoolAdmin(address(payloadToAddEMode));
     vm.stopPrank();
 
-    payloadToAddEMode.execute();
-
     createConfigurationSnapshot(
       'preTestEngineAssetEModeUpdate',
       IPool(address(contracts.poolProxy))
diff --git a/tests/extensions/v3-config-engine/mocks/AaveV3MockEModeCategoryCreation.sol b/tests/extensions/v3-config-engine/mocks/AaveV3MockEModeCategoryCreation.sol
@@ -0,0 +1,71 @@
+// SPDX-License-Identifier: BUSL-1.1
+pragma solidity ^0.8.0;
+
+import '../../../../src/contracts/extensions/v3-config-engine/AaveV3Payload.sol';
+
+/**
+ * @dev Smart contract for a mock emode category update, to be able to test
+ * IMPORTANT Parameters are pseudo-random, DON'T USE THIS ANYHOW IN PRODUCTION
+ * @dev Inheriting directly from AaveV3Payload for being able to inject a custom engine
+ * @author BGD Labs
+ */
+contract AaveV3MockEModeCategoryCreation is AaveV3Payload {
+  address immutable COLLATERAL_ONE;
+  address immutable COLLATERAL_TWO;
+
+  address immutable BORROWABLE_ONE;
+  address immutable BORROWABLE_TWO;
+
+  constructor(
+    address collateral1,
+    address collateral2,
+    address borrowable1,
+    address borrowable2,
+    address customEngine
+  ) AaveV3Payload(IEngine(customEngine)) {
+    COLLATERAL_ONE = collateral1;
+    COLLATERAL_TWO = collateral2;
+    BORROWABLE_ONE = borrowable1;
+    BORROWABLE_TWO = borrowable2;
+  }
+
+  function eModeCategoryCreations()
+    public
+    view
+    override
+    returns (IEngine.EModeCategoryCreation[] memory)
+  {
+    IEngine.EModeCategoryCreation[] memory eModeUpdates = new IEngine.EModeCategoryCreation[](2);
+
+    address[] memory empty = new address[](0);
+
+    eModeUpdates[0] = IEngine.EModeCategoryCreation({
+      ltv: 50_00,
+      liqThreshold: 60_00,
+      liqBonus: 1_00,
+      label: 'No assets',
+      borrowables: empty,
+      collaterals: empty
+    });
+    address[] memory collaterals = new address[](2);
+    address[] memory borrowables = new address[](2);
+    collaterals[0] = COLLATERAL_ONE;
+    collaterals[1] = COLLATERAL_TWO;
+    borrowables[0] = BORROWABLE_ONE;
+    borrowables[1] = BORROWABLE_TWO;
+    eModeUpdates[1] = IEngine.EModeCategoryCreation({
+      ltv: 97_40,
+      liqThreshold: 97_60,
+      liqBonus: 1_50,
+      label: 'Test',
+      borrowables: borrowables,
+      collaterals: collaterals
+    });
+
+    return eModeUpdates;
+  }
+
+  function getPoolContext() public pure override returns (IEngine.PoolContext memory) {
+    return IEngine.PoolContext({networkName: 'Polygon', networkAbbreviation: 'Pol'});
+  }
+}
diff --git a/tests/protocol/tokenization/ATokenTransfers.t.sol b/tests/protocol/tokenization/ATokenTransfers.t.sol
diff --git a/tests/utils/ProtocolV3TestBase.sol b/tests/utils/ProtocolV3TestBase.sol
