Wisp/build.gradle.kts at main · angryPodo/Wisp · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
import com.vanniktech.maven.publish.MavenPublishBaseExtension
import com.vanniktech.maven.publish.SonatypeHost
import org.jlleitschuh.gradle.ktlint.KtlintExtension

plugins {
    // Android
    alias(libs.plugins.android.application) apply false
    alias(libs.plugins.android.library) apply false

    // Kotlin
    alias(libs.plugins.kotlin.android) apply false
    alias(libs.plugins.kotlin.jvm) apply false
    alias(libs.plugins.kotlin.compose) apply false
    alias(libs.plugins.kotlin.serialization) apply false

    // Tools
    alias(libs.plugins.ksp) apply false
    alias(libs.plugins.ktlint) apply false
    alias(libs.plugins.vanniktech.maven.publish) apply false
}

subprojects {
    apply(plugin = "org.jlleitschuh.gradle.ktlint")

    extensions.configure<KtlintExtension> {
        android.set(true)
        debug.set(true)
        coloredOutput.set(true)
        verbose.set(true)
        outputToConsole.set(true)
    }

    tasks.withType<Test> {
        useJUnitPlatform()
    }

    if (name != "app") {
        apply(plugin = "com.vanniktech.maven.publish")

        extensions.configure<MavenPublishBaseExtension> {
            publishToMavenCentral(SonatypeHost.CENTRAL_PORTAL)
            signAllPublications()

            coordinates("io.github.angrypodo", name, "0.1.0")

            pom {
                name.set(project.name)
                description.set("Wisp library: ${project.name}")
                inceptionYear.set("2025")
                url.set("https://github.com/angrypodo/wisp")
                licenses {
                    license {
                        name.set("The Apache License, Version 2.0")
                        url.set("http://www.apache.org/licenses/LICENSE-2.0.txt")
                        distribution.set("http://www.apache.org/licenses/LICENSE-2.0.txt")
                    }
                }
                developers {
                    developer {
                        id.set("angrypodo")
                        name.set("MinJae Han")
                        url.set("https://github.com/angrypodo")
                    }
                }
                scm {
                    url.set("https://github.com/angrypodo/wisp")
                    connection.set("scm:git:git://github.com/angrypodo/wisp.git")
                    developerConnection.set("scm:git:ssh://git@github.com/angrypodo/wisp.git")
                }
            }
        }
    }
}