feat: Phase Two Asset Listing

Makefile

@@ -92,6 +92,14 @@ deploy-liquidation-data-provider :;
 		--sig "run(address,address)" ${pool} ${addressesProvider} \
 		--verify --broadcast
 
+# Deploys payload to update phase two assets. `make deploy-phase-two-payload CHAIN=mainnet ACCOUNT=<account>`
+deploy-phase-two-payload :;
+	FOUNDRY_PROFILE=${CHAIN} forge script scripts/misc/DeployHorizonPhaseTwoPayload.sol:DeployHorizonPhaseTwoPayload \
+		--rpc-url ${CHAIN} --account ${ACCOUNT} --slow --gas-estimate-multiplier 150 \
+		--chain ${CHAIN} --verifier-url ${VERIFIER_URL} \
+		--sig "run()" \
+		--verify --broadcast \
+
 # Invariants
 echidna:
 	echidna tests/invariants/Tester.t.sol --contract Tester --config ./tests/invariants/_config/echidna_config.yaml --corpus-dir ./tests/invariants/_corpus/echidna/default/_data/corpus

foundry.lock

@@ -0,0 +1,14 @@
+{
+  "lib/solidity-utils": {
+    "rev": "627712ae49771530594bc6ea0eb384544979d4ca"
+  },
+  "lib/forge-std": {
+    "rev": "999be66ec94c78090087f674bbf52ce1cca12b75"
+  },
+  "lib/aave-address-book": {
+    "tag": {
+      "name": "v4.36.0",
+      "rev": "6cb3a0f32db8c85115c2c7434c0e5644f18e11ff"
+    }
+  }
+}

foundry.toml

@@ -43,6 +43,7 @@ base = "${RPC_BASE}"
 metis = "${RPC_METIS}"
 linea = "${RPC_LINEA}"
 sepolia = "${RPC_SEPOLIA}"
+vtestnet = "${RPC_VTESTNET}"
 
 [etherscan]
 mainnet = { key = "${ETHERSCAN_API_KEY}", chainId = 1 }

scripts/misc/DeployHorizonPhaseTwoPayload.sol

@@ -0,0 +1,31 @@
+// SPDX-License-Identifier: BUSL-1.1
+pragma solidity ^0.8.0;
+
+import {AaveV3EthereumHorizonCustom} from 'tests/horizon/utils/AaveV3EthereumHorizonCustom.sol';
+import {HorizonPhaseTwoListing} from 'src/deployments/inputs/HorizonPhaseTwoListing.sol';
+import {AaveV3HelpersBatchOne} from 'src/deployments/projects/aave-v3-batched/batches/AaveV3HelpersBatchOne.sol';
+import {AaveV3ConfigEngine} from 'src/contracts/extensions/v3-config-engine/AaveV3ConfigEngine.sol';
+import {Script} from 'forge-std/Script.sol';
+
+contract DeployHorizonPhaseTwoPayload is Script {
+  function run() public returns (address, address) {
+    vm.startBroadcast();
+    AaveV3HelpersBatchOne helpersBatchOne = new AaveV3HelpersBatchOne(
+      AaveV3EthereumHorizonCustom.POOL,
+      AaveV3EthereumHorizonCustom.POOL_CONFIGURATOR,
+      AaveV3EthereumHorizonCustom.DEFAULT_INTEREST_RATE_STRATEGY,
+      AaveV3EthereumHorizonCustom.AAVE_ORACLE,
+      AaveV3EthereumHorizonCustom.REWARDS_CONTROLLER,
+      AaveV3EthereumHorizonCustom.REVENUE_SPLITTER,
+      AaveV3EthereumHorizonCustom.ATOKEN_IMPL,
+      AaveV3EthereumHorizonCustom.VARIABLE_DEBT_TOKEN_IMPL
+    );
+
+    HorizonPhaseTwoListing horizonPhaseTwoListing = new HorizonPhaseTwoListing(
+      helpersBatchOne.getConfigEngineReport().configEngine
+    );
+    vm.stopBroadcast();
+
+    return (address(helpersBatchOne), address(horizonPhaseTwoListing));
+  }
+}

src/deployments/inputs/HorizonPhaseTwoListing.sol

