dotfiles/home.nix at main · alDuncanson/dotfiles · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
{
  inputs,
  lib,
  config,
  ...
}:
let
  inherit (lib)
    mapAttrs
    mapAttrsToList
    mkOption
    nameValuePair
    types
    ;

  profileType = types.submodule (
    { ... }:
    {
      options = {
        aliases = mkOption {
          type = types.listOf types.str;
          default = [ ];
        };

        system = mkOption {
          type = types.str;
        };

        userName = mkOption {
          type = types.str;
        };

        homeDirectory = mkOption {
          type = types.str;
        };

        gitName = mkOption {
          type = types.str;
        };

        gitEmail = mkOption {
          type = types.str;
        };

        homeModule = mkOption {
          type = types.deferredModule;
          default = { };
        };
      };
    }
  );

  mkHomeConfiguration =
    profile:
    let
      pkgs = config.dotfiles.lib.mkPkgs profile.system;
    in
    inputs.home-manager.lib.homeManagerConfiguration {
      inherit pkgs;
      modules = [
        inputs.nvf.homeManagerModules.default
        {
          home = {
            username = profile.userName;
            homeDirectory = profile.homeDirectory;
            stateVersion = config.dotfiles.home.stateVersion;
          };

          programs.git.settings.user = {
            name = profile.gitName;
            email = profile.gitEmail;
          };
        }
        config.dotfiles.home.shared
        profile.homeModule
      ];
    };

  canonicalHomes = mapAttrs (_: mkHomeConfiguration) config.dotfiles.profiles;

  aliasHomes = builtins.listToAttrs (
    lib.concatLists (
      mapAttrsToList (
        _: profile: builtins.map (alias: nameValuePair alias (mkHomeConfiguration profile)) profile.aliases
      ) config.dotfiles.profiles
    )
  );
in
{
  imports = [
    (inputs.import-tree ./modules)
    (inputs.import-tree ./profiles)
  ];

  options.dotfiles = {
    defaultSystem = mkOption {
      type = types.str;
      default = "aarch64-darwin";
    };

    lib.mkPkgs = mkOption {
      type = types.raw;
      readOnly = true;
    };

    home = {
      stateVersion = mkOption {
        type = types.str;
        default = "24.05";
      };

      shared = mkOption {
        type = types.deferredModule;
        default = { };
      };
    };

    profiles = mkOption {
      type = types.attrsOf profileType;
      default = { };
    };
  };

  config = {
    dotfiles.lib.mkPkgs =
      system:
      import inputs.nixpkgs {
        inherit system;
        config.allowUnfree = true;
      };

    flake.homeConfigurations = canonicalHomes // aliasHomes;
  };
}