.justfile

# Variables
git_tag := `git describe --tags --abbrev=0 2>/dev/null || echo "no-tag"`
timestamp := `date +%s`
build_path := "target"
functional_tests_dir := "functional-tests"
functional_tests_datadir := "_dd"
docker_dir := "docker"
docker_datadir := "data"
profile := env("PROFILE", "dev")
cargo_install_extra_flags := env("CARGO_INSTALL_EXTRA_FLAGS", "")
features := env("FEATURES", "")
docker_image_name := env("DOCKER_IMAGE_NAME", "")
unit_test_args := "--locked --workspace --profile ci --retries 2 --status-level fail --no-capture"
cov_file := "lcov.info"

# Default recipe - show available commands
default:
    @just --list

# Build the workspace into the `target` directory
[group('build')]
build:
    cargo build --workspace --features "{{features}}" --profile "{{profile}}" --lib --bins --examples --tests --benches

# Run unit tests
[group('test')]
test-unit: ensure-cargo-nextest
    ZKVM_MOCK=1 cargo nextest run {{unit_test_args}}

# Run unit tests with coverage
[group('test')]
cov-unit: ensure-cargo-llvm-cov ensure-cargo-nextest
    rm -f {{cov_file}}
    cargo llvm-cov nextest --lcov --output-path {{cov_file}} {{unit_test_args}}

# Generate an HTML coverage report and open it in the browser
[group('test')]
cov-report-html: ensure-cargo-llvm-cov ensure-cargo-nextest
    cargo llvm-cov --open nextest {{unit_test_args}}

# Runs `nextest` under `cargo-mutants`. Caution: This can take *really* long to run
[group('test')]
mutants-test: ensure-cargo-mutants
    cargo mutants --workspace -j2

# Check for security advisories on any dependencies
[group('test')]
sec: ensure-cargo-audit
    cargo audit

# cargo clean
[group('build')]
clean-cargo:
    cargo clean 2>/dev/null || true

# Remove docker data files inside /docker/data
[group('docker')]
clean-docker-data:
    rm -rf {{docker_dir}}/{{docker_datadir}} 2>/dev/null || true

# Builds the base image used to build the binaries
[group('docker')]
build-base:
    docker build -f docker/base.Dockerfile . -t bridge-base:latest

# Builds the runtime image used as the final container
[group('docker')]
build-rt:
    docker build -f docker/rt.Dockerfile . -t bridge-rt:latest

# Builds all images in the compose.yml
[group('docker')]
build-compose:
    docker compose down
    docker compose build
    just start-fdb
    docker compose up -d

