UVCCamera/lib/build.gradle.kts at 3b1c3e9084678ba1ae4d116fbdc82790bcc7c439 · alexey-pelykh/UVCCamera · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
plugins {
    alias(libs.plugins.android.library)
    id("maven-publish")
}

version = findProperty("uvccamera.version") as String? ?: "0.0.0-SNAPSHOT"

android {
    namespace = "org.uvccamera.lib"
    compileSdk = 34

    defaultConfig {
        minSdk = 21

        testInstrumentationRunner = "android.support.test.runner.AndroidJUnitRunner"
        consumerProguardFiles("consumer-rules.pro")

        ndk {
            abiFilters += mutableSetOf("armeabi-v7a", "arm64-v8a")
        }
    }

    buildTypes {
        release {
            isMinifyEnabled = false
            proguardFiles(getDefaultProguardFile("proguard-android-optimize.txt"), "proguard-rules.pro")
        }
    }

    externalNativeBuild {
        ndkBuild {
            path = file("src/main/jni/Android.mk")
        }
    }

    compileOptions {
        sourceCompatibility = JavaVersion.VERSION_11
        targetCompatibility = JavaVersion.VERSION_11
    }

    publishing {
        singleVariant("release") {
            withSourcesJar()
            withJavadocJar()
        }
    }
}

dependencies {
    testImplementation(libs.junit)
    androidTestImplementation(libs.support.test.runner)
    androidTestImplementation(libs.support.espresso.core)
}

publishing {
    publications {
        create<MavenPublication>("release") {
            afterEvaluate {
                from(components["release"])
            }

            groupId = "org.uvccamera"
            artifactId = project.name
            version = project.version.toString()

            pom {
                name = "org.uvccamera:${project.name}"
                description = "USB Video (UVC) Camera Library for Android"
                url = "https://uvccamera.org"

                licenses {
                    license {
                        name = "Apache License Version 2.0"
                        url = "https://www.apache.org/licenses/LICENSE-2.0.txt"
                    }
                }
                developers {
                    developer {
                        name = "saki"
                        email = "t_saki@serenegiant.com"
                    }
                    developer {
                        name = "Alexey Pelykh"
                        email = "alexey.pelykh@gmail.com"
                        organization = "The UVCCamera Project"
                        organizationUrl = "https://uvccamera.org"
                    }
                }
                scm {
                    connection = "scm:git:git://github.com/alexey-pelykh/UVCCamera.git"
                    developerConnection = "scm:git:ssh://github.com:alexey-pelykh/UVCCamera.git"
                    url = "https://github.com/alexey-pelykh/UVCCamera"
                }
            }
        }
    }

    repositories {
        maven {
            name = "StagingDeploy"
            url = uri(layout.buildDirectory.dir("staging-deploy"))
        }
    }
}