opencms-gradle-plugin/build.gradle at master · alkacon/opencms-gradle-plugin · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
plugins {
    id 'groovy'
    id 'maven-publish'
    id 'signing'
    id 'io.github.gradle-nexus.publish-plugin' version "2.0.0"
}

dependencies {
    implementation gradleApi()
    implementation localGroovy()
}

group="org.opencms"

nexusPublishing {
    repositories {
        sonatype {
            nexusUrl.set(uri("https://ossrh-staging-api.central.sonatype.com/service/local/"))
            snapshotRepositoryUrl.set(uri("https://central.sonatype.com/repository/maven-snapshots/"))
        }
    }
}

repositories {
    mavenCentral()
}

sourceCompatibility='1.8'
targetCompatibility='1.8'

task javadocJar(type: Jar, dependsOn: groovydoc) {
    archiveClassifier = 'javadoc'
    from "${buildDir}/docs/groovydoc"
}

task sourcesJar(type: Jar) {
    from sourceSets.main.groovy.srcDirs
    archiveClassifier = 'sources'
}

task setGradleVersion(type: Wrapper) {
    gradleVersion = '7.5.1'
}

task install(dependsOn: publishToMavenLocal) {
    doFirst {
        println "Installing artifacts for version $version"
    }
}

task uploadArchives(dependsOn: publish) {
    doFirst {
        println "Upload artifacts for version $version"
    }
}
afterEvaluate {
    def uploadArchivesDeps = [tasks.findByName("publishToSonatype"), tasks.findByName("closeSonatypeStagingRepository")]
    tasks.findByName("uploadArchives").dependsOn(uploadArchivesDeps)
}

signing {
    useGpgCmd()
    sign publishing.publications
}

gradle.taskGraph.whenReady { taskGraph ->
    tasks.withType(Sign) {
        onlyIf {
            taskGraph.hasTask(":uploadArchives")
        }
    }
}

artifacts {
    archives jar
    archives javadocJar
    archives sourcesJar

}


publishing {
    publications {
        opencmsPlugin(MavenPublication) {
            artifactId = 'opencms-gradle-plugin'
            from components.java
            artifact javadocJar
            artifact sourcesJar
            pom {
                name = 'OpenCms Modules Gradle Plugin'
                description = 'This Gradle pugin can be used to build modules for OpenCms.'
                url = 'http://www.opencms.org'
                licenses {
                    license {
                        name = 'GNU Lesser General Public License'
                        url = 'http://www.gnu.org/licenses/lgpl.html'
                    }
                }
                developers {
                    developer {
                        url = 'https://www.alkacon.com'
                        name = 'Alkacon Software'
                    }
                }
                organization {
                    name = 'Alkacon Software'
                    url = 'https://www.alkacon.com'
                }

                scm {
                    connection = 'scm:git@github.com:alkacon/opencms-gradle-plugin.git'
                    developerConnection = 'scm:git@github.com:alkacon/opencms-gradle-plugin.git'
                    url = 'scm:git@github.com:alkacon/opencms-gradle-plugin.git'
                }
            }
        }
    }
}