@@ -0,0 +1,101 @@
+// SPDX-License-Identifier: BUSL-1.1
+pragma solidity ^0.8.0;
+
+import {IAaveV3ConfigEngine as IEngine} from '../../contracts/extensions/v3-config-engine/IAaveV3ConfigEngine.sol';
+import {EngineFlags} from '../../contracts/extensions/v3-config-engine/EngineFlags.sol';
+import {AaveV3Payload} from '../../contracts/extensions/v3-config-engine/AaveV3Payload.sol';
+
+import {AaveV3EthereumHorizonCustom} from 'tests/horizon/utils/AaveV3EthereumHorizonCustom.sol';
+
+contract HorizonPhaseTwoListing is AaveV3Payload {
+  constructor(address configEngine) AaveV3Payload(IEngine(configEngine)) {}
+
+  function eModeCategoriesUpdates()
+    public
+    pure
+    override
+    returns (IEngine.EModeCategoryUpdate[] memory)
+  {
+    IEngine.EModeCategoryUpdate[] memory eModeCategories = new IEngine.EModeCategoryUpdate[](1);
+
+    // VBILL GHO
+    eModeCategories[0] = IEngine.EModeCategoryUpdate({
+      eModeCategory: 1, // overwrite previous empty eMode category
+      ltv: 84_00,
+      liqThreshold: 89_00,
+      liqBonus: 3_00,
+      label: 'VBILL GHO'
+    });
+
+    return eModeCategories;
+  }
+
+  function newListingsCustom()
+    public
+    view
+    override
+    returns (IEngine.ListingWithCustomImpl[] memory)
+  {
+    IEngine.ListingWithCustomImpl[] memory listingsCustom = new IEngine.ListingWithCustomImpl[](1);
+
+    listingsCustom[0] = IEngine.ListingWithCustomImpl(
+      IEngine.Listing({
+        asset: AaveV3EthereumHorizonCustom.VBILL_UNDERLYING,
+        assetSymbol: 'VBILL',
+        priceFeed: AaveV3EthereumHorizonCustom.VBILL_PRICE_FEED,
+        rateStrategyParams: IEngine.InterestRateInputData({
+          optimalUsageRatio: 99_00,
+          baseVariableBorrowRate: 0,
+          variableRateSlope1: 0,
+          variableRateSlope2: 0
+        }),
+        enabledToBorrow: EngineFlags.DISABLED,
+        borrowableInIsolation: EngineFlags.DISABLED,
+        withSiloedBorrowing: EngineFlags.DISABLED,
+        flashloanable: EngineFlags.DISABLED,
+        ltv: 83_00,
+        liqThreshold: 88_00,
+        liqBonus: 3_00,
+        reserveFactor: EngineFlags.KEEP_CURRENT,
+        supplyCap: 15_000_000,
+        borrowCap: 0,
+        debtCeiling: 0,
+        liqProtocolFee: 0
+      }),
+      IEngine.TokenImplementations({
+        aToken: AaveV3EthereumHorizonCustom.RWA_ATOKEN_IMPL,
+        vToken: AaveV3EthereumHorizonCustom.VARIABLE_DEBT_TOKEN_IMPL
+      })
+    );
+
+    return listingsCustom;
+  }
+
+  function assetsEModeUpdates() public view override returns (IEngine.AssetEModeUpdate[] memory) {
+    IEngine.AssetEModeUpdate[] memory assetsEMode = new IEngine.AssetEModeUpdate[](2);
+
+    uint256 index = 0;
+
+    // Overwrite empty eMode category 1
+    assetsEMode[index++] = IEngine.AssetEModeUpdate({
+      asset: AaveV3EthereumHorizonCustom.VBILL_UNDERLYING,
+      eModeCategory: 1,
+      collateral: EngineFlags.ENABLED,
+      borrowable: EngineFlags.DISABLED
+    });
+    assetsEMode[index++] = IEngine.AssetEModeUpdate({
+      asset: AaveV3EthereumHorizonCustom.GHO_UNDERLYING,
+      eModeCategory: 1,
+      collateral: EngineFlags.DISABLED,
+      borrowable: EngineFlags.ENABLED
+    });
+
+    assert(index == assetsEMode.length);
+
+    return assetsEMode;
+  }
+
+  function getPoolContext() public pure override returns (IEngine.PoolContext memory) {
+    return IEngine.PoolContext({networkName: 'Horizon RWA', networkAbbreviation: 'HorRwa'});
+  }
+}