.justfile

# Prover perf variables
prover_perf_eval_dir := "bin/prover-perf"
prover_programs := "asm-stf,moho"

# List all the available commands
default:
  just --list

# Fix Rust formatting
fmt:
  cargo fmt --all

# Fix TOML formatting with `taplo`
toml-fmt:
  taplo format

# Check Rust formatting
check-fmt:
  cargo fmt --all --check

# Rust `clippy` lints
clippy:
  cargo clippy --examples --tests --benches --all-features --all-targets --locked

# TOML lint with `taplo`
toml-lint:
  taplo lint

# Check TOML formatting with `taplo`
toml-check-fmt:
  taplo format --check

# Check formatting of functional tests
functional-check-fmt:
  cd functional-tests && uv run ruff format --check

# Lint and typecheck functional tests
functional-lint:
  cd functional-tests && uv run ruff check && uv run ty check

# Rust unit tests with `cargo-nextest`
unit-test:
  cargo --locked nextest run --all-features

# Rust documentation tests
doctest:
  cargo test --doc --all-features

# Run functional tests
functional-test:
  cd functional-tests && ./run_test.sh

# Run all lints and formatting checks
lints: toml-check-fmt toml-lint check-fmt clippy functional-check-fmt functional-lint

# Rust all tests
test: unit-test doctest

# Publish crate to crates.io
publish:
  cargo publish --token $CARGO_REGISTRY_TOKEN

# Check supply chain security analsis with `cargo-audit`
audit:
  cargo audit

# Check GitHub Actions security analysis with `zizmor`
check-github-actions-security:
  zizmor .

# Generate reports and profiling data for proofs
prover-eval: prover-clean
  cd {{prover_perf_eval_dir}} && ASM_PARAMS_JSON="$(cat asm-params.json)" RUST_LOG=info ZKVM_MOCK=1 ZKVM_PROFILING=1 cargo run --release -- --programs {{prover_programs}}

# Cleans up profiling data generated by prover eval
prover-clean:
  rm -rf {{prover_perf_eval_dir}}/*.trace