git-wt/flake.nix at main · ahmedelgabri/git-wt · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
{
  description = "git-wt - Git worktree management tool";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
    flake-parts.url = "github:hercules-ci/flake-parts";
    treefmt-nix.url = "github:numtide/treefmt-nix";
  };

  outputs = inputs:
    inputs.flake-parts.lib.mkFlake {inherit inputs;} {
      systems = [
        "x86_64-linux"
        "aarch64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];

      imports = [
        inputs.treefmt-nix.flakeModule
      ];

      perSystem = {
        pkgs,
        config,
        self',
        lib,
        ...
      }: {
        packages = {
          default = self'.packages.git-wt;
          git-wt = pkgs.buildGoModule {
            pname = "git-wt";
            version = "1.2.1";

            src = lib.cleanSource ./.;

            vendorHash = "sha256-qDEbnnCd47RxEoXH4TXlcMHjAIVTMq/1ypNd7AdT/Bc=";

            ldflags = [
              "-s"
              "-w"
              "-X github.com/ahmedelgabri/git-wt/internal/cmd.Version=${self'.packages.git-wt.version}"
            ];

            nativeBuildInputs = with pkgs; [
              installShellFiles
              makeWrapper
            ];

            subPackages = ["cmd/git-wt"];

            postInstall = ''
              # Generate shell completions before wrapping
              $out/bin/git-wt completion bash > git-wt.bash
              $out/bin/git-wt completion zsh > _git-wt
              $out/bin/git-wt completion fish > git-wt.fish
              installShellCompletion --bash git-wt.bash
              installShellCompletion --zsh _git-wt
              installShellCompletion --fish git-wt.fish

              # Generate and install man pages
              mkdir -p $TMPDIR/man
              $out/bin/git-wt man $TMPDIR/man
              installManPage $TMPDIR/man/*.1

              wrapProgram $out/bin/git-wt \
                --prefix PATH : ${pkgs.lib.makeBinPath [pkgs.git]}
            '';

            meta = {
              mainProgram = "git-wt";
              homepage = "https://github.com/ahmedelgabri/git-wt";
              description = "Git worktree management tool";
              license = lib.licenses.mit;
              platforms = lib.platforms.unix;
            };
          };
        };

        treefmt = {
          projectRootFile = "flake.nix";

          programs = {
            gofumpt.enable = true;
            prettier = {
              enable = true;
              includes = [
                "*.md"
                "*.yml"
                "*.yaml"
                "*.json"
                "*.svg"
              ];
            };
            alejandra.enable = true;
          };
        };

        devShells.default = pkgs.mkShell {
          packages = with pkgs; [
            git
            nixd
            lefthook
            prettier
            bats
            go
            gopls
            gofumpt
            go-tools # staticcheck, etc...
            gomodifytags
            gotools # goimports
            just
          ];

          inputsFrom = [config.treefmt.build.devShell];

          shellHook =
            /*
            bash
            */
            ''
              # avoid overriding global git hooks
              git config core.hooksPath .hooks
              lefthook install
            '';
        };
      };
    };
}