gcp-gradle-build-cache/gcpbuildcache/build.gradle.kts at 7f3a88ff6f8ba21ef68c4aa2436b03e7ddf157ee · androidx/gcp-gradle-build-cache · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
/*
 * Copyright 2022 The Android Open Source Project
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *   http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 *
 */

import org.jetbrains.kotlin.gradle.dsl.KotlinVersion

plugins {
    id("maven-publish")
    id("signing")
    id("bundle")
    alias(libs.plugins.gradle.publish)
    alias(libs.plugins.kotlin.jvm)
}

dependencies {
    // Bundle core library directly as we only get to publish one jar per plugin in Gradle Plugin Portal
    bundleInside(project(":core"))
    implementation(platform(libs.okhttp.bom))
    implementation(libs.google.cloud.storage)
    implementation(libs.google.protobuf.java)
    implementation(libs.retrofit.core)
    implementation(libs.retrofit.converter.gson)
    implementation(libs.google.gson)
    implementation(libs.okhttp)
}

kotlin {
    jvmToolchain {
        jvmToolchain(17)
    }
    compilerOptions {
        languageVersion.set(KotlinVersion.KOTLIN_2_0)
    }
    coreLibrariesVersion = "2.0.0"
}

gradlePlugin {
    website = "https://github.com/androidx/gcp-gradle-build-cache"
    vcsUrl = "https://github.com/androidx/gcp-gradle-build-cache"
    plugins {
        create("gcpbuildcache") {
            id = "androidx.build.gradle.gcpbuildcache"
            displayName = "Gradle GCP Build Cache Plugin"
            description = """
                - Move to using GRPC to fetch cache entries from GCP. Local testing shows that it drops sequential download time by ~40%
            """.trimIndent()
            implementationClass = "androidx.build.gradle.gcpbuildcache.GcpGradleBuildCachePlugin"
            tags = listOf("buildcache", "gcp", "caching")
        }
    }
}

group = "androidx.build.gradle.gcpbuildcache"
version = "1.0.1"

testing {
    suites {
        // Configure built-in test suite.
        val test by getting(JvmTestSuite::class) {
            useJUnit()
        }

        // Create a new functional test suite.
        val functionalTest by registering(JvmTestSuite::class) {
            useJUnit()

            dependencies {
                // functionalTest test suite depends on the production code in tests
                implementation(project())
            }

            targets {
                all {
                    // This test suite should run after the built-in test suite has run its tests
                    testTask.configure { shouldRunAfter(test) }
                }
            }
        }
    }
}

gradlePlugin.testSourceSets(sourceSets["functionalTest"])

tasks.named<Task>("check") {
    // Include functionalTest as part of the check lifecycle
    dependsOn(testing.suites.named("functionalTest"))
}

tasks.withType<Sign>().configureEach {
    val signingKeyIdPresent = project.hasProperty("signing.keyId")
    onlyIf("signing.keyId is present") { signingKeyIdPresent }
}