Merge pull request #11 from nick-shaw/feature/ctl

Add first draft CTL implementation.

Author: nick-shaw

model/README.md

@@ -29,7 +29,7 @@ DCC Implementations for the following software packages are included. For specif
 - [DCTL for Resolve Studio](/model/docs/doc-resolve.md)
 - [Matchbox for Flame, Scratch and Baselight](/model/docs/doc-flame.md)
 
-A Python implementation is also included.
+A Python implementation is also included, as well as a first draft of the CTL which will form part of the deliverable of the Virtual Working Group.
 
 ## Default Parameter Values
 This [Google Colab notebook](https://colab.research.google.com/drive/1ZMSQhyhXtAYQXfop6qhifXudDiPu4eTV?usp=sharing) shows calculations for the threshold values needed to protect the colors of the ColorChecker24, as defined in Annexe B of [TB-2014-004](http://j.mp/TB-2014-004), and the distance limits needed to map the entirety of a set of common camera encoding gamuts into AP1.

model/gamut_compress.ctl

@@ -0,0 +1,134 @@
+// <ACEStransformID>urn:ampas:aces:transformId:v1.5:LMT.VWG.GamutCompress.a1.v1</ACEStransformID>
+// <ACESuserName>ACES 1.3 Look - Gamut Compress</ACESuserName>
+
+//
+// "LMT" for compressing out of gamut scene-referred values into AP1.
+// 
+// Input and output are ACES2065-1.
+//
+
+//
+// Direction:
+//    By default this transform operates in the forward direction (compressing the gamut).
+//    If instead an inverse operation is needed (undoing a prior gamut compression), there
+//    is a runtime flag to do this. In ctlrender, this can be achieved by appending 
+//    '-param1 invert 1' after the '-ctl gamut_compress.ctl' string.
+//
+
+
+
+import "ACESlib.Transform_Common";
+
+
+
+/* --- Gamut Compress Parameters --- */
+// Distance from achromatic which will be compressed to the gamut boundary
+const float LIM_CYAN =  1.147;
+const float LIM_MAGENTA = 1.264;
+const float LIM_YELLOW = 1.312;
+
+// Percentage of the core gamut to protect
+const float THR_CYAN = 0.815;
+const float THR_MAGENTA = 0.803;
+const float THR_YELLOW = 0.880;
+
+// Agressiveness of the compression curve
+const float PWR = 1.2;
+
+
+
+// Calculate compressed distance
+float compress(float dist, float lim, float thr, float pwr, bool invert)
+{
+    float comprDist;
+    float scl;
+    float nd;
+    float p;
+
+    if (dist < thr) {
+        comprDist = dist; // No compression below threshold
+    }
+    else {
+        // Calculate scale factor for y = 1 intersect
+        scl = (lim - thr) / pow(pow((1.0 - thr) / (lim - thr), -pwr) - 1.0, 1.0 / pwr);
+
+        // Normalize distance outside threshold by scale factor
+        nd = (dist - thr) / scl;
+        p = pow(nd, pwr);
+
+        if (!invert) {
+            comprDist = thr + scl * nd / (pow(1.0 + p, 1.0 / pwr)); // Compress
+        }
+        else {
+            if (dist > (thr + scl)) {
+                comprDist = dist; // Avoid singularity
+            }
+            else {
+                comprDist = thr + scl * pow(-(p / (p - 1.0)), 1.0 / pwr); // Uncompress
+            }
+        }
+    }
+
+    return comprDist;
+}
+
+
+
+void main 
+(
+    input varying float rIn, 
+    input varying float gIn, 
+    input varying float bIn, 
+    input varying float aIn,
+    output varying float rOut,
+    output varying float gOut,
+    output varying float bOut,
+    output varying float aOut,
+    input uniform bool invert = false
+) 
+{ 
+    // Source values
+    float ACES[3] = {rIn, gIn, bIn};
+
+    // Convert to ACEScg
+    float linAP1[3] = mult_f3_f44(ACES, AP0_2_AP1_MAT);
+
+    // Achromatic axis
+    float ach = max_f3(linAP1);
+
+    // Distance from the achromatic axis for each color component aka inverse RGB ratios
+    float dist[3];
+    if (ach == 0.0) {
+        dist[0] = 0.0;
+        dist[1] = 0.0;
+        dist[2] = 0.0;
+    }
+    else {
+        dist[0] = (ach - linAP1[0]) / fabs(ach);
+        dist[1] = (ach - linAP1[1]) / fabs(ach);
+        dist[2] = (ach - linAP1[2]) / fabs(ach);
+    }
+
+    // Compress distance with parameterized shaper function
+    float comprDist[3] = {
+        compress(dist[0], LIM_CYAN, THR_CYAN, PWR, invert),
+        compress(dist[1], LIM_MAGENTA, THR_MAGENTA, PWR, invert),
+        compress(dist[2], LIM_YELLOW, THR_YELLOW, PWR, invert)
+    };
+
+    // Recalculate RGB from compressed distance and achromatic
+    float comprLinAP1[3] = {
+        ach - comprDist[0] * fabs(ach),
+        ach - comprDist[1] * fabs(ach),
+        ach - comprDist[2] * fabs(ach)
+    };
+
+    // Convert back to ACES2065-1
+    ACES = mult_f3_f44(comprLinAP1, AP1_2_AP0_MAT);
+
+    // Write output
+    rOut = ACES[0];
+    gOut = ACES[1];
+    bOut = ACES[2];
+    aOut = aIn;
+}