allthingsembedded.github.io/flake.nix at main · allthingsembedded/allthingsembedded.github.io · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
{
  description = "Flake to build a static site with hugo";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/release-24.11";
    even-theme = {
      url = "github:olOwOlo/hugo-theme-even/master";
      flake = false;
    };
  };

  outputs =
    {
      self,
      even-theme,
      nixpkgs,
      ...
    }:
    let
      systems = [
        "aarch64-darwin"
        "aarch64-linux"
        "x86_64-linux"
      ];
      forEachSystem =
        fn:
        nixpkgs.lib.genAttrs systems (
          system:
          let
            pkgs = import nixpkgs { inherit system; };
          in
          fn pkgs
        );

      buildHugoPackage = { pkgs, pname, version, src, extraBuildArgs ? "" }: (pkgs.stdenvNoCC.mkDerivation {
        inherit pname version src;

        nativeBuildInputs = [
          pkgs.hugo
        ];

        patchPhase = ''
          mkdir -p themes/
          cp -r ${even-theme}/ themes/even
        '';

        buildPhase = ''
          hugo ${extraBuildArgs}
        '';

        installPhase = ''
          cp -r public $out
        '';
      });

    in
    {
      packages = forEachSystem (pkgs: rec {
        allthingsembedded = buildHugoPackage {
          inherit pkgs;
          pname = "allthingsembedded";
          version = "1.0.0";
          src = self;
          extraBuildArgs = "--minify";
        };

        allthingsembedded-staging = buildHugoPackage {
          inherit pkgs;
          pname = "allthingsembedded";
          version = "1.0.0";
          src = self;
          extraBuildArgs = "--minify -D --baseURL https://allthingsembedded.com/staging-web";
        };

        default = allthingsembedded;
      });

      devShells = forEachSystem (pkgs: rec {
        allthingsembedded = pkgs.mkShellNoCC {
          nativeBuildInputs = [
            pkgs.hugo
          ];
        };

        default = allthingsembedded;
      });
    };
}