libgdx/publish.gradle at master · aemous/libgdx · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
configure([
	project(":gdx"),
	project(":backends:gdx-backend-android"),
	project(":backends:gdx-backend-headless"),
	project(":backends:gdx-backend-lwjgl"),
	project(":backends:gdx-backend-lwjgl3"),
	project(":backends:gdx-backend-robovm"),
	project(":backends:gdx-backend-robovm-metalangle"),
	project(":backends:gdx-backend-gwt"),
	project(":extensions:gdx-box2d-parent"),
	project(":extensions:gdx-box2d-parent:gdx-box2d"),
	project(":extensions:gdx-box2d-parent:gdx-box2d-gwt"),
	project(":extensions:gdx-bullet"),
	project(":extensions:gdx-freetype"),
	project(":extensions:gdx-lwjgl3-angle"),
	project(":extensions:gdx-tools")
]) {
	apply plugin: 'maven-publish'
	apply plugin: 'signing'

	afterEvaluate { project ->
		//Workaround android not having components populated yet.
		afterEvaluate {
			publishing {
				publications {
					mavenJava(MavenPublication) {
						//Most normal java projects
						if(components.findByName("java") != null)
							from components.java

						//Android
						if(components.findByName("release") != null) {
							from components.release
						}


						pom {
							name = POM_NAME
							if(!POM_DESCRIPTION.isEmpty())
								description = POM_DESCRIPTION
							url = POM_URL
							licenses {
								license {
									name = POM_LICENCE_NAME
									url = POM_LICENCE_URL
									distribution = POM_LICENCE_DIST
								}
							}
							developers {
								developer {
									id = "libGDX Developers"
									url = "https://github.com/libgdx/libgdx/graphs/contributors"
								}
							}
							scm {
								connection = POM_SCM_CONNECTION
								developerConnection = POM_SCM_DEV_CONNECTION
								url = POM_SCM_URL
							}
						}
					}
					//Libgdx natives all follow the "$name-platform" artifact structure.
					if(project.tasks.findByName('jnigen')) {
						mavenPlatform(MavenPublication) {
							artifactId = artifactId + "-platform"
							if(project.tasks.findByName('jnigenJarNativesDesktop'))
								artifact jnigenJarNativesDesktop { }

							[
								'arm64-v8a',
								'armeabi-v7a',
								'x86_64',
								'x86'
							].each { id ->
								if(project.tasks.findByName("jnigenJarNativesAndroid${id}"))
									artifact "jnigenJarNativesAndroid${id}" { }
							}

							if(project.tasks.findByName('jnigenJarNativesIOS'))
								artifact jnigenJarNativesIOS { }

							pom {
								name = POM_NAME + " Native Libraries"
								if(!POM_DESCRIPTION.isEmpty())
									description = POM_DESCRIPTION
								url = POM_URL
								licenses {
									license {
										name = POM_LICENCE_NAME
										url = POM_LICENCE_URL
										distribution = POM_LICENCE_DIST
									}
								}
								developers {
									developer {
										id = "libGDX Developers"
										url = "https://github.com/libgdx/libgdx/graphs/contributors"
									}
								}
								scm {
									connection = POM_SCM_CONNECTION
									developerConnection = POM_SCM_DEV_CONNECTION
									url = POM_SCM_URL
								}
							}
						}
					}
				}

				repositories {
					maven {
						url = version.endsWith('SNAPSHOT')
								? getSnapshotRepositoryUrl()
								// If release build, dump artifacts to local build/staging-deploy folder for consumption by jreleaser below
								: rootProject.layout.buildDirectory.dir('staging-deploy')

						if (version.endsWith('SNAPSHOT') && (getRepositoryUsername() || getRepositoryPassword())) {
							credentials {
								username = getRepositoryUsername()
								password = getRepositoryPassword()
							}
						}
					}
				}
			}

			signing {
				useGpgCmd()
				sign publishing.publications.mavenJava

				if(project.tasks.findByName('jnigen'))
					sign publishing.publications.mavenPlatform
			}

			//Simply using "required" in signing block doesn't work because taskGraph isn't ready yet.
			gradle.taskGraph.whenReady {
				tasks.withType(Sign) {
					onlyIf { isReleaseBuild() }
				}
			}
		}
	}
}

// JReleaser config for release builds to Central Portal
if (project.hasProperty('RELEASE')) {
	rootProject.apply plugin: 'org.jreleaser'

	rootProject.jreleaser {
		deploy {
			maven {
				mavenCentral {
					sonatype {
						active = 'ALWAYS'
						username = getRepositoryUsername()
						password = getRepositoryPassword()
						url = 'https://central.sonatype.com/api/v1/publisher'
						stagingRepository("${rootProject.buildDir}/staging-deploy")
						sign = false
						verifyPom = false
					}
				}
			}
		}
	}

	rootProject.tasks.register('publish') {
		dependsOn subprojects.collect { it.tasks.withType(PublishToMavenRepository) }
		finalizedBy rootProject.tasks.named('jreleaserDeploy')
	}
}