current-location/flake.nix at master · aitvann/current-location · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    flake-parts.url = "github:hercules-ci/flake-parts";
    rust-overlay.url = "github:oxalica/rust-overlay";
    rust-overlay.inputs.nixpkgs.follows = "nixpkgs";
  };

  outputs = inputs:
    inputs.flake-parts.lib.mkFlake {inherit inputs;} {
      systems = ["x86_64-linux"];
      perSystem = {
        config,
        self',
        pkgs,
        lib,
        system,
        ...
      }: let
        runtimeDeps = with pkgs; [];
        buildDeps = with pkgs; [];
        devDeps = with pkgs; [
          # Tools
          cargo-flamegraph
          heaptrack

          # Editor tools
          tombi

          codebook

          marksman
          efm-langserver
          pandoc
          markdownlint-cli2

          nixd
          alejandra
        ];

        cargoToml = builtins.fromTOML (builtins.readFile ./Cargo.toml);
        msrv = cargoToml.package.rust-version;

        toolchainFilePath = ./rust-toolchain.toml;
        # Legacy variant
        # toolchainFilePath = ./rust-toolchain;
        pinnedToolchain = pkgs.rust-bin.fromRustupToolchainFile toolchainFilePath;

        rustPackage = features:
          (pkgs.makeRustPlatform {
            cargo = pkgs.rust-bin.nightly.latest.minimal;
            rustc = pkgs.rust-bin.nightly.latest.minimal;
          }).buildRustPackage {
            inherit (cargoToml.package) name version;
            src = ./.;
            cargoLock.lockFile = ./Cargo.lock;
            buildFeatures = features;
            buildInputs = runtimeDeps;
            nativeBuildInputs = buildDeps;
            # Uncomment if your cargo tests require networking or otherwise
            # don't play nicely with the Nix build sandbox:
            # doCheck = false;
          };

        mkToolchain = toolchain: (toolchain.override {
          extensions = [
            "rust-src"
            "rustfmt"
            "rust-analyzer"
            "clippy"
            "miri"
          ];
        });

        mkDevShell = toolchain:
          pkgs.mkShell {
            RUST_SRC_PATH = "${toolchain}/lib/rustlib/src/rust/library";
            buildInputs = runtimeDeps;
            nativeBuildInputs =
              buildDeps
              ++ devDeps
              ++ [(mkToolchain toolchain)];
          };
      in {
        _module.args.pkgs = import inputs.nixpkgs {
          inherit system;
          overlays = [(import inputs.rust-overlay)];
        };

        packages."${cargoToml.package.name}" = rustPackage "";

        devShells.nightly-latest =
          mkDevShell (pkgs.rust-bin.selectLatestNightlyWith (toolchain: mkToolchain toolchain.default));
        devShells.stable-latest = mkDevShell pkgs.rust-bin.stable.latest.default;
        devShells.msrv = mkDevShell pkgs.rust-bin.stable.${msrv}.default;
        devShells.pinned = mkDevShell pinnedToolchain;

        packages.default = self'.packages."${cargoToml.package.name}";
        devShells.default = self'.devShells.pinned;
      };
    };
}