PageInfo needs to be shareable in GraphQL Federation

[zche-theScore]

Hi folks,

I want to use absinthe_relay in a GraphQL Federation subgraph.

However, as explained here, PageInfo must be declared as @shareable.

I am using absinthe_federation, and I wanted to add shareable to the PageInfo type.

Is there a way to do this in my own project without touching the libraries? Thanks!!!

[kzlsakal]

As a workaround, we use a pipeline modifier to add the shareable directive to the PageInfo object if it exists. You can find more information about the usage of those here.

Essentially what you'd want to do is prewalking the blueprint and if the object matches with %Absinthe.Blueprint.Schema.ObjectTypeDefinition{name: "PageInfo"} pattern, you'd want to inject %Absinthe.Blueprint.Directive{name: "shareable"} in the directives.

Since the shareable directive doesn't exist in non-federated graphs, it's understandable to not have it in the page_info definition in this library.

[chazsconi]

I had the same issue. To fix it using the above suggestion I did the following:

defmodule Web.GraphQL.MySchema do
  use Absinthe.Schema
  use Absinthe.Relay.Schema, :modern
  @pipeline_modifier __MODULE__.CustomSchemaPhase
  ...


  defmodule CustomSchemaPhase do
    @moduledoc false
    alias Absinthe.{Blueprint, Phase, Pipeline}

    def pipeline(pipeline) do
      Pipeline.insert_after(pipeline, Phase.Schema.TypeImports, __MODULE__)
    end

    def run(%Blueprint{} = blueprint, _) do
      blueprint =
        Blueprint.prewalk(blueprint, fn
          %Absinthe.Blueprint.Schema.ObjectTypeDefinition{
            name: "PageInfo"
          } = node ->
            %Absinthe.Blueprint.Schema.ObjectTypeDefinition{
              node
              | directives: [%Absinthe.Blueprint.Directive{name: "shareable"} | node.directives]
            }

          node ->
            node
        end)

      {:ok, blueprint}
    end
  end
end

[aaronrenner]

It also works to add the following lines in the schema

  defmodule MySchema do
    use Absinthe.Federation.Schema
    use Absinthe.Schema.Schema
    use Absinthe.Relay.Schema

    # ...

+   extend object :page_info do
+     shareable()
+   end
  end

That generates the following SDL

type PageInfo @shareable {
  "When paginating backwards, are there more items?"
  hasPreviousPage: Boolean!

  "When paginating forwards, are there more items?"
  hasNextPage: Boolean!

  "When paginating backwards, the cursor to continue."
  startCursor: String

  "When paginating forwards, the cursor to continue."
  endCursor: String
}