compose-recompose-pulse/build.gradle.kts at main · adamglin0/compose-recompose-pulse · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
import com.vanniktech.maven.publish.MavenPublishBaseExtension
import org.gradle.api.publish.PublishingExtension
import org.gradle.api.publish.maven.MavenPublication

data class PublishedModule(
    val artifactId: String,
    val pomName: String,
    val pomDescription: String,
)

val publishedModules = mapOf(
    ":annotations" to PublishedModule(
        artifactId = "annotations",
        pomName = "Compose Recompose Pulse Annotations",
        pomDescription = "Annotations for opting out of Compose Recompose Pulse instrumentation.",
    ),
    ":runtime" to PublishedModule(
        artifactId = "runtime",
        pomName = "Compose Recompose Pulse Runtime",
        pomDescription = "Runtime APIs and pulse overlay rendering for Compose Recompose Pulse.",
    ),
    ":compiler" to PublishedModule(
        artifactId = "compiler",
        pomName = "Compose Recompose Pulse Compiler",
        pomDescription = "Compiler plugin that injects Compose Recompose Pulse instrumentation.",
    ),
    ":gradle" to PublishedModule(
        artifactId = "gradle",
        pomName = "Compose Recompose Pulse Gradle Plugin",
        pomDescription = "Gradle plugin that wires Compose Recompose Pulse dependencies and compiler integration.",
    ),
)

plugins {
    alias(libs.plugins.androidLibrary) apply false
    alias(libs.plugins.kotlinJvm) apply false
    alias(libs.plugins.kotlinMultiplatform) apply false
    alias(libs.plugins.composeMultiplatform) apply false
    alias(libs.plugins.kotlinCompose) apply false
    alias(libs.plugins.mavenPublish) apply false
}

tasks.register("publishPulseToMavenLocal") {
    dependsOn(publishedModules.keys.map { "$it:publishToMavenLocal" })
}

allprojects {
    group = providers.gradleProperty("GROUP").get()
    version = rootProject.providers.gradleProperty("releaseVersion")
        .orElse(rootProject.providers.gradleProperty("VERSION_NAME"))
        .get()

    configurations.configureEach {
        resolutionStrategy.dependencySubstitution {
            substitute(module("${project.group}:annotations"))
                .using(project(":annotations"))
            substitute(module("${project.group}:compiler"))
                .using(project(":compiler"))
            substitute(module("${project.group}:runtime"))
                .using(project(":runtime"))
        }
    }
}

subprojects {
    val publishedModule = publishedModules[path] ?: return@subprojects
    val isMavenLocalPublish = gradle.startParameter.taskNames.any { taskName ->
        "MavenLocal" in taskName
    }

    plugins.withId("com.vanniktech.maven.publish") {
        extensions.configure(MavenPublishBaseExtension::class.java) {
            publishToMavenCentral(automaticRelease = true)
            if (!isMavenLocalPublish) {
                signAllPublications()
            }
            pom {
                name.set(publishedModule.pomName)
                description.set(publishedModule.pomDescription)
                inceptionYear.set(rootProject.providers.gradleProperty("POM_INCEPTION_YEAR"))
                url.set(rootProject.providers.gradleProperty("POM_URL"))
                licenses {
                    license {
                        name.set(rootProject.providers.gradleProperty("POM_LICENSE_NAME"))
                        url.set(rootProject.providers.gradleProperty("POM_LICENSE_URL"))
                        distribution.set(rootProject.providers.gradleProperty("POM_LICENSE_DIST"))
                    }
                }
                developers {
                    developer {
                        id.set(rootProject.providers.gradleProperty("POM_DEVELOPER_ID"))
                        name.set(rootProject.providers.gradleProperty("POM_DEVELOPER_NAME"))
                        url.set(rootProject.providers.gradleProperty("POM_DEVELOPER_URL"))
                    }
                }
                scm {
                    url.set(rootProject.providers.gradleProperty("POM_SCM_URL"))
                    connection.set(rootProject.providers.gradleProperty("POM_SCM_CONNECTION"))
                    developerConnection.set(rootProject.providers.gradleProperty("POM_SCM_DEV_CONNECTION"))
                }
            }
        }

        extensions.configure(PublishingExtension::class.java) {
            publications.withType(MavenPublication::class.java).configureEach {
                version = project.version.toString()
            }
        }
    }
}