tradukisto/build.gradle.kts at master · allegro/tradukisto · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
import org.gradle.api.tasks.testing.logging.TestLogEvent.FAILED
import org.gradle.api.tasks.testing.logging.TestLogEvent.SKIPPED

buildscript {
    repositories {
        mavenCentral()
    }
}

plugins {
    id("java")
    id("groovy")
    id("jacoco")
    id("checkstyle")
    id("maven-publish")
    id("signing")
    id("pl.allegro.tech.build.axion-release") version "1.21.1"
    id("io.github.gradle-nexus.publish-plugin") version "2.0.0"
}

dependencies {
    testImplementation("org.spockframework:spock-core:2.3-groovy-4.0")
}

project.version = scmVersion.version
project.group = "pl.allegro.finance"

repositories {
    mavenCentral()
}

java {
    withSourcesJar()
    withJavadocJar()
    toolchain {
        languageVersion.set(JavaLanguageVersion.of(17))
    }
}

tasks.compileJava {
    options.encoding = "UTF-8"
}


tasks.jacocoTestReport {
    reports {
        xml.required.set(true)
        csv.required.set(true)
    }
}

tasks.test {
    useJUnitPlatform()
    testLogging {
        events = setOf(SKIPPED, FAILED)
    }
}

publishing {
    publications {
        create<MavenPublication>("sonatype") {
            from(components["java"])
            pom {
                name.set("Tradukisto")
                description.set("Small java library created to convert numbers to their word representations")
                url.set("https://github.com/allegro/tradukisto")
                inceptionYear.set("2015")
                licenses {
                    license {
                        name.set("The Apache License, Version 2.0")
                        url.set("http://www.apache.org/licenses/LICENSE-2.0.txt")
                    }
                }
                developers {
                    developer {
                        id.set("dorians")
                        name.set("Dorian Sarnowski")
                    }
                    developer {
                        id.set("wjur")
                        name.set("Wojciech Jurczyk")
                    }
                    developer {
                        id.set("MaciejLipinski")
                        name.set("Maciej Lipiński")
                    }
                    developer {
                        id.set("jglaszka")
                        name.set("Julia Glaszka")
                    }
                    developer {
                        id.set("bgalek")
                        name.set("Bartosz Gałek")
                    }
                    developer {
                        id.set("pawelkowalski92")
                        name.set("Paweł Kowalski")
                    }
                    developer {
                        id.set("bartlomiejgraczyk")
                        name.set("Bartłomiej Graczyk")
                    }
                }
                scm {
                    url.set("https://github.com/allegro/tradukisto")
                    connection.set("scm:git@github.com:allegro/tradukisto.git")
                    developerConnection.set("scm:git@github.com:allegro/tradukisto.git")
                }
            }
        }
    }
}

nexusPublishing {
    repositories {
        sonatype {
            username.set(System.getenv("SONATYPE_USERNAME"))
            password.set(System.getenv("SONATYPE_PASSWORD"))
            nexusUrl.set(uri("https://ossrh-staging-api.central.sonatype.com/service/local/"))
            snapshotRepositoryUrl.set(uri("https://central.sonatype.com/repository/maven-snapshots/"))
        }
    }
}

signing {
    setRequired {
        System.getenv("GPG_KEY_ID") != null
    }
    useInMemoryPgpKeys(
        System.getenv("GPG_KEY_ID"),
        System.getenv("GPG_PRIVATE_KEY"),
        System.getenv("GPG_PRIVATE_KEY_PASSWORD")
    )
    sign(publishing.publications)
}