chcp.com and fc.exe does reset the standard input

[andry81]

If execute chcp.com or fc.exe while the stdin is being read, then it will reset stdin handle into the beginning of the being read stream.

Note

It is opposite to the wmic.exe issue in #25 when wmic.exe reads the input bypassing the standard stream handle.

Tests:

https://github.com/andry81/contools--debug/tree/HEAD/test_chcp_stdin_reset.bat
https://github.com/andry81/contools--debug/tree/HEAD/test_fc_stdin_reset.bat
https://github.com/andry81/contools--debug/tree/HEAD/1.in
https://github.com/andry81/contools--debug/tree/HEAD/dummy1.txt

@echo off

setlocal

pushd "%~dp0"

echo;1.in:
type 1.in
echo;---

echo Broken iteration

rem trick with simultaneous iteration over 2 list in the same time
(
  for /F "usebackq tokens=* delims="eol^= %%i in ("1.in") do set /P "READ1=" & set "READ2=%%i" & call :PROCESS & echo;---
) < "1.in"

goto NEXT

:PROCESS
set READ
"%SystemRoot%\System32\fc.exe" /B "dummy1.txt" "dummy1.txt"
exit /b

:NEXT

echo Fixed iteration 1

rem trick with simultaneous iteration over 2 list in the same time
(
  for /F "usebackq tokens=* delims="eol^= %%i in ("1.in") do set /P "READ1=" & set "READ2=%%i" & call :PROCESS & echo;---
) < "1.in"

goto NEXT

:PROCESS
set READ
"%SystemRoot%\System32\fc.exe" /B "dummy1.txt" "dummy1.txt" <nul
exit /b

:NEXT

echo Fixed iteration 2

rem trick with simultaneous iteration over 2 list in the same time
(
  for /F "usebackq tokens=* delims="eol^= %%i in ("1.in") do set /P "READ1=" & set "READ2=%%i" & call :PROCESS <nul & echo;---
) < "1.in"

goto NEXT

:PROCESS
set READ
"%SystemRoot%\System32\fc.exe" /B "dummy1.txt" "dummy1.txt"
exit /b

:NEXT

echo Fixed iteration 3

rem trick with simultaneous iteration over 2 list in the same time
(
  for /F "usebackq tokens=* delims="eol^= %%i in ("1.in") do set /P "READ1=" & set "READ2=%%i" & call :PROCESS & echo;---
) < "1.in"

goto NEXT

:PROCESS
set READ
call;|"%SystemRoot%\System32\fc.exe" /B "dummy1.txt" "dummy1.txt"
exit /b

:NEXT
exit /b 0

Results:

1.in:
1
2
3
---
Broken iteration
READ1=1
READ2=1
Comparing files dummy1.txt and DUMMY1.TXT
FC: no differences encountered

---
READ1=1
READ2=2
Comparing files dummy1.txt and DUMMY1.TXT
FC: no differences encountered

---
READ1=1
READ2=3
Comparing files dummy1.txt and DUMMY1.TXT
FC: no differences encountered

---
Fixed iteration 1
READ1=1
READ2=1
Comparing files dummy1.txt and DUMMY1.TXT
FC: no differences encountered

---
READ1=2
READ2=2
Comparing files dummy1.txt and DUMMY1.TXT
FC: no differences encountered

---
READ1=3
READ2=3
Comparing files dummy1.txt and DUMMY1.TXT
FC: no differences encountered

---
Fixed iteration 2
READ1=1
READ2=1
Comparing files dummy1.txt and DUMMY1.TXT
FC: no differences encountered

---
READ1=2
READ2=2
Comparing files dummy1.txt and DUMMY1.TXT
FC: no differences encountered

---
READ1=3
READ2=3
Comparing files dummy1.txt and DUMMY1.TXT
FC: no differences encountered

---
Fixed iteration 3
READ1=1
READ2=1
Comparing files dummy1.txt and DUMMY1.TXT
FC: no differences encountered

---
READ1=2
READ2=2
Comparing files dummy1.txt and DUMMY1.TXT
FC: no differences encountered

---
READ1=3
READ2=3
Comparing files dummy1.txt and DUMMY1.TXT
FC: no differences encountered

---