circuitpython/ports/zephyr-cp/boards/board_aliases.cmake at abbd8b054a05a53654358b138d705f23bc03d97c · adafruit/circuitpython · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
# Workaround for Zephyr alias handling with BOARD_QUALIFIERS in newer Zephyr.
#
# Instead of using <alias>_BOARD_ALIAS variables, translate BOARD directly so
# we don't end up with a spurious trailing '/' in BOARD_QUALIFIERS.
macro(cp_board_alias alias target)
  if(BOARD STREQUAL "${alias}")
    if(NOT "${target}" MATCHES "^([^@/]+)(@[^@/]+)?(/([^@]+))?$")
      message(FATAL_ERROR "Invalid alias target '${target}'")
    endif()

    set(BOARD_ALIAS "${alias}" CACHE STRING "Board alias, provided by user")
    set(BOARD "${CMAKE_MATCH_1}")

    if(CMAKE_MATCH_2)
      string(REPLACE "@" "" _rev "${CMAKE_MATCH_2}")
      set(BOARD_REVISION "${_rev}")
    else()
      unset(BOARD_REVISION)
    endif()

    if(CMAKE_MATCH_4)
      set(BOARD_QUALIFIERS "${CMAKE_MATCH_4}")
    else()
      unset(BOARD_QUALIFIERS)
    endif()
  endif()
endmacro()

cp_board_alias(pca10056 nrf52840dk/nrf52840)
cp_board_alias(adafruit_feather_nrf52840_zephyr adafruit_feather_nrf52840/nrf52840/uf2)
cp_board_alias(renesas_ek_ra6m5 ek_ra6m5)
cp_board_alias(renesas_ek_ra8d1 ek_ra8d1)
cp_board_alias(renesas_da14695_dk_usb da14695_dk_usb)
cp_board_alias(native_native_sim native_sim/native)
cp_board_alias(native_nrf5340bsim nrf5340bsim/nrf5340/cpuapp)
cp_board_alias(nordic_nrf54l15dk nrf54l15dk/nrf54l15/cpuapp)
cp_board_alias(nordic_nrf54h20dk nrf54h20dk/nrf54h20/cpuapp)
cp_board_alias(nordic_nrf5340dk nrf5340dk/nrf5340/cpuapp)
cp_board_alias(nordic_nrf7002dk nrf7002dk/nrf5340/cpuapp)
cp_board_alias(nxp_frdm_mcxn947 frdm_mcxn947/mcxn947/cpu0)
cp_board_alias(nxp_frdm_rw612 frdm_rw612)
cp_board_alias(nxp_mimxrt1170_evk mimxrt1170_evk@A/mimxrt1176/cm7)
cp_board_alias(st_stm32h7b3i_dk stm32h7b3i_dk)
cp_board_alias(st_stm32h750b_dk stm32h750b_dk/stm32h750xx/ext_flash_app)
cp_board_alias(st_stm32wba65i_dk1 stm32wba65i_dk1)
cp_board_alias(st_nucleo_u575zi_q nucleo_u575zi_q/stm32u575xx)
cp_board_alias(raspberrypi_rpi_pico_zephyr rpi_pico/rp2040)
cp_board_alias(raspberrypi_rpi_pico_w_zephyr rpi_pico/rp2040/w)
cp_board_alias(raspberrypi_rpi_pico2_zephyr rpi_pico2/rp2350a/m33)
cp_board_alias(raspberrypi_rpi_pico2_w_zephyr rpi_pico2/rp2350a/m33/w)
cp_board_alias(st_nucleo_n657x0_q nucleo_n657x0_q/stm32n657xx)