! character can be escaped while ENABLEDELAYEDEXPANSION is used

[andry81]

Tested on:

Windows XP x86 SP3

Windows XP x64 SP2

Windows 7 x64

Windows 8.1 x64

Tests:

https://github.com/andry81/contools--debug/tree/HEAD/test_delayed_expansion_escape.bat

@echo off

setlocal ENABLEDELAYEDEXPANSION

set A=123

echo;^!A^!A!A!
echo;"^!A^!A!A!"

setlocal DISABLEDELAYEDEXPANSION & for /F "usebackq tokens=* delims="eol^= %%i in ('^!A^!A!A!') do endlocal & echo;%%i
setlocal DISABLEDELAYEDEXPANSION & for /F "usebackq tokens=* delims="eol^= %%i in ('"^!A^!A!A!"') do endlocal & echo;%%~i

setlocal DISABLEDELAYEDEXPANSION & for /F "usebackq tokens=* delims="eol^= %%i in ('"^!A^!A!A!"') do endlocal & set "B=%%~i"
set B

setlocal DISABLEDELAYEDEXPANSION & for /F "usebackq tokens=* delims="eol^= %%i in ('"^!B^!B!B!"') do endlocal & echo;%%~i
setlocal DISABLEDELAYEDEXPANSION & for /F "usebackq tokens=* delims="eol^= %%i in ('"!B!"') do endlocal & echo;%%~i

Results:

test_delayed_expansion_escape.bat:

123A123
"!A!A123"
123A123
!A!A123
B=!A!A123
!B!B!A!A123
!A!A123

[jeb-de]

I'm missing the escaping when there are no double quotes like here

setlocal ENABLEDELAYEDEXPANSION

set A=123

echo;#1 ^^!A^^!A!A!
echo;#2 "^!A^!A!A!"

setlocal DISABLEDELAYEDEXPANSION & for /F "usebackq tokens=* delims="eol^= %%i in ('#3 ^^!A^^!A!A!') do endlocal & echo;%%i

[andry81]

You can add double quotes and use %%~i instead, right?