feat: temporary approvals in AllowancePositionManager

Author: avniculae

snapshots/PositionManager.Operations.json

@@ -1,7 +1,7 @@
 {
-  "AllowancePositionManager - borrowOnBehalfOf": "306478",
-  "AllowancePositionManager - withdrawOnBehalfOf: full": "121565",
-  "AllowancePositionManager - withdrawOnBehalfOf: partial": "131756",
+  "AllowancePositionManager - borrowOnBehalfOf": "307050",
+  "AllowancePositionManager - withdrawOnBehalfOf: full": "122024",
+  "AllowancePositionManager - withdrawOnBehalfOf: partial": "132329",
   "Common - setSelfAsUserPositionManagerWithSig": "72588",
   "SupplyRepayPositionManager - repayOnBehalfOf": "167131",
   "SupplyRepayPositionManager - supplyOnBehalfOf": "135803"

src/position-manager/AllowancePositionManager.sol

@@ -4,6 +4,8 @@ pragma solidity 0.8.28;
 
 import {SignatureChecker} from 'src/dependencies/openzeppelin/SignatureChecker.sol';
 import {SafeERC20, IERC20} from 'src/dependencies/openzeppelin/SafeERC20.sol';
+import {SlotDerivation} from 'src/dependencies/openzeppelin/SlotDerivation.sol';
+import {TransientSlot} from 'src/dependencies/openzeppelin/TransientSlot.sol';
 import {EIP712} from 'src/dependencies/solady/EIP712.sol';
 import {MathUtils} from 'src/libraries/math/MathUtils.sol';
 import {NoncesKeyed} from 'src/utils/NoncesKeyed.sol';
@@ -24,15 +26,27 @@ contract AllowancePositionManager is
   using SafeERC20 for IERC20;
   using EIP712Hash for *;
   using MathUtils for uint256;
+  using SlotDerivation for bytes32;
+  using TransientSlot for *;
 
   /// @notice Mapping of withdraw allowances.
   mapping(address owner => mapping(address spender => mapping(uint256 reserveId => uint256 amount)))
     private _withdrawAllowances;
 
+  /// @notice Slot for the temporary withdraw allowances.
+  /// @dev keccak256('temporary.withdrawAllowances')
+  bytes32 private constant _TEMPORARY_WITHDRAW_ALLOWANCES_SLOT =
+    0x1c6a61279a13a86a789311ddf30aee38e2f4a9f6c4aad1ff4a2e75a4018e68c3;
+
   /// @notice Mapping of credit delegations.
   mapping(address owner => mapping(address spender => mapping(uint256 reserveId => uint256 amount)))
     private _creditDelegations;
 
+  /// @notice Slot for the temporary credit delegations.
+  /// @dev keccak256('temporary.creditDelegations')
+  bytes32 private constant _TEMPORARY_CREDIT_DELEGATIONS_SLOT =
+    0xcd470af8670f5baa744a0341af8a2e3f5d7ca086178908432a5cfaf39cb9299d;
+
   /// @dev Constructor.
   /// @param spoke_ The address of the spoke contract.
   constructor(address spoke_) PositionManagerBase(spoke_) {}
@@ -58,6 +72,11 @@ contract AllowancePositionManager is
     emit WithdrawApproval(user, params.spender, params.reserveId, params.amount);
   }
 
+  /// @inheritdoc IAllowancePositionManager
+  function temporaryApproveWithdraw(address spender, uint256 reserveId, uint256 amount) external {
+    _temporaryWithdrawAllowancesSlot(msg.sender, spender, reserveId).tstore(amount);
+  }
+
   /// @inheritdoc IAllowancePositionManager
   function approveCreditDelegation(address spender, uint256 reserveId, uint256 amount) external {
     _creditDelegations[msg.sender][spender][reserveId] = amount;
@@ -79,6 +98,15 @@ contract AllowancePositionManager is
     emit CreditDelegation(user, params.spender, params.reserveId, params.amount);
   }
 
+  /// @inheritdoc IAllowancePositionManager
+  function temporaryApproveCreditDelegation(
+    address spender,
+    uint256 reserveId,
+    uint256 amount
+  ) external {
+    _temporaryCreditDelegationsSlot(msg.sender, spender, reserveId).tstore(amount);
+  }
+
   /// @inheritdoc IAllowancePositionManager
   function renounceWithdrawAllowance(address owner, uint256 reserveId) external {
     _withdrawAllowances[owner][msg.sender][reserveId] = 0;
@@ -98,9 +126,7 @@ contract AllowancePositionManager is
     address onBehalfOf
   ) external returns (uint256, uint256) {
     require(amount > 0, InvalidAmount());
-    uint256 currentAllowance = _withdrawAllowances[onBehalfOf][msg.sender][reserveId];
-    require(currentAllowance >= amount, InsufficientWithdrawAllowance(currentAllowance, amount));
-    _withdrawAllowances[onBehalfOf][msg.sender][reserveId] = currentAllowance.uncheckedSub(amount);
+    _spendWithdrawAllowance(onBehalfOf, msg.sender, reserveId, amount);
 
     IERC20 asset = _getReserveUnderlying(reserveId);
     (uint256 withdrawnShares, uint256 withdrawnAmount) = ISpokeBase(SPOKE).withdraw(
@@ -120,9 +146,7 @@ contract AllowancePositionManager is
     address onBehalfOf
   ) external returns (uint256, uint256) {
     require(amount > 0, InvalidAmount());
-    uint256 currentAllowance = _creditDelegations[onBehalfOf][msg.sender][reserveId];
-    require(currentAllowance >= amount, InsufficientCreditDelegation(currentAllowance, amount));
-    _creditDelegations[onBehalfOf][msg.sender][reserveId] = currentAllowance.uncheckedSub(amount);
+    _spendCreditDelegation(onBehalfOf, msg.sender, reserveId, amount);
 
     IERC20 asset = _getReserveUnderlying(reserveId);
     (uint256 borrowedShares, uint256 borrowedAmount) = ISpokeBase(SPOKE).borrow(
@@ -171,4 +195,78 @@ contract AllowancePositionManager is
   function _domainNameAndVersion() internal pure override returns (string memory, string memory) {
     return ('AllowancePositionManager', '1');
   }
+
+  /// @dev Temporary allowance takes precedence over stored allowance, and does not cumulate.
+  function _spendWithdrawAllowance(
+    address onBehalfOf,
+    address spender,
+    uint256 reserveId,
+    uint256 amount
+  ) internal {
+    uint256 temporaryAllowance = _temporaryWithdrawAllowancesSlot(onBehalfOf, spender, reserveId)
+      .tload();
+    if (temporaryAllowance > 0) {
+      require(
+        temporaryAllowance >= amount,
+        InsufficientWithdrawAllowance(temporaryAllowance, amount)
+      );
+      _temporaryWithdrawAllowancesSlot(onBehalfOf, spender, reserveId).tstore(
+        temporaryAllowance.uncheckedSub(amount)
+      );
+    } else {
+      uint256 allowance = _withdrawAllowances[onBehalfOf][spender][reserveId];
+      require(allowance >= amount, InsufficientWithdrawAllowance(allowance, amount));
+      _withdrawAllowances[onBehalfOf][spender][reserveId] = allowance.uncheckedSub(amount);
+    }
+  }
+
+  /// @dev Temporary allowance takes precedence over stored allowance, and does not cumulate.
+  function _spendCreditDelegation(
+    address onBehalfOf,
+    address spender,
+    uint256 reserveId,
+    uint256 amount
+  ) internal {
+    uint256 temporaryAllowance = _temporaryCreditDelegationsSlot(onBehalfOf, spender, reserveId)
+      .tload();
+    if (temporaryAllowance > 0) {
+      require(
+        temporaryAllowance >= amount,
+        InsufficientCreditDelegation(temporaryAllowance, amount)
+      );
+      _temporaryCreditDelegationsSlot(onBehalfOf, spender, reserveId).tstore(
+        temporaryAllowance.uncheckedSub(amount)
+      );
+    } else {
+      uint256 allowance = _creditDelegations[onBehalfOf][spender][reserveId];
+      require(allowance >= amount, InsufficientCreditDelegation(allowance, amount));
+      _creditDelegations[onBehalfOf][spender][reserveId] = allowance.uncheckedSub(amount);
+    }
+  }
+
+  function _temporaryWithdrawAllowancesSlot(
+    address owner,
+    address spender,
+    uint256 reserveId
+  ) internal pure returns (TransientSlot.Uint256Slot) {
+    return
+      _TEMPORARY_WITHDRAW_ALLOWANCES_SLOT
+        .deriveMapping(owner)
+        .deriveMapping(spender)
+        .deriveMapping(reserveId)
+        .asUint256();
+  }
+
+  function _temporaryCreditDelegationsSlot(
+    address owner,
+    address spender,
+    uint256 reserveId
+  ) internal pure returns (TransientSlot.Uint256Slot) {
+    return
+      _TEMPORARY_CREDIT_DELEGATIONS_SLOT
+        .deriveMapping(owner)
+        .deriveMapping(spender)
+        .deriveMapping(reserveId)
+        .asUint256();
+  }
 }

src/position-manager/interfaces/IAllowancePositionManager.sol

@@ -44,6 +44,13 @@ interface IAllowancePositionManager is IPositionManagerBase {
     bytes calldata signature
   ) external;
 
+  /// @notice Temporarily approves a spender to withdraw assets from the specified reserve on the spoke.
+  /// @dev The allowance is discarded after the transaction.
+  /// @param spender The address of the spender to receive the allowance.
+  /// @param reserveId The identifier of the reserve.
+  /// @param amount The amount of allowance.
+  function temporaryApproveWithdraw(address spender, uint256 reserveId, uint256 amount) external;
+
   /// @notice Approves a credit delegation allowance for a spender.
   /// @param spender The address of the spender to receive the allowance.
   /// @param reserveId The identifier of the reserve.
@@ -58,6 +65,17 @@ interface IAllowancePositionManager is IPositionManagerBase {
     bytes calldata signature
   ) external;
 
+  /// @notice Temporarily approves a credit delegation allowance for a spender.
+  /// @dev The allowance is discarded after the transaction.
+  /// @param spender The address of the spender to receive the allowance.
+  /// @param reserveId The identifier of the reserve.
+  /// @param amount The amount of allowance.
+  function temporaryApproveCreditDelegation(
+    address spender,
+    uint256 reserveId,
+    uint256 amount
+  ) external;
+
   /// @notice Renounces the withdraw allowance given by the owner.
   /// @param owner The address of the owner.
   /// @param reserveId The identifier of the reserve.

tests/mocks/AllowancePositionManagerWrapper.sol

@@ -0,0 +1,28 @@
+// SPDX-License-Identifier: UNLICENSED
+// Copyright (c) 2025 Aave Labs
+pragma solidity ^0.8.0;
+
+import {TransientSlot} from 'src/dependencies/openzeppelin/TransientSlot.sol';
+import {AllowancePositionManager} from 'src/position-manager/AllowancePositionManager.sol';
+
+contract AllowancePositionManagerWrapper is AllowancePositionManager {
+  using TransientSlot for *;
+
+  constructor(address spoke_) AllowancePositionManager(spoke_) {}
+
+  function temporaryWithdrawAllowance(
+    address owner,
+    address spender,
+    uint256 reserveId
+  ) external view returns (uint256) {
+    return _temporaryWithdrawAllowancesSlot(owner, spender, reserveId).tload();
+  }
+
+  function temporaryCreditDelegation(
+    address owner,
+    address spender,
+    uint256 reserveId
+  ) external view returns (uint256) {
+    return _temporaryCreditDelegationsSlot(owner, spender, reserveId).tload();
+  }
+}