# Clean docker volumes
[group('docker')]
clean:
    rm -rf docker/vol/*/data

# Start FoundationDB container, wait for health, and initialize
[group('docker')]
start-fdb:
    docker compose up -d foundationdb
    just init-fdb
    docker compose up -d --wait foundationdb

# Initialize FoundationDB (idempotent - safe to run multiple times)
[group('docker')]
init-fdb:
    #!/usr/bin/env bash
    if docker compose exec -T foundationdb fdbcli --no-status --exec "status minimal" 2>/dev/null | grep -q "The database is available"; then
        echo "FoundationDB already configured, skipping..."
    else
        docker compose exec -T foundationdb fdbcli --exec "configure new single ssd"
        echo -e "\n\033[36m======== FDB_INITIALIZED ========\033[0m\n"
    fi

# Cleans data and rebuilds all containers
[group('docker')]
clean-docker: build-base build-rt clean build-compose
    @echo "\n\033[36m======== DOCKER_BUILD_COMPLETE ========\033[0m\n"

# Rebuilds and starts containers without cleaning data
[group('docker')]
docker: build-base build-rt build-compose
    @echo "\n\033[36m======== DOCKER_BUILD_COMPLETE_WITH_DATA ========\033[0m\n"

# Generate TLS for secret service 1
[group('docker')]
gen-s2-tls-1:
    ./docker/gen_s2_tls.sh docker/vol/strata-bridge-1 docker/vol/secret-service-1

# Generate TLS for secret service 2
[group('docker')]
gen-s2-tls-2:
    ./docker/gen_s2_tls.sh docker/vol/strata-bridge-2 docker/vol/secret-service-2

# Generate TLS for secret service 3
[group('docker')]
gen-s2-tls-3:
    ./docker/gen_s2_tls.sh docker/vol/strata-bridge-3 docker/vol/secret-service-3

# (Re)generates the TLS CAs, certs and keys for S2's and the bridge nodes to connect
[group('docker')]
gen-s2-tls: gen-s2-tls-1 gen-s2-tls-2 gen-s2-tls-3
    @echo "\n\033[36m======== TLS FILES GENERATION COMPLETE ========\033[0m\n"

# Check formatting issues but do not fix automatically
[group('code-quality')]
fmt-check-ws:
    cargo fmt --check

# Format source code in the workspace
[group('code-quality')]
fmt-ws:
    cargo fmt --all

# Check formatting of python files inside `test` directory
[group('code-quality')]
fmt-check-func-tests: ensure-uv activate-uv
    cd {{functional_tests_dir}} && uv run ruff format --check

# Apply formatting of python files inside `test` directory
[group('code-quality')]
fmt-func-tests: ensure-uv activate-uv
    cd {{functional_tests_dir}} && uv run ruff format

# Lints the functional tests and applies fixes where possible
[group('code-quality')]
lint-fix-func-tests: ensure-uv activate-uv
    cd {{functional_tests_dir}} && uv run ruff check --fix


# Lints the functional tests
[group('code-quality')]
lint-check-func-tests: ensure-uv activate-uv
    cd {{functional_tests_dir}} && uv run ruff check && uv run ty check

# Check if cargo-audit is installed
[group('prerequisites')]
ensure-cargo-audit:
    #!/usr/bin/env bash
    if ! command -v cargo-audit &> /dev/null;
    then
        echo "cargo-audit not found. Please install it by running the command 'cargo install cargo-audit'"
        exit 1
    fi

# Check if cargo-llvm-cov is installed
[group('prerequisites')]
ensure-cargo-llvm-cov:
    #!/usr/bin/env bash
    if ! command -v cargo-llvm-cov &> /dev/null;
    then
        echo "cargo-llvm-cov not found. Please install it by running the command 'cargo install cargo-llvm-cov --locked'"
        exit 1
    fi

# Check if cargo-mutants is installed
[group('prerequisites')]
ensure-cargo-mutants:
    #!/usr/bin/env bash
    if ! command -v cargo-mutants &> /dev/null;
    then
        echo "cargo-mutants not found. Please install it by running the command 'cargo install cargo-mutants'"
        exit 1
    fi

# Check if cargo-nextest is installed
[group('prerequisites')]
ensure-cargo-nextest:
    #!/usr/bin/env bash
    if ! command -v cargo-nextest &> /dev/null;
    then
        echo "cargo-nextest not found. Please install it by running the command 'cargo install cargo-nextest --locked'"
        exit 1
    fi

# Check if taplo is installed
[group('prerequisites')]
ensure-taplo:
    #!/usr/bin/env bash
    if ! command -v taplo &> /dev/null; then
        echo "taplo not found. Please install it by following the instructions from: https://taplo.tamasfe.dev/cli/installation/binary.html"
        exit 1
    fi

# Check if uv is installed
[group('prerequisites')]
ensure-uv:
    #!/usr/bin/env bash
    if ! command -v uv &> /dev/null;
    then
        echo "uv not found. Please install it by following the instructions from: https://docs.astral.sh/uv/"
        exit 1
    fi

# Runs `taplo` to check that TOML files are properly formatted
[group('code-quality')]
fmt-check-toml: ensure-taplo
    taplo fmt --check

# Runs `taplo` to format TOML files
[group('code-quality')]
fmt-toml: ensure-taplo
    taplo fmt

# Checks for lint issues in the workspace
[group('code-quality')]
lint-check-ws:
    cargo clippy \
        --workspace \
        --lib \
        --examples \
        --tests \
        --benches \
        --all-features \
        --no-deps \
        -- -D warnings

# Lints the workspace and applies fixes where possible
[group('code-quality')]
lint-fix-ws:
    cargo clippy \
        --workspace \
        --lib \
        --examples \
        --tests \
        --benches \
        --all-features \
        --fix \
        --no-deps \
        -- -D warnings

# Check if codespell is installed
[group('prerequisites')]
ensure-codespell:
    #!/usr/bin/env bash
    if ! command -v codespell &> /dev/null; then
        echo "codespell not found. Please install it by running the command 'pip install codespell' or refer to the following link for more information: https://github.com/codespell-project/codespell"
        exit 1
    fi

# Runs `codespell` to check for spelling errors
[group('code-quality')]
lint-check-codespell: ensure-codespell
    codespell

# Runs orphan check for Jira-linked TODO/FIXME comments
[group('code-quality')]
orphan-check-jira:
    python3 scripts/orphan_check.py --format jira-link --slugs TODO FIXME

# Runs orphan check for assignee-tagged NOTE/HACK/PERF comments
[group('code-quality')]
orphan-check-assignees:
    python3 scripts/orphan_check.py --format assignee --slugs NOTE HACK PERF --allow-rust-docstrings NOTE

# Runs all orphan checks for comment formatting
[group('code-quality')]
orphan-check: orphan-check-jira orphan-check-assignees

# Runs `codespell` to fix spelling errors if possible
[group('code-quality')]
lint-fix-codespell: ensure-codespell
    codespell -w

# Lints TOML files
[group('code-quality')]
lint-check-toml: ensure-taplo
    taplo lint

# Runs all lints and checks for issues without trying to fix them
[group('code-quality')]
lint: fmt-check-ws fmt-check-toml lint-check-ws lint-check-codespell orphan-check
    @echo "\n\033[36m======== OK: Lints and Formatting ========\033[0m\n"

# Runs all lints and applies fixes where possible
[group('code-quality')]
lint-fix: fmt-toml fmt-ws lint-fix-ws lint-fix-codespell
    @echo "\n\033[36m======== OK: Lints and Formatting Fixes ========\033[0m\n"

# Runs `cargo docs` to generate the Rust documents in the `target/doc` directory
[group('code-quality')]
rustdocs:
    RUSTDOCFLAGS="\
    --show-type-layout \
    --enable-index-page -Z unstable-options \
    -A rustdoc::private-doc-tests \
    -D warnings" \
    cargo doc \
    --workspace \
    --no-deps

# Runs doctests on the workspace
[group('code-quality')]
test-doc:
    cargo test --doc --workspace

# Runs all tests in the workspace including unit and docs tests
[group('code-quality')]
test: test-unit test-doc

# Runs lints (without fixing), audit, docs, and tests (run this before creating a PR)
[group('code-quality')]
pr: lint rustdocs test-doc test-unit
    @echo "\n\033[36m======== CHECKS_COMPLETE ========\033[0m\n"
    @test -z "`git status --porcelain`" || echo "WARNING: You have uncommitted changes"
    @echo "All good to create a PR!"

# Broadcast a mock checkpoint
[group('bridge')]
checkpoint genesis-l1-height="101" num-withdrawals="1" ol-start-slot="0" ol-end-slot="1" epoch="1" assignee-node-idx="0":
    RUST_LOG=info \
    cargo r \
        --bin dev-cli \
        -- \
        create-and-publish-mock-checkpoint \
        --btc-url http://localhost:18443/wallet/default \
        --btc-user user \
        --btc-pass password \
        --epoch {{ epoch }} \
        --ol-start-slot {{ ol-start-slot }} \
        --ol-end-slot {{ ol-end-slot }} \
        --num-withdrawals {{ num-withdrawals }} \
        --genesis-l1-height {{ genesis-l1-height }} \
        --assignee-node-idx {{ assignee-node-idx }}

# Run bridge-in
[group('bridge')]
bridge-in:
    RUST_LOG=info \
    cargo r \
        --bin dev-cli \
        -- \
        bridge-in \
        --btc-url http://localhost:18443/wallet/default \
        --btc-user user \
        --btc-pass password \
        --params bin/dev-cli/params.toml \
        --ee-address 70997970C51812dc3A010C7d01b50e0d17dc79C8 # from anvil #2

# Contest a claim transaction by signing and broadcasting a challenge via the game graph
[group('bridge')]
contest deposit-idx="0" operator-idx="0" contester-node-idx="1" seed="" bridge-node-url="http://localhost:4781":
    RUST_LOG=info \
    cargo r \
        --bin dev-cli \
        -- \
        contest \
        --deposit-idx {{ deposit-idx }} \
        --operator-idx {{ operator-idx }} \
        --bridge-node-url {{ bridge-node-url }} \
        --contester-node-idx {{ contester-node-idx }} \
        --seed {{ seed }} \
        --params bin/dev-cli/params.toml \
        --btc-url http://localhost:18443/wallet/default \
        --btc-user user \
        --btc-pass password

# Derive operator keys from a seed for functional tests
[group('bridge')]
derive-keys seed:
    cargo r --bin dev-cli -- derive-keys {{seed}}

# Activate uv environment for integration tests
[group('functional-tests')]
activate-uv: ensure-uv
    cd {{functional_tests_dir}} && uv venv --clear
    @if [ -n "${FISH_VERSION:-}" ]; then source {{functional_tests_dir}}/.venv/bin/activate.fish; else source {{functional_tests_dir}}/.venv/bin/activate; fi

# Remove the data directory used by functional tests
[group('functional-tests')]
clean-dd:
    rm -rf {{functional_tests_dir}}/{{functional_tests_datadir}} 2>/dev/null || true

# Runs functional tests
[group('functional-tests')]
test-functional: ensure-uv activate-uv clean-dd
    cd {{functional_tests_dir}} && ./run_test.sh