ht/flake.nix at main · andyk/ht · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
{
  description = "ht";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
    rust-overlay.url = "github:oxalica/rust-overlay";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs =
    {
      self,
      nixpkgs,
      rust-overlay,
      flake-utils,
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        overlays = [ (import rust-overlay) ];
        pkgs = import nixpkgs { inherit system overlays; };

        ht = pkgs.rustPlatform.buildRustPackage {
          pname = "ht";
          version = (builtins.fromTOML (builtins.readFile ./Cargo.toml)).package.version;
          src = self;

          cargoLock = {
            lockFile = ./Cargo.lock;
          };

          buildInputs = pkgs.lib.optionals pkgs.stdenv.isDarwin [
            pkgs.libiconv
            pkgs.darwin.apple_sdk.frameworks.Foundation
          ];
        };
      in
      {
        packages = {
          ht = ht;
          default = ht;
        };

        devShells.default = pkgs.mkShell {
          nativeBuildInputs =
            with pkgs;
            [
              (rust-bin.stable."1.84.0".default.override { extensions = [ "rust-src" "rust-analyzer" ]; })
              bashInteractive
            ]
            ++ (lib.optionals stdenv.isDarwin [
              libiconv
              darwin.apple_sdk.frameworks.Foundation
            ]);
        };
      }
    );